frontend/cspace_neon.S

   1 /*
   2  * (C) Gražvydas "notaz" Ignotas, 2010
   3  *
   4  * This work is licensed under the terms of any of these licenses
   5  * (at your option):
   6  *  - GNU GPL, version 2 or later.
   7  *  - GNU LGPL, version 2.1 or later.
   8  * See the COPYING file in the top-level directory.
   9  */
  10
  11 #include "arm_features.h"
  12
  13 .text
  14 .align 2
  15
  16 FUNCTION(bgr555_to_rgb565):
  17     pld         [r1]
  18     mov         r3, #0x07c0
  19     vdup.16     q15, r3
  20     subs        r2, r2, #64
  21     blt         btr16_end64
  22 0:
  23     pld         [r1, #64*2]
  24     vldmia      r1!, {q0-q3}
  25     vshl.u16    q4, q0, #11
  26     vshl.u16    q5, q1, #11
  27     vshl.u16    q6, q2, #11
  28     vshl.u16    q7, q3, #11
  29     vsri.u16    q4, q0, #10
  30     vsri.u16    q5, q1, #10
  31     vsri.u16    q6, q2, #10
  32     vsri.u16    q7, q3, #10
  33     vshl.u16    q0, q0, #1
  34     vshl.u16    q1, q1, #1
  35     vshl.u16    q2, q2, #1
  36     vshl.u16    q3, q3, #1
  37     vbit        q4, q0, q15
  38     vbit        q5, q1, q15
  39     vbit        q6, q2, q15
  40     vbit        q7, q3, q15
  41     vstmia      r0!, {q4-q7}
  42     subs        r2, r2, #64
  43     bge         0b
  44
  45 btr16_end64:
  46     adds        r2, r2, #64
  47     bxeq        lr
  48     subs        r2, r2, #16
  49     blt         btr16_end16
  50
  51     @ handle the remainder (reasonably rare)
  52 0:
  53     vld1.16     {q0}, [r1]!
  54     vshl.u16    q1, q0, #11
  55     vshl.u16    q2, q0, #1
  56     vsri.u16    q1, q0, #10
  57     vbit        q1, q2, q15
  58     subs        r2, r2, #16
  59     vst1.16     {q1}, [r0]!
  60     bge         0b
  61
  62 btr16_end16:
  63     adds        r2, r2, #16
  64     bxeq        lr
  65     subs        r2, r2, #8
  66     bxlt        lr
  67
  68     @ very rare
  69     vld1.16     d0, [r1]!
  70     vshl.u16    d1, d0, #11
  71     vshl.u16    d2, d0, #1
  72     vsri.u16    d1, d0, #10
  73     vbit        d1, d2, d30
  74     vst1.16     d1, [r0]!
  75     bx          lr
  76
  77
  78 FUNCTION(bgr888_to_rgb888):
  79     pld         [r1]
  80     @ r2 /= 48
  81     mov         r2, r2, lsr #4
  82     movw        r3, #0x5556
  83     movt        r3, #0x5555
  84     umull       r12,r2, r3, r2
  85 0:
  86     pld         [r1, #48*3]
  87     vld3.8      {d0-d2}, [r1, :64]!
  88     vld3.8      {d3-d5}, [r1, :64]!
  89     vswp        d0, d2
  90     vswp        d3, d5
  91     vst3.8      {d0-d2}, [r0, :64]!
  92     vst3.8      {d3-d5}, [r0, :64]!
  93     subs        r2, r2, #1
  94     bne         0b
  95
  96     bx          lr
  97
  98
  99 FUNCTION(bgr888_to_rgb565):
 100     pld         [r1]
 101     @ r2 /= 48
 102     mov         r2, r2, lsr #4
 103     movw        r3, #0x5556
 104     movt        r3, #0x5555
 105     umull       r12,r2, r3, r2
 106
 107     mov         r3, #0x07e0
 108     vdup.16     q15, r3
 109 0:
 110     pld         [r1, #48*3]
 111     vld3.8      {d1-d3}, [r1, :64]!
 112     vld3.8      {d5-d7}, [r1, :64]!
 113
 114     vshll.u8    q8, d2, #3      @ g
 115     vshll.u8    q9, d6, #3
 116     vshr.u8     d0, d3, #3      @ b
 117     vshr.u8     d4, d7, #3
 118     vzip.8      d0, d1          @ rb
 119     vzip.8      d4, d5
 120     vbit        q0, q8, q15
 121     vbit        q2, q9, q15
 122
 123     vstmia      r0!, {d0,d1}
 124     vstmia      r0!, {d4,d5}
 125     subs        r2, r2, #1
 126     bne         0b
 127
 128     bx          lr
 129
 130
 131 FUNCTION(rgb888_to_rgb565):
 132     pld         [r1]
 133     @ r2 /= 48
 134     mov         r2, r2, lsr #4
 135     movw        r3, #0x5556
 136     movt        r3, #0x5555
 137     umull       r12,r2, r3, r2
 138
 139     mov         r3, #0x07e0
 140     vdup.16     q15, r3
 141 0:
 142     pld         [r1, #48*3]
 143     vld3.8      {d1-d3}, [r1, :64]!
 144     vld3.8      {d5-d7}, [r1, :64]!
 145
 146     vshll.u8    q8, d2, #3      @ g
 147     vshll.u8    q9, d6, #3
 148     vshr.u8     d2, d1, #3      @ b
 149     vshr.u8     d6, d5, #3
 150     vzip.8      d2, d3          @ rb
 151     vzip.8      d6, d7
 152     vbit        q1, q8, q15
 153     vbit        q3, q9, q15
 154
 155     vstmia      r0!, {d2,d3}
 156     vstmia      r0!, {d6,d7}
 157     subs        r2, r2, #1
 158     bne         0b
 159
 160     bx          lr
 161
 162
 163 @ vim:filetype=armasm