deps/libchdr/deps/zstd-1.5.5/build/cmake/CMakeLists.txt

   1 # ################################################################
   2 # Copyright (c) Meta Platforms, Inc. and affiliates.
   3 # All rights reserved.
   4 #
   5 # This source code is licensed under both the BSD-style license (found in the
   6 # LICENSE file in the root directory of this source tree) and the GPLv2 (found
   7 # in the COPYING file in the root directory of this source tree).
   8 # ################################################################
   9
  10 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
  11
  12 # As of 2018-12-26 ZSTD has been validated to build with cmake version 3.13.2 new policies.
  13 # Set and use the newest cmake policies that are validated to work
  14 set(ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION "3")
  15 set(ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION "13") #Policies never changed at PATCH level
  16 if("${CMAKE_MAJOR_VERSION}" LESS 3)
  17   set(ZSTD_CMAKE_POLICY_VERSION "${CMAKE_VERSION}")
  18 elseif( "${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}" EQUAL "${CMAKE_MAJOR_VERSION}" AND
  19         "${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}" GREATER "${CMAKE_MINOR_VERSION}")
  20     set(ZSTD_CMAKE_POLICY_VERSION "${CMAKE_VERSION}")
  21 else()
  22     set(ZSTD_CMAKE_POLICY_VERSION "${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}.${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}.0")
  23 endif()
  24 cmake_policy(VERSION ${ZSTD_CMAKE_POLICY_VERSION})
  25
  26 set(CMAKE_BUILD_WITH_INSTALL_RPATH on)
  27
  28 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules")
  29 set(ZSTD_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../..")
  30 set(LIBRARY_DIR ${ZSTD_SOURCE_DIR}/lib)
  31 # Parse version
  32 include(GetZstdLibraryVersion)
  33 GetZstdLibraryVersion(${LIBRARY_DIR}/zstd.h zstd_VERSION_MAJOR zstd_VERSION_MINOR zstd_VERSION_PATCH)
  34
  35 if( CMAKE_MAJOR_VERSION LESS 3 )
  36   ## Provide cmake 3+ behavior for older versions of cmake
  37   project(zstd)
  38   set(PROJECT_VERSION_MAJOR ${zstd_VERSION_MAJOR})
  39   set(PROJECT_VERSION_MINOR ${zstd_VERSION_MINOR})
  40   set(PROJECT_VERSION_PATCH ${zstd_VERSION_PATCH})
  41   set(PROJECT_VERSION "${zstd_VERSION_MAJOR}.${zstd_VERSION_MINOR}.${zstd_VERSION_PATCH}")
  42   enable_language(C)   # Main library is in C
  43   enable_language(ASM) # And ASM
  44   enable_language(CXX) # Testing contributed code also utilizes CXX
  45 else()
  46   project(zstd
  47     VERSION "${zstd_VERSION_MAJOR}.${zstd_VERSION_MINOR}.${zstd_VERSION_PATCH}"
  48     LANGUAGES C   # Main library is in C
  49               ASM # And ASM
  50               CXX # Testing contributed code also utilizes CXX
  51     )
  52 endif()
  53 message(STATUS "ZSTD VERSION: ${zstd_VERSION}")
  54 set(zstd_HOMEPAGE_URL "https://facebook.github.io/zstd")
  55 set(zstd_DESCRIPTION  "Zstandard is a real-time compression algorithm, providing high compression ratios.")
  56
  57 # Set a default build type if none was specified
  58 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  59   message(STATUS "Setting build type to 'Release' as none was specified.")
  60   set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
  61   # Set the possible values of build type for cmake-gui
  62   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  63 endif()
  64
  65 include(GNUInstallDirs)
  66
  67 #-----------------------------------------------------------------------------
  68 # Add extra compilation flags
  69 #-----------------------------------------------------------------------------
  70 include(AddZstdCompilationFlags)
  71 ADD_ZSTD_COMPILATION_FLAGS()
  72
  73 # Always hide XXHash symbols
  74 add_definitions(-DXXH_NAMESPACE=ZSTD_)
  75
  76 #-----------------------------------------------------------------------------
  77 # Installation variables
  78 #-----------------------------------------------------------------------------
  79 message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
  80 message(STATUS "CMAKE_INSTALL_LIBDIR: ${CMAKE_INSTALL_LIBDIR}")
  81
  82 #-----------------------------------------------------------------------------
  83 # Options
  84 #-----------------------------------------------------------------------------
  85
  86 # Legacy support
  87 option(ZSTD_LEGACY_SUPPORT "LEGACY SUPPORT" ON)
  88
  89 if (ZSTD_LEGACY_SUPPORT)
  90     message(STATUS "ZSTD_LEGACY_SUPPORT defined!")
  91     set(ZSTD_LEGACY_LEVEL 5 CACHE STRING "")
  92     add_definitions(-DZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_LEVEL})
  93 else ()
  94     message(STATUS "ZSTD_LEGACY_SUPPORT not defined!")
  95     add_definitions(-DZSTD_LEGACY_SUPPORT=0)
  96 endif ()
  97
  98 if (ANDROID)
  99     set(ZSTD_MULTITHREAD_SUPPORT_DEFAULT OFF)
 100 else()
 101     set(ZSTD_MULTITHREAD_SUPPORT_DEFAULT ON)
 102 endif()
 103
 104 # Multi-threading support
 105 option(ZSTD_MULTITHREAD_SUPPORT "MULTITHREADING SUPPORT" ${ZSTD_MULTITHREAD_SUPPORT_DEFAULT})
 106
 107 if (ZSTD_MULTITHREAD_SUPPORT)
 108     message(STATUS "ZSTD_MULTITHREAD_SUPPORT is enabled")
 109 else ()
 110     message(STATUS "ZSTD_MULTITHREAD_SUPPORT is disabled")
 111 endif ()
 112
 113 option(ZSTD_BUILD_PROGRAMS "BUILD PROGRAMS" ON)
 114 option(ZSTD_BUILD_CONTRIB "BUILD CONTRIB" OFF)
 115
 116 # Respect the conventional CMake option for enabling tests if it was specified on the first configure
 117 if (BUILD_TESTING)
 118     set(ZSTD_BUILD_TESTS_default ON)
 119 else()
 120     set(ZSTD_BUILD_TESTS_default OFF)
 121 endif()
 122 option(ZSTD_BUILD_TESTS "BUILD TESTS" ${ZSTD_BUILD_TESTS_default})
 123 if (MSVC)
 124     option(ZSTD_USE_STATIC_RUNTIME "LINK TO STATIC RUN-TIME LIBRARIES" OFF)
 125 endif ()
 126
 127 #-----------------------------------------------------------------------------
 128 # External dependencies
 129 #-----------------------------------------------------------------------------
 130 if (ZSTD_MULTITHREAD_SUPPORT AND UNIX)
 131     set(THREADS_PREFER_PTHREAD_FLAG ON)
 132     find_package(Threads REQUIRED)
 133     if(CMAKE_USE_PTHREADS_INIT)
 134         set(THREADS_LIBS "${CMAKE_THREAD_LIBS_INIT}")
 135     else()
 136         message(SEND_ERROR "ZSTD currently does not support thread libraries other than pthreads")
 137     endif()
 138 endif ()
 139
 140 #-----------------------------------------------------------------------------
 141 # Add source directories
 142 #-----------------------------------------------------------------------------
 143 add_subdirectory(lib)
 144
 145 option(ZSTD_PROGRAMS_LINK_SHARED "PROGRAMS LINK SHARED" OFF)
 146
 147 if (ZSTD_BUILD_PROGRAMS)
 148     if (NOT ZSTD_BUILD_STATIC AND NOT ZSTD_PROGRAMS_LINK_SHARED)
 149         message(SEND_ERROR "You need to build static library to build zstd CLI")
 150     elseif(NOT ZSTD_BUILD_SHARED AND ZSTD_PROGRAMS_LINK_SHARED)
 151         message(SEND_ERROR "You need to build shared library to build zstd CLI")
 152     endif ()
 153
 154     add_subdirectory(programs)
 155 endif ()
 156
 157 if (ZSTD_BUILD_TESTS)
 158     enable_testing()
 159     if (NOT ZSTD_BUILD_STATIC)
 160         message(SEND_ERROR "You need to build static library to build tests")
 161     endif ()
 162
 163     add_subdirectory(tests)
 164 endif ()
 165
 166 if (ZSTD_BUILD_CONTRIB)
 167     add_subdirectory(contrib)
 168 endif ()
 169
 170 #-----------------------------------------------------------------------------
 171 # Add clean-all target
 172 #-----------------------------------------------------------------------------
 173 add_custom_target(clean-all
 174    COMMAND ${CMAKE_BUILD_TOOL} clean
 175    COMMAND rm -rf ${CMAKE_BINARY_DIR}/
 176 )
 177
 178 #-----------------------------------------------------------------------------
 179 # Generate Package Config files
 180 #
 181 # This section is based on the boiler plate code from:
 182 # https://cmake.org/cmake/help/latest/manual/cmake-packages.7.html#creating-packages
 183 #-----------------------------------------------------------------------------
 184 include(CMakePackageConfigHelpers)
 185 write_basic_package_version_file(
 186     "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake"
 187     VERSION ${zstd_VERSION}
 188     COMPATIBILITY SameMajorVersion
 189     )
 190
 191 # A Package Config file that works from the build directory
 192 export(EXPORT zstdExports
 193     FILE "${CMAKE_CURRENT_BINARY_DIR}/zstdTargets.cmake"
 194     NAMESPACE zstd::
 195     )
 196 configure_file(zstdConfig.cmake
 197     "${CMAKE_CURRENT_BINARY_DIR}/zstdConfig.cmake"
 198     COPYONLY
 199     )
 200
 201 # A Package Config file that works from the installation directory
 202 set(ConfigPackageLocation ${CMAKE_INSTALL_LIBDIR}/cmake/zstd)
 203 install(EXPORT zstdExports
 204     FILE zstdTargets.cmake
 205     NAMESPACE zstd::
 206     DESTINATION ${ConfigPackageLocation}
 207     )
 208 install(FILES
 209     zstdConfig.cmake
 210     "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake"
 211     DESTINATION ${ConfigPackageLocation}
 212     )