save key config

[fceu.git] / ncpu.S

/*************************************
  Little John GP32
  File : ncpu.S
  Authors : FCA author
            modified and adapted by Yoyo.
            timing fixed, missing opcodes added
	    and adapted for fceu by notaz, 2007.
**************************************/

#include "ncpu.h"

/* emulate (some) dummy reads (may need that because they affect open bus) */
#define DO_DUMMY_READS 1

@@@
@@@ Offets from REG_OP_TABLE
@@@
#define OTOFFS_NES_RAM   (nes_internal_ram - cpu_exec_table)
#define OTOFFS_NES_STACK (nes_stack        - cpu_exec_table)
#define OTOFFS_NES_REGS  (nes_registers    - cpu_exec_table)
#define OTOFFS_PC_BASE   (pc_base          - cpu_exec_table)
#define OTOFFS_IRQ_HOOK  (MapIRQHook       - cpu_exec_table)
#define OTOFFS_TIMESTAMP (timestamp        - cpu_exec_table)
#define OTOFFS_X         (X_               - cpu_exec_table)

@ fceu
#define FCEU_IQNMI      0x08
#define FCEU_IQTEMP     0x80


@@@@@@@@@@@@@@@@@@@@@@@@@@


@	SECTION_FAST
	SECTION_TEXT
	ALIGN

/*
bbbb:
.ascii "ab_a: %04x"
.byte 0x0a,0
.align 4
stmfd sp!,{r0-r3,r12,lr}
mov r1,r0
ldr r0,=bbbb
bl printf
ldmfd sp!,{r0-r3,r12,lr}
*/

@@@
@@@ r0	=  Address (unbased)
@@@ uses REG_OP_TABLE; sets REG_PC; trashes r1,r2; keeps r0
@@@
.macro	REBASE_PC
	@ FIXME: do something with mem not in Page[].
@	stmfd	sp!, {r0-r3,r12,lr}
@	mov	r1, r0
@	ldr     r0, =bbbb
@	bl      printf
@	ldmfd	sp!, {r0-r3,r12,lr}

	cmp     r0, #0x2000
	ldrge	r1, =Page
	movge	r2, r0, lsr #11
	ldrge	r2, [r1, r2, lsl #2]
	andlt	r2, r0, #0xf800
	addlt	r1, REG_OP_TABLE, #OTOFFS_NES_RAM
	sublt	r2, r1, r2
	str	r2, [REG_OP_TABLE, #OTOFFS_PC_BASE]
	add	REG_PC, r2, r0
.endm


@ updates fceu "timestamp" variable
@ loads cycles to reg, reg!=r1, trashes r1, kills flags
.macro	FLUSH_TIMESTAMP reg
	ands	\reg, REG_CYCLE, #0xff
	beq	1f
	ldr	r1, [REG_OP_TABLE, #OTOFFS_TIMESTAMP]
	orr	REG_CYCLE, REG_CYCLE, \reg, lsl #8	@ put cycles for do_irq_hook
	add	r1, r1, \reg
	bic	REG_CYCLE, REG_CYCLE, #0xff
	str	r1, [REG_OP_TABLE, #OTOFFS_TIMESTAMP]
1:
.endm


@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@
@@@ CYCLE_NEXT
@@@