libpcsxcore/new_dynarec/linkage_arm.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas                     *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "linkage_offsets.h"
  25
  26
  27 #ifdef __MACH__
  28 #define dynarec_local           ESYM(dynarec_local)
  29 #define add_link                ESYM(add_link)
  30 #define new_recompile_block     ESYM(new_recompile_block)
  31 #define get_addr                ESYM(get_addr)
  32 #define get_addr_ht             ESYM(get_addr_ht)
  33 #define clean_blocks            ESYM(clean_blocks)
  34 #define gen_interupt            ESYM(gen_interupt)
  35 #define psxException            ESYM(psxException)
  36 #define execI                   ESYM(execI)
  37 #define invalidate_addr         ESYM(invalidate_addr)
  38 #endif
  39
  40         .bss
  41         .align  4
  42         .global dynarec_local
  43         .type   dynarec_local, %object
  44         .size   dynarec_local, LO_dynarec_local_size
  45 dynarec_local:
  46         .space  LO_dynarec_local_size
  47
  48 #define DRC_VAR_(name, vname, size_) \
  49         vname = dynarec_local + LO_##name; \
  50         .global vname; \
  51         .type   vname, %object; \
  52         .size   vname, size_
  53
  54 #define DRC_VAR(name, size_) \
  55         DRC_VAR_(name, ESYM(name), size_)
  56
  57 DRC_VAR(next_interupt, 4)
  58 DRC_VAR(cycle_count, 4)
  59 DRC_VAR(last_count, 4)
  60 DRC_VAR(pending_exception, 4)
  61 DRC_VAR(stop, 4)
  62 DRC_VAR(branch_target, 4)
  63 DRC_VAR(address, 4)
  64 @DRC_VAR(align0, 4) /* unused/alignment */
  65 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  66
  67 /* psxRegs */
  68 @DRC_VAR(reg, 128)
  69 DRC_VAR(lo, 4)
  70 DRC_VAR(hi, 4)
  71 DRC_VAR(reg_cop0, 128)
  72 DRC_VAR(reg_cop2d, 128)
  73 DRC_VAR(reg_cop2c, 128)
  74 DRC_VAR(pcaddr, 4)
  75 @DRC_VAR(code, 4)
  76 @DRC_VAR(cycle, 4)
  77 @DRC_VAR(interrupt, 4)
  78 @DRC_VAR(intCycle, 256)
  79
  80 DRC_VAR(rcnts, 7*4*4)
  81 DRC_VAR(inv_code_start, 4)
  82 DRC_VAR(inv_code_end, 4)
  83 DRC_VAR(mem_rtab, 4)
  84 DRC_VAR(mem_wtab, 4)
  85 DRC_VAR(psxH_ptr, 4)
  86 DRC_VAR(zeromem_ptr, 4)
  87 DRC_VAR(invc_ptr, 4)
  88 DRC_VAR(scratch_buf_ptr, 4)
  89 @DRC_VAR(align1, 8) /* unused/alignment */
  90 DRC_VAR(mini_ht, 256)
  91 DRC_VAR(restore_candidate, 512)
  92
  93
  94 #ifdef TEXRELS_FORBIDDEN
  95         .data
  96         .align 2
  97 ptr_jump_in:
  98         .word   ESYM(jump_in)
  99 ptr_jump_dirty:
 100         .word   ESYM(jump_dirty)
 101 ptr_hash_table:
 102         .word   ESYM(hash_table)
 103 #endif
 104
 105
 106         .syntax unified
 107         .text
 108         .align  2
 109
 110 #ifndef HAVE_ARMV5
 111 .macro blx rd
 112         mov     lr, pc
 113         bx      \rd
 114 .endm
 115 #endif
 116
 117 .macro load_varadr reg var
 118 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 119         movw    \reg, #:lower16:(\var-(1678f+8))
 120         movt    \reg, #:upper16:(\var-(1678f+8))
 121 1678:
 122         add     \reg, pc
 123 #elif defined(HAVE_ARMV7) && !defined(__PIC__)
 124         movw    \reg, #:lower16:\var
 125         movt    \reg, #:upper16:\var
 126 #else
 127         ldr     \reg, =\var
 128 #endif
 129 .endm
 130
 131 .macro load_varadr_ext reg var
 132 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 133         movw    \reg, #:lower16:(ptr_\var-(1678f+8))
 134         movt    \reg, #:upper16:(ptr_\var-(1678f+8))
 135 1678:
 136         ldr     \reg, [pc, \reg]
 137 #else
 138         load_varadr \reg \var
 139 #endif
 140 .endm
 141
 142 .macro mov_16 reg imm
 143 #ifdef HAVE_ARMV7
 144         movw    \reg, #\imm
 145 #else
 146         mov     \reg, #(\imm & 0x00ff)
 147         orr     \reg, #(\imm & 0xff00)
 148 #endif
 149 .endm
 150
 151 .macro mov_24 reg imm
 152 #ifdef HAVE_ARMV7
 153         movw    \reg, #(\imm & 0xffff)
 154         movt    \reg, #(\imm >> 16)
 155 #else
 156         mov     \reg, #(\imm & 0x0000ff)
 157         orr     \reg, #(\imm & 0x00ff00)
 158         orr     \reg, #(\imm & 0xff0000)
 159 #endif
 160 .endm
 161
 162 /* r0 = virtual target address */
 163 /* r1 = instruction to patch */
 164 .macro dyna_linker_main
 165 #ifndef NO_WRITE_EXEC
 166         load_varadr_ext r3, jump_in
 167         /* get_page */
 168         lsr     r2, r0, #12
 169         mov     r6, #4096
 170         bic     r2, r2, #0xe0000
 171         sub     r6, r6, #1
 172         cmp     r2, #0x1000
 173         ldr     r7, [r1]
 174         biclt   r2, #0x0e00
 175         and     r6, r6, r2
 176         cmp     r2, #2048
 177         add     r12, r7, #2
 178         orrcs   r2, r6, #2048
 179         ldr     r5, [r3, r2, lsl #2]
 180         lsl     r12, r12, #8
 181         add     r6, r1, r12, asr #6
 182         mov     r8, #0
 183         /* jump_in lookup */
 184 1:
 185         movs    r4, r5
 186         beq     2f
 187         ldr     r3, [r5]         /* ll_entry .vaddr */
 188         ldrd    r4, r5, [r4, #8] /* ll_entry .next, .addr */
 189         teq     r3, r0
 190         bne     1b
 191         teq     r4, r6
 192         moveq   pc, r4 /* Stale i-cache */
 193         mov     r8, r4
 194         b       1b     /* jump_in may have dupes, continue search */
 195 2:
 196         tst     r8, r8
 197         beq     3f     /* r0 not in jump_in */
 198
 199         mov     r5, r1
 200         mov     r1, r6
 201         bl      add_link
 202         sub     r2, r8, r5
 203         and     r1, r7, #0xff000000
 204         lsl     r2, r2, #6
 205         sub     r1, r1, #2
 206         add     r1, r1, r2, lsr #8
 207         str     r1, [r5]
 208         mov     pc, r8
 209 3:
 210         /* hash_table lookup */
 211         cmp     r2, #2048
 212         load_varadr_ext r3, jump_dirty
 213         eor     r4, r0, r0, lsl #16
 214         lslcc   r2, r0, #9
 215         load_varadr_ext r6, hash_table
 216         lsr     r4, r4, #12
 217         lsrcc   r2, r2, #21
 218         bic     r4, r4, #15
 219         ldr     r5, [r3, r2, lsl #2]
 220         ldr     r7, [r6, r4]!
 221         teq     r7, r0
 222         ldreq   pc, [r6, #8]
 223         ldr     r7, [r6, #4]
 224         teq     r7, r0
 225         ldreq   pc, [r6, #12]
 226         /* jump_dirty lookup */
 227 6:
 228         movs    r4, r5
 229         beq     8f
 230         ldr     r3, [r5]
 231         ldr     r5, [r4, #12]
 232         teq     r3, r0
 233         bne     6b
 234 7:
 235         ldr     r1, [r4, #8]
 236         /* hash_table insert */
 237         ldr     r2, [r6]
 238         ldr     r3, [r6, #8]
 239         str     r0, [r6]
 240         str     r1, [r6, #8]
 241         str     r2, [r6, #4]
 242         str     r3, [r6, #12]
 243         mov     pc, r1
 244 8:
 245 #else
 246         /* XXX: should be able to do better than this... */
 247         bl      get_addr_ht
 248         mov     pc, r0
 249 #endif
 250 .endm
 251
 252
 253 FUNCTION(dyna_linker):
 254         /* r0 = virtual target address */
 255         /* r1 = instruction to patch */
 256         dyna_linker_main
 257
 258         mov     r4, r0
 259         mov     r5, r1
 260         bl      new_recompile_block
 261         tst     r0, r0
 262         mov     r0, r4
 263         mov     r1, r5
 264         beq     dyna_linker
 265         /* pagefault */
 266         mov     r1, r0
 267         mov     r2, #8
 268         .size   dyna_linker, .-dyna_linker
 269
 270 FUNCTION(exec_pagefault):
 271         /* r0 = instruction pointer */
 272         /* r1 = fault address */
 273         /* r2 = cause */
 274         ldr     r3, [fp, #LO_reg_cop0+48] /* Status */
 275         mvn     r6, #0xF000000F
 276         ldr     r4, [fp, #LO_reg_cop0+16] /* Context */
 277         bic     r6, r6, #0x0F800000
 278         str     r0, [fp, #LO_reg_cop0+56] /* EPC */
 279         orr     r3, r3, #2
 280         str     r1, [fp, #LO_reg_cop0+32] /* BadVAddr */
 281         bic     r4, r4, r6
 282         str     r3, [fp, #LO_reg_cop0+48] /* Status */
 283         and     r5, r6, r1, lsr #9
 284         str     r2, [fp, #LO_reg_cop0+52] /* Cause */
 285         and     r1, r1, r6, lsl #9
 286         str     r1, [fp, #LO_reg_cop0+40] /* EntryHi */
 287         orr     r4, r4, r5
 288         str     r4, [fp, #LO_reg_cop0+16] /* Context */
 289         mov     r0, #0x80000000
 290         bl      get_addr_ht
 291         mov     pc, r0
 292         .size   exec_pagefault, .-exec_pagefault
 293
 294 /* Special dynamic linker for the case where a page fault
 295    may occur in a branch delay slot */
 296 FUNCTION(dyna_linker_ds):
 297         /* r0 = virtual target address */
 298         /* r1 = instruction to patch */
 299         dyna_linker_main
 300
 301         mov     r4, r0
 302         bic     r0, r0, #7
 303         mov     r5, r1
 304         orr     r0, r0, #1
 305         bl      new_recompile_block
 306         tst     r0, r0
 307         mov     r0, r4
 308         mov     r1, r5
 309         beq     dyna_linker_ds
 310         /* pagefault */
 311         bic     r1, r0, #7
 312         mov     r2, #0x80000008 /* High bit set indicates pagefault in delay slot */
 313         sub     r0, r1, #4
 314         b       exec_pagefault
 315         .size   dyna_linker_ds, .-dyna_linker_ds
 316
 317         .align  2
 318
 319 FUNCTION(jump_vaddr_r0):
 320         eor     r2, r0, r0, lsl #16
 321         b       jump_vaddr
 322         .size   jump_vaddr_r0, .-jump_vaddr_r0
 323 FUNCTION(jump_vaddr_r1):
 324         eor     r2, r1, r1, lsl #16
 325         mov     r0, r1
 326         b       jump_vaddr
 327         .size   jump_vaddr_r1, .-jump_vaddr_r1
 328 FUNCTION(jump_vaddr_r2):
 329         mov     r0, r2
 330         eor     r2, r2, r2, lsl #16
 331         b       jump_vaddr
 332         .size   jump_vaddr_r2, .-jump_vaddr_r2
 333 FUNCTION(jump_vaddr_r3):
 334         eor     r2, r3, r3, lsl #16
 335         mov     r0, r3
 336         b       jump_vaddr
 337         .size   jump_vaddr_r3, .-jump_vaddr_r3
 338 FUNCTION(jump_vaddr_r4):
 339         eor     r2, r4, r4, lsl #16
 340         mov     r0, r4
 341         b       jump_vaddr
 342         .size   jump_vaddr_r4, .-jump_vaddr_r4
 343 FUNCTION(jump_vaddr_r5):
 344         eor     r2, r5, r5, lsl #16
 345         mov     r0, r5
 346         b       jump_vaddr
 347         .size   jump_vaddr_r5, .-jump_vaddr_r5
 348 FUNCTION(jump_vaddr_r6):
 349         eor     r2, r6, r6, lsl #16
 350         mov     r0, r6
 351         b       jump_vaddr
 352         .size   jump_vaddr_r6, .-jump_vaddr_r6
 353 FUNCTION(jump_vaddr_r8):
 354         eor     r2, r8, r8, lsl #16
 355         mov     r0, r8
 356         b       jump_vaddr
 357         .size   jump_vaddr_r8, .-jump_vaddr_r8
 358 FUNCTION(jump_vaddr_r9):
 359         eor     r2, r9, r9, lsl #16
 360         mov     r0, r9
 361         b       jump_vaddr
 362         .size   jump_vaddr_r9, .-jump_vaddr_r9
 363 FUNCTION(jump_vaddr_r10):
 364         eor     r2, r10, r10, lsl #16
 365         mov     r0, r10
 366         b       jump_vaddr
 367         .size   jump_vaddr_r10, .-jump_vaddr_r10
 368 FUNCTION(jump_vaddr_r12):
 369         eor     r2, r12, r12, lsl #16
 370         mov     r0, r12
 371         b       jump_vaddr
 372         .size   jump_vaddr_r12, .-jump_vaddr_r12
 373 FUNCTION(jump_vaddr_r7):
 374         eor     r2, r7, r7, lsl #16
 375         add     r0, r7, #0
 376         .size   jump_vaddr_r7, .-jump_vaddr_r7
 377 FUNCTION(jump_vaddr):
 378         load_varadr_ext r1, hash_table
 379         mvn     r3, #15
 380         and     r2, r3, r2, lsr #12
 381         ldr     r2, [r1, r2]!
 382         teq     r2, r0
 383         ldreq   pc, [r1, #8]
 384         ldr     r2, [r1, #4]
 385         teq     r2, r0
 386         ldreq   pc, [r1, #12]
 387         str     r10, [fp, #LO_cycle_count]
 388         bl      get_addr
 389         ldr     r10, [fp, #LO_cycle_count]
 390         mov     pc, r0
 391         .size   jump_vaddr, .-jump_vaddr
 392
 393         .align  2
 394
 395 FUNCTION(verify_code_ds):
 396         str     r8, [fp, #LO_branch_target]
 397 FUNCTION(verify_code):
 398         /* r1 = source */
 399         /* r2 = target */
 400         /* r3 = length */
 401         tst     r3, #4
 402         mov     r4, #0
 403         add     r3, r1, r3
 404         mov     r5, #0
 405         ldrne   r4, [r1], #4
 406         mov     r12, #0
 407         ldrne   r5, [r2], #4
 408         teq     r1, r3
 409         beq     .D3
 410 .D2:
 411         ldr     r7, [r1], #4
 412         eor     r9, r4, r5
 413         ldr     r8, [r2], #4
 414         orrs    r9, r9, r12
 415         bne     .D4
 416         ldr     r4, [r1], #4
 417         eor     r12, r7, r8
 418         ldr     r5, [r2], #4
 419         cmp     r1, r3
 420         bcc     .D2
 421         teq     r7, r8
 422 .D3:
 423         teqeq   r4, r5
 424 .D4:
 425         ldr     r8, [fp, #LO_branch_target]
 426         moveq   pc, lr
 427 .D5:
 428         bl      get_addr
 429         mov     pc, r0
 430         .size   verify_code, .-verify_code
 431         .size   verify_code_ds, .-verify_code_ds
 432
 433         .align  2
 434 FUNCTION(cc_interrupt):
 435         ldr     r0, [fp, #LO_last_count]
 436         mov     r1, #0
 437         mov     r2, #0x1fc
 438         add     r10, r0, r10
 439         str     r1, [fp, #LO_pending_exception]
 440         and     r2, r2, r10, lsr #17
 441         add     r3, fp, #LO_restore_candidate
 442         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 443 @@      str     r10, [fp, #LO_reg_cop0+36]      /* Count */
 444         ldr     r4, [r2, r3]
 445         mov     r10, lr
 446         tst     r4, r4
 447         bne     .E4
 448 .E1:
 449         bl      gen_interupt
 450         mov     lr, r10
 451         ldr     r10, [fp, #LO_cycle]
 452         ldr     r0, [fp, #LO_next_interupt]
 453         ldr     r1, [fp, #LO_pending_exception]
 454         ldr     r2, [fp, #LO_stop]
 455         str     r0, [fp, #LO_last_count]
 456         sub     r10, r10, r0
 457         tst     r2, r2
 458         ldmfdne sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 459         tst     r1, r1
 460         moveq   pc, lr
 461 .E2:
 462         ldr     r0, [fp, #LO_pcaddr]
 463         bl      get_addr_ht
 464         mov     pc, r0
 465 .E4:
 466         /* Move 'dirty' blocks to the 'clean' list */
 467         lsl     r5, r2, #3
 468         str     r1, [r2, r3]
 469 .E5:
 470         lsrs    r4, r4, #1
 471         mov     r0, r5
 472         add     r5, r5, #1
 473         blcs    clean_blocks
 474         tst     r5, #31
 475         bne     .E5
 476         b       .E1
 477         .size   cc_interrupt, .-cc_interrupt
 478
 479         .align  2
 480 FUNCTION(fp_exception):
 481         mov     r2, #0x10000000
 482 .E7:
 483         ldr     r1, [fp, #LO_reg_cop0+48] /* Status */
 484         mov     r3, #0x80000000
 485         str     r0, [fp, #LO_reg_cop0+56] /* EPC */
 486         orr     r1, #2
 487         add     r2, r2, #0x2c
 488         str     r1, [fp, #LO_reg_cop0+48] /* Status */
 489         str     r2, [fp, #LO_reg_cop0+52] /* Cause */
 490         add     r0, r3, #0x80
 491         bl      get_addr_ht
 492         mov     pc, r0
 493         .size   fp_exception, .-fp_exception
 494         .align  2
 495 FUNCTION(fp_exception_ds):
 496         mov     r2, #0x90000000 /* Set high bit if delay slot */
 497         b       .E7
 498         .size   fp_exception_ds, .-fp_exception_ds
 499
 500         .align  2
 501 FUNCTION(jump_syscall):
 502         ldr     r1, [fp, #LO_reg_cop0+48] /* Status */
 503         mov     r3, #0x80000000
 504         str     r0, [fp, #LO_reg_cop0+56] /* EPC */
 505         orr     r1, #2
 506         mov     r2, #0x20
 507         str     r1, [fp, #LO_reg_cop0+48] /* Status */
 508         str     r2, [fp, #LO_reg_cop0+52] /* Cause */
 509         add     r0, r3, #0x80
 510         bl      get_addr_ht
 511         mov     pc, r0
 512         .size   jump_syscall, .-jump_syscall
 513         .align  2
 514
 515         .align  2
 516 FUNCTION(jump_syscall_hle):
 517         str     r0, [fp, #LO_pcaddr] /* PC must be set to EPC for psxException */
 518         ldr     r2, [fp, #LO_last_count]
 519         mov     r1, #0    /* in delay slot */
 520         add     r2, r2, r10
 521         mov     r0, #0x20 /* cause */
 522         str     r2, [fp, #LO_cycle] /* PCSX cycle counter */
 523         bl      psxException
 524
 525         /* note: psxException might do recursive recompiler call from it's HLE code,
 526          * so be ready for this */
 527 pcsx_return:
 528         ldr     r1, [fp, #LO_next_interupt]
 529         ldr     r10, [fp, #LO_cycle]
 530         ldr     r0, [fp, #LO_pcaddr]
 531         sub     r10, r10, r1
 532         str     r1, [fp, #LO_last_count]
 533         bl      get_addr_ht
 534         mov     pc, r0
 535         .size   jump_syscall_hle, .-jump_syscall_hle
 536
 537         .align  2
 538 FUNCTION(jump_hlecall):
 539         ldr     r2, [fp, #LO_last_count]
 540         str     r0, [fp, #LO_pcaddr]
 541         add     r2, r2, r10
 542         adr     lr, pcsx_return
 543         str     r2, [fp, #LO_cycle] /* PCSX cycle counter */
 544         bx      r1
 545         .size   jump_hlecall, .-jump_hlecall
 546
 547         .align  2
 548 FUNCTION(jump_intcall):
 549         ldr     r2, [fp, #LO_last_count]
 550         str     r0, [fp, #LO_pcaddr]
 551         add     r2, r2, r10
 552         adr     lr, pcsx_return
 553         str     r2, [fp, #LO_cycle] /* PCSX cycle counter */
 554         b       execI
 555         .size   jump_hlecall, .-jump_hlecall
 556
 557         .align  2
 558 FUNCTION(new_dyna_leave):
 559         ldr     r0, [fp, #LO_last_count]
 560         add     r12, fp, #28
 561         add     r10, r0, r10
 562         str     r10, [fp, #LO_cycle]
 563         ldmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 564         .size   new_dyna_leave, .-new_dyna_leave
 565
 566         .align  2
 567 FUNCTION(invalidate_addr_r0):
 568         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 569         b       invalidate_addr_call
 570         .size   invalidate_addr_r0, .-invalidate_addr_r0
 571         .align  2
 572 FUNCTION(invalidate_addr_r1):
 573         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 574         mov     r0, r1
 575         b       invalidate_addr_call
 576         .size   invalidate_addr_r1, .-invalidate_addr_r1
 577         .align  2
 578 FUNCTION(invalidate_addr_r2):
 579         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 580         mov     r0, r2
 581         b       invalidate_addr_call
 582         .size   invalidate_addr_r2, .-invalidate_addr_r2
 583         .align  2
 584 FUNCTION(invalidate_addr_r3):
 585         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 586         mov     r0, r3
 587         b       invalidate_addr_call
 588         .size   invalidate_addr_r3, .-invalidate_addr_r3
 589         .align  2
 590 FUNCTION(invalidate_addr_r4):
 591         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 592         mov     r0, r4
 593         b       invalidate_addr_call
 594         .size   invalidate_addr_r4, .-invalidate_addr_r4
 595         .align  2
 596 FUNCTION(invalidate_addr_r5):
 597         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 598         mov     r0, r5
 599         b       invalidate_addr_call
 600         .size   invalidate_addr_r5, .-invalidate_addr_r5
 601         .align  2
 602 FUNCTION(invalidate_addr_r6):
 603         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 604         mov     r0, r6
 605         b       invalidate_addr_call
 606         .size   invalidate_addr_r6, .-invalidate_addr_r6
 607         .align  2
 608 FUNCTION(invalidate_addr_r7):
 609         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 610         mov     r0, r7
 611         b       invalidate_addr_call
 612         .size   invalidate_addr_r7, .-invalidate_addr_r7
 613         .align  2
 614 FUNCTION(invalidate_addr_r8):
 615         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 616         mov     r0, r8
 617         b       invalidate_addr_call
 618         .size   invalidate_addr_r8, .-invalidate_addr_r8
 619         .align  2
 620 FUNCTION(invalidate_addr_r9):
 621         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 622         mov     r0, r9
 623         b       invalidate_addr_call
 624         .size   invalidate_addr_r9, .-invalidate_addr_r9
 625         .align  2
 626 FUNCTION(invalidate_addr_r10):
 627         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 628         mov     r0, r10
 629         b       invalidate_addr_call
 630         .size   invalidate_addr_r10, .-invalidate_addr_r10
 631         .align  2
 632 FUNCTION(invalidate_addr_r12):
 633         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 634         mov     r0, r12
 635         .size   invalidate_addr_r12, .-invalidate_addr_r12
 636         .align  2
 637 invalidate_addr_call:
 638         ldr     r12, [fp, #LO_inv_code_start]
 639         ldr     lr, [fp, #LO_inv_code_end]
 640         cmp     r0, r12
 641         cmpcs   lr, r0
 642         blcc    invalidate_addr
 643         ldmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
 644         .size   invalidate_addr_call, .-invalidate_addr_call
 645
 646         .align  2
 647 FUNCTION(new_dyna_start):
 648         /* ip is stored to conform EABI alignment */
 649         stmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
 650         mov     fp, r0 /* dynarec_local */
 651         ldr     r0, [fp, #LO_pcaddr]
 652         bl      get_addr_ht
 653         ldr     r1, [fp, #LO_next_interupt]
 654         ldr     r10, [fp, #LO_cycle]
 655         str     r1, [fp, #LO_last_count]
 656         sub     r10, r10, r1
 657         mov     pc, r0
 658         .size   new_dyna_start, .-new_dyna_start
 659
 660 /* --------------------------------------- */
 661
 662 .align  2
 663
 664 .macro pcsx_read_mem readop tab_shift
 665         /* r0 = address, r1 = handler_tab, r2 = cycles */
 666         lsl     r3, r0, #20
 667         lsr     r3, #(20+\tab_shift)
 668         ldr     r12, [fp, #LO_last_count]
 669         ldr     r1, [r1, r3, lsl #2]
 670         add     r2, r2, r12
 671         lsls    r1, #1
 672 .if \tab_shift == 1
 673         lsl     r3, #1
 674         \readop r0, [r1, r3]
 675 .else
 676         \readop r0, [r1, r3, lsl #\tab_shift]
 677 .endif
 678         movcc   pc, lr
 679         str     r2, [fp, #LO_cycle]
 680         bx      r1
 681 .endm
 682
 683 FUNCTION(jump_handler_read8):
 684         add     r1, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 685         pcsx_read_mem ldrbcc, 0
 686
 687 FUNCTION(jump_handler_read16):
 688         add     r1, #0x1000/4*4              @ shift to r16 part
 689         pcsx_read_mem ldrhcc, 1
 690
 691 FUNCTION(jump_handler_read32):
 692         pcsx_read_mem ldrcc, 2
 693
 694
 695 .macro pcsx_write_mem wrtop tab_shift
 696         /* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
 697         lsl     r12,r0, #20
 698         lsr     r12, #(20+\tab_shift)
 699         ldr     r3, [r3, r12, lsl #2]
 700         str     r0, [fp, #LO_address]      @ some handlers still need it..
 701         lsls    r3, #1
 702         mov     r0, r2                                @ cycle return in case of direct store
 703 .if \tab_shift == 1
 704         lsl     r12, #1
 705         \wrtop  r1, [r3, r12]
 706 .else
 707         \wrtop  r1, [r3, r12, lsl #\tab_shift]
 708 .endif
 709         movcc   pc, lr
 710         ldr     r12, [fp, #LO_last_count]
 711         mov     r0, r1
 712         add     r2, r2, r12
 713         push    {r2, lr}
 714         str     r2, [fp, #LO_cycle]
 715         blx     r3
 716
 717         ldr     r0, [fp, #LO_next_interupt]
 718         pop     {r2, lr}
 719         str     r0, [fp, #LO_last_count]
 720         sub     r0, r2, r0
 721         bx      lr
 722 .endm
 723
 724 FUNCTION(jump_handler_write8):
 725         add     r3, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 726         pcsx_write_mem strbcc, 0
 727
 728 FUNCTION(jump_handler_write16):
 729         add     r3, #0x1000/4*4              @ shift to r16 part
 730         pcsx_write_mem strhcc, 1
 731
 732 FUNCTION(jump_handler_write32):
 733         pcsx_write_mem strcc, 2
 734
 735 FUNCTION(jump_handler_write_h):
 736         /* r0 = address, r1 = data, r2 = cycles, r3 = handler */
 737         ldr     r12, [fp, #LO_last_count]
 738         str     r0, [fp, #LO_address]      @ some handlers still need it..
 739         add     r2, r2, r12
 740         mov     r0, r1
 741         push    {r2, lr}
 742         str     r2, [fp, #LO_cycle]
 743         blx     r3
 744
 745         ldr     r0, [fp, #LO_next_interupt]
 746         pop     {r2, lr}
 747         str     r0, [fp, #LO_last_count]
 748         sub     r0, r2, r0
 749         bx      lr
 750
 751 FUNCTION(jump_handle_swl):
 752         /* r0 = address, r1 = data, r2 = cycles */
 753         ldr     r3, [fp, #LO_mem_wtab]
 754         mov     r12,r0,lsr #12
 755         ldr     r3, [r3, r12, lsl #2]
 756         lsls    r3, #1
 757         bcs     4f
 758         add     r3, r0, r3
 759         mov     r0, r2
 760         tst     r3, #2
 761         beq     101f
 762         tst     r3, #1
 763         beq     2f
 764 3:
 765         str     r1, [r3, #-3]
 766         bx      lr
 767 2:
 768         lsr     r2, r1, #8
 769         lsr     r1, #24
 770         strh    r2, [r3, #-2]
 771         strb    r1, [r3]
 772         bx      lr
 773 101:
 774         tst     r3, #1
 775         lsrne   r1, #16         @ 1
 776         lsreq   r12, r1, #24    @ 0
 777         strhne  r1, [r3, #-1]
 778         strbeq  r12, [r3]
 779         bx      lr
 780 4:
 781         mov     r0, r2
 782 @       b       abort
 783         bx      lr              @ TODO?
 784
 785
 786 FUNCTION(jump_handle_swr):
 787         /* r0 = address, r1 = data, r2 = cycles */
 788         ldr     r3, [fp, #LO_mem_wtab]
 789         mov     r12,r0,lsr #12
 790         ldr     r3, [r3, r12, lsl #2]
 791         lsls    r3, #1
 792         bcs     4f
 793         add     r3, r0, r3
 794         and     r12,r3, #3
 795         mov     r0, r2
 796         cmp     r12,#2
 797         strbgt  r1, [r3]        @ 3
 798         strheq  r1, [r3]        @ 2
 799         cmp     r12,#1
 800         strlt   r1, [r3]        @ 0
 801         bxne    lr
 802         lsr     r2, r1, #8      @ 1
 803         strb    r1, [r3]
 804         strh    r2, [r3, #1]
 805         bx      lr
 806 4:
 807         mov     r0, r2
 808 @       b       abort
 809         bx      lr              @ TODO?
 810
 811
 812 .macro rcntx_read_mode0 num
 813         /* r0 = address, r2 = cycles */
 814         ldr     r3, [fp, #LO_rcnts+6*4+7*4*\num] @ cycleStart
 815         mov     r0, r2, lsl #16
 816         sub     r0, r0, r3, lsl #16
 817         lsr     r0, #16
 818         bx      lr
 819 .endm
 820
 821 FUNCTION(rcnt0_read_count_m0):
 822         rcntx_read_mode0 0
 823
 824 FUNCTION(rcnt1_read_count_m0):
 825         rcntx_read_mode0 1
 826
 827 FUNCTION(rcnt2_read_count_m0):
 828         rcntx_read_mode0 2
 829
 830 FUNCTION(rcnt0_read_count_m1):
 831         /* r0 = address, r2 = cycles */
 832         ldr     r3, [fp, #LO_rcnts+6*4+7*4*0] @ cycleStart
 833         mov_16  r1, 0x3334
 834         sub     r2, r2, r3
 835         mul     r0, r1, r2              @ /= 5
 836         lsr     r0, #16
 837         bx      lr
 838
 839 FUNCTION(rcnt1_read_count_m1):
 840         /* r0 = address, r2 = cycles */
 841         ldr     r3, [fp, #LO_rcnts+6*4+7*4*1]
 842         mov_24  r1, 0x1e6cde
 843         sub     r2, r2, r3
 844         umull   r3, r0, r1, r2          @ ~ /= hsync_cycles, max ~0x1e6cdd
 845         bx      lr
 846
 847 FUNCTION(rcnt2_read_count_m1):
 848         /* r0 = address, r2 = cycles */
 849         ldr     r3, [fp, #LO_rcnts+6*4+7*4*2]
 850         mov     r0, r2, lsl #16-3
 851         sub     r0, r0, r3, lsl #16-3
 852         lsr     r0, #16                 @ /= 8
 853         bx      lr
 854
 855 @ vim:filetype=armasm