frontend/cspace_neon.s

   1 /*
   2  * (C) Gražvydas "notaz" Ignotas, 2010
   3  *
   4  * This work is licensed under the terms of any of these licenses
   5  * (at your option):
   6  *  - GNU GPL, version 2 or later.
   7  *  - GNU LGPL, version 2.1 or later.
   8  * See the COPYING file in the top-level directory.
   9  */
  10
  11 .text
  12 .align 2
  13
  14 .global bgr555_to_rgb565
  15 bgr555_to_rgb565:
  16     mov         r3, #0x07c0
  17     vdup.16     q15, r3
  18     subs        r2, r2, #64
  19     blt         btr16_end64
  20 0:
  21     vldmia      r1!, {q0-q3}
  22     vshl.u16    q4, q0, #11
  23     vshl.u16    q5, q1, #11
  24     vshl.u16    q6, q2, #11
  25     vshl.u16    q7, q3, #11
  26     vsri.u16    q4, q0, #10
  27     vsri.u16    q5, q1, #10
  28     vsri.u16    q6, q2, #10
  29     vsri.u16    q7, q3, #10
  30     vshl.u16    q0, q0, #1
  31     vshl.u16    q1, q1, #1
  32     vshl.u16    q2, q2, #1
  33     vshl.u16    q3, q3, #1
  34     vbit        q4, q0, q15
  35     vbit        q5, q1, q15
  36     vbit        q6, q2, q15
  37     vbit        q7, q3, q15
  38     vstmia      r0!, {q4-q7}
  39     subs        r2, r2, #64
  40     bge         0b
  41
  42 btr16_end64:
  43     adds        r2, r2, #64
  44     bxeq        lr
  45     subs        r2, r2, #16
  46     blt         btr16_end16
  47
  48     @ handle the remainder (reasonably rare)
  49 0:
  50     vld1.16     {q0}, [r1]!
  51     vshl.u16    q1, q0, #11
  52     vshl.u16    q2, q0, #1
  53     vsri.u16    q1, q0, #10
  54     vbit        q1, q2, q15
  55     subs        r2, r2, #16
  56     vst1.16     {q1}, [r0]!
  57     bge         0b
  58
  59 btr16_end16:
  60     adds        r2, r2, #16
  61     bxeq        lr
  62     subs        r2, r2, #8
  63     bxlt        lr
  64
  65     @ very rare
  66     vld1.16     d0, [r1]!
  67     vshl.u16    d1, d0, #11
  68     vshl.u16    d2, d0, #1
  69     vsri.u16    d1, d0, #10
  70     vbit        d1, d2, d30
  71     vst1.16     d1, [r0]!
  72     bx          lr
  73
  74
  75 .global bgr888_to_rgb888
  76 bgr888_to_rgb888:
  77     @ r2 /= 48
  78     mov         r2, r2, lsr #4
  79     movw        r3, #0x5556
  80     movt        r3, #0x5555
  81     umull       r12,r2, r3, r2
  82 0:
  83     vld3.8      {d0-d2}, [r1, :64]!
  84     vld3.8      {d3-d5}, [r1, :64]!
  85     vswp        d0, d2
  86     vswp        d3, d5
  87     vst3.8      {d0-d2}, [r0, :64]!
  88     vst3.8      {d3-d5}, [r0, :64]!
  89     subs        r2, r2, #1
  90     bne         0b
  91
  92     bx          lr
  93
  94
  95 .global bgr888_to_rgb565
  96 bgr888_to_rgb565:
  97     @ r2 /= 48
  98     mov         r2, r2, lsr #4
  99     movw        r3, #0x5556
 100     movt        r3, #0x5555
 101     umull       r12,r2, r3, r2
 102
 103     mov         r3, #0x07e0
 104     vdup.16     q15, r3
 105 0:
 106     vld3.8      {d1-d3}, [r1, :64]!
 107     vld3.8      {d5-d7}, [r1, :64]!
 108
 109     vshll.u8    q8, d2, #3      @ g
 110     vshll.u8    q9, d6, #3
 111     vshr.u8     d0, d3, #3      @ b
 112     vshr.u8     d4, d7, #3
 113     vzip.8      d0, d1          @ rb
 114     vzip.8      d4, d5
 115     vbit        q0, q8, q15
 116     vbit        q2, q9, q15
 117
 118     vstmia      r0!, {d0,d1}
 119     vstmia      r0!, {d4,d5}
 120     subs        r2, r2, #1
 121     bne         0b
 122
 123     bx          lr
 124
 125
 126 @ vim:filetype=armasm