[pcsx_rearmed.git] / deps / lightning / configure.ac

dnl
dnl Copyright 2000, 2001, 2002, 2012-2019 Free Software Foundation, Inc.
dnl
dnl This file is part of GNU lightning.
dnl
dnl GNU lightning is free software; you can redistribute it and/or modify it
dnl under the terms of the GNU Lesser General Public License as published
dnl by the Free Software Foundation; either version 3, or (at your option)
dnl any later version.
dnl
dnl GNU lightning is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
dnl License for more details.
dnl

AC_PREREQ(2.64)
AC_INIT([GNU lightning], 2.1.3, pcpa@gnu.org, lightning)
AC_CONFIG_AUX_DIR([build-aux])
AC_CANONICAL_TARGET
AC_CONFIG_SRCDIR([Makefile.am])
AM_INIT_AUTOMAKE([dist-bzip2])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_HEADERS([config.h])

AC_PROG_CC
gl_EARLY
AM_PROG_AR
LT_INIT
gl_INIT

case "$target_cpu" in
    ia64)
	case "$host_os" in
	    # Only supported mode
	    *hpux*)
		LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -mlp64"		;;
	    *)					;;
	esac					;;
    *mips*)
	case "$host_os" in
	    # (Hack) Flags to pass configure with gcc 3.x
	    # Should not set LIGHTNINT_CFLAGS
	    *irix*)
		CFLAGS="$CFLAGS -D__c99 -Drestrict=";;
	    *)					;;
	esac					;;
    alpha*)
	case "$host_os" in
	    osf*)
		# Get proper varargs and mmap prototypes and definitions
		CFLAGS="$CFLAGS -D_ANSI_C_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_OSF_SOURCE -D_POSIX_C_SOURCE=199309L"
		# Want to generate NaN with 0.0/0.0 and Inf with 1.0/0.0
		if test x$GCC = "xyes"; then
		    CFLAGS="$CFLAGS -mieee"
		else
		    CFLAGS="$CFLAGS -ieee_with_no_inexact"
		fi				;;
	    *)					;;
	esac					;;
    *)						;;
esac

AC_CHECK_FUNCS(mremap ffsl getopt_long_only isnan isinf,,)

AC_CHECK_HEADERS([getopt.h stdint.h],,,)

AC_ARG_ENABLE(disassembler,
	      AS_HELP_STRING([--enable-disassembler],
			     [Enable jit disassembler using binutils]),
	      [DISASSEMBLER=$enableval], [DISASSEMBLER=auto])
if test "x$DISASSEMBLER" != "xno"; then
    # FIXME need to check for libiberty first or will fail to link
    AC_CHECK_LIB(iberty, htab_try_create, ,
		 [HAVE_IBERTY="no"])
    AC_CHECK_LIB(bfd, bfd_init, ,
		 [HAVE_BFD="no"])
    AC_CHECK_LIB(z, compressBound, ,
		 [HAVE_Z="no"])
    AC_CHECK_LIB(opcodes, init_disassemble_info, ,
		 [HAVE_OPCODES="no"])
    if test "x$HAVE_IBERTY"  = "xno" -o \
	    "x$HAVE_BFD"     = "xno" -o \
	    "x$HAVE_Z"       = "xno" -o \
	    "x$HAVE_OPCODES" = "xno"; then
	if test "x$DISASSEMBLER" != "xauto"; then
	    AC_MSG_ERROR([binutils not found, see http://www.gnu.org/software/binutils/])
	else
	    AC_MSG_WARN([binutils not found, see http://www.gnu.org/software/binutils/])
	    DISASSEMBLER="no"
	fi
    fi
fi
AM_CONDITIONAL(with_disassembler, [test "x$DISASSEMBLER" != "xno"])
if test "x$DISASSEMBLER" != "xno"; then
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDISASSEMBLER=1"
    save_CFLAGS=$CFLAGS
    CFLAGS="$CFLAGS -I$PWD/include -D_GNU_SOURCE"
    AC_COMPILE_IFELSE([AC_LANG_SOURCE(
	#include <lightning.h>
	#include <lightning/jit_private.h>
	#include <dis-asm.h>
	int main(int argc, char *argv[])
	{
		disassembler_ftype	 print;
		bfd			*abfd;
		print = disassembler(abfd);
		return 0;
	}
    )], [ac_cv_test_new_disassembler=no],,)
    CFLAGS="$save_CFLAGS"
    if test "x$ac_cv_test_new_disassembler" != "xno"; then
	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_29=1"
    fi
fi

AC_ARG_ENABLE(devel-disassembler,
	      AS_HELP_STRING([--enable-devel-disassembler],
			     [Enable extra disassembly options]),
	      [DEVEL_DISASSEMBLER=$enableval], [DEVEL_DISASSEMBLER=no])
if test "x$DEVEL_DISASSEMBLER" != "xno"; then
    if test "x$DISASSEMBLER" = "xno"; then
	AC_MSG_ERROR(devel-disassembler needs disassembler enabled)
    fi
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEVEL_DISASSEMBLER=1"
fi

AC_ARG_ENABLE(assertions,
	      AS_HELP_STRING([--enable-assertions],
			     [Enable runtime code generation assertions]),
	      [DEBUG=$enableval], [DEBUG=auto])
if test "x$DEBUG" = xyes; then
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEBUG=1"
else
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DNDEBUG"
    DEBUG=no
fi

# This option is only useful during development.
AC_ARG_ENABLE(devel-get-jit-size,
	      AS_HELP_STRING([--enable-devel-get-jit-size],
			     [Devel mode to regenerate jit size information]),
	      [GET_JIT_SIZE=$enableval], [GET_JIT_SIZE=no])
AM_CONDITIONAL(get_jit_size, [test $GET_JIT_SIZE = yes])

case "$host_os" in
    *bsd*|osf*)		SHLIB=""	;;
    *hpux*)		SHLIB="-ldld"	;;
    *)			SHLIB="-ldl"	;;
esac
AC_SUBST(SHLIB)

cpu=
case "$target_cpu" in
    i?86|x86_64|amd64)	cpu=x86		;;
    *arm*)		cpu=arm		;;
    *mips*)		cpu=mips	;;
    *powerpc*)		cpu=ppc		;;
    *sparc*)		cpu=sparc	;;
    ia64)		cpu=ia64	;;
    hppa*)		cpu=hppa	;;
    aarch64)		cpu=aarch64	;;
    s390*)		cpu=s390	;;
    alpha*)		cpu=alpha	;;
    riscv*)		cpu=riscv	;;
    *)					;;
esac
AM_CONDITIONAL(cpu_arm,     [test cpu-$cpu = cpu-arm])
AM_CONDITIONAL(cpu_mips,    [test cpu-$cpu = cpu-mips])
AM_CONDITIONAL(cpu_ppc,     [test cpu-$cpu = cpu-ppc])
AM_CONDITIONAL(cpu_sparc,   [test cpu-$cpu = cpu-sparc])
AM_CONDITIONAL(cpu_x86,     [test cpu-$cpu = cpu-x86])
AM_CONDITIONAL(cpu_ia64,    [test cpu-$cpu = cpu-ia64])
AM_CONDITIONAL(cpu_hppa,    [test cpu-$cpu = cpu-hppa])
AM_CONDITIONAL(cpu_aarch64, [test cpu-$cpu = cpu-aarch64])
AM_CONDITIONAL(cpu_s390,    [test cpu-$cpu = cpu-s390])
AM_CONDITIONAL(cpu_alpha,   [test cpu-$cpu = cpu-alpha])
AM_CONDITIONAL(cpu_riscv,   [test cpu-$cpu = cpu-riscv])

# Test x87 if both, x87 and sse2 available
ac_cv_test_x86_x87=
# Test arm instruction set if thumb instruction set available
ac_cv_test_arm_arm=
# Test sofware float if vfp available and not using hard float abi
ac_cv_test_arm_swf=

save_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -I$PWD/include -D_GNU_SOURCE"
if test x$cpu = x; then
    AC_MSG_ERROR([cpu $target_cpu not supported])
elif test $cpu = x86; then
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <lightning.h>
    int main(void) {
	int		    ac, flags;
	unsigned int	    eax, ebx, ecx, edx;
	if (__WORDSIZE == 64)
	    return 1;
	__asm__ volatile ("pushfl;\n\t"
			  "popl %0;\n\t"
			  "movl \$0x240000, %1;\n\t"
			  "xorl %0, %1;\n\t"
			  "pushl %1;\n\t"
			  "popfl;\n\t"
			  "pushfl;\n\t"
			  "popl %1;\n\t"
			  "xorl %0, %1;\n\t"
			  "pushl %0;\n\t"
			  "popfl"
			  : "=r" (flags), "=r" (ac));
	if ((ac & (1 << 21)) == 0)
	    return 1;
	__asm__ volatile ("xchgl %%ebx, %1; cpuid; xchgl %%ebx, %1"
			  : "=a" (eax), "=r" (ebx),
			  "=c" (ecx), "=d" (edx)
			  : "0" (1));
	return (edx & 1 << 26) ? 0 : 1;
    }
    ]])],[ac_cv_test_x86_x87=yes],[],[ac_cv_test_x86_x87=no])
elif test $cpu = arm; then
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <stdio.h>
    int main(void) {
    #if defined(__linux__)
	FILE	*fp;
	char	 buf[128];
	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	    return 1;
	while (fgets(buf, sizeof(buf), fp)) {
	    if (strncmp(buf, "Features\t:", 10) == 0 &&
		strstr(buf + 10, "thumb")) {
		fclose(fp);
		return 0;
	    }
	}
	fclose(fp);
    #elif defined(__thumb2__)
	return 0;
    #endif
	return 1;
    }
    ]])],[ac_cv_test_arm_arm=yes],[],[ac_cv_test_arm_arm=no])
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <stdio.h>
    int main(void) {
    #if defined(__linux__)
	FILE	*fp;
	char	 buf[128];
    #  if !defined(__ARM_PCS_VFP)
	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	    return 1;
	while (fgets(buf, sizeof(buf), fp)) {
	    if (strncmp(buf, "Features\t:", 10) == 0 &&
		strstr(buf + 10, "vfp")) {
		fclose(fp);
		return 0;
	    }
	}
	fclose(fp);
    #  endif
    #endif
	return 1;
    }
    ]])],[ac_cv_test_arm_swf=yes],[],[ac_cv_test_arm_swf=no])
elif test $cpu = ppc; then
    if test "x$DISASSEMBLER" != "xno"; then
	save_LIBS="$LIBS"
	LIBS="$LIBS $SHLIB"
	AC_CHECK_FUNCS(disassemble_init_for_target disassemble_init_powerpc)
	LIBS="$save_LIBS"
    fi
fi
CFLAGS=$save_CFLAGS

AM_CONDITIONAL(test_x86_x87, [test x$ac_cv_test_x86_x87 = xyes])
AM_CONDITIONAL(test_arm_arm, [test x$ac_cv_test_arm_arm = xyes])
AM_CONDITIONAL(test_arm_swf, [test x$ac_cv_test_arm_swf = xyes])

AM_CONDITIONAL(test_nodata, [test cpu-$cpu = cpu-mips -o cpu-$cpu = cpu-ppc -o cpu-$cpu = cpu-sparc -o cpu-$cpu = cpu-x86 -o cpu-$cpu = cpu-ia64 -o cpu-$cpu = cpu-hppa -o cpu-$cpu = cpu-s390 -o cpu-$cpu = cpu-alpha])

if test $cpu = arm; then
     AC_CHECK_LIB(m, sqrtf, ,
        [AC_MSG_ERROR([sqrtf required but not available])])
fi
AC_SUBST(cpu)

AC_SUBST([LIGHTNING_CFLAGS])

if test $ac_cv_header_stdint_h = yes; then
    AC_SUBST(MAYBE_INCLUDE_STDINT_H, ["#include <stdint.h>"])
fi

AC_OUTPUT([Makefile
	   lightning.pc
           gnulib-lib/Makefile
	   doc/Makefile
	   include/Makefile
	   include/lightning/Makefile
	   include/lightning.h
	   lib/Makefile
	   check/Makefile])
Commit	Line	Data
4a71579b PC	1	dnl
	2	dnl Copyright 2000, 2001, 2002, 2012-2019 Free Software Foundation, Inc.
	3	dnl
	4	dnl This file is part of GNU lightning.
	5	dnl
	6	dnl GNU lightning is free software; you can redistribute it and/or modify it
	7	dnl under the terms of the GNU Lesser General Public License as published
	8	dnl by the Free Software Foundation; either version 3, or (at your option)
	9	dnl any later version.
519a9ea1	10	dnl
4a71579b PC	11	dnl GNU lightning is distributed in the hope that it will be useful, but
	12	dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
	13	dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
	14	dnl License for more details.
	15	dnl
	16
519a9ea1	17	AC_PREREQ(2.64)
4a71579b	18	AC_INIT([GNU lightning], 2.1.3, pcpa@gnu.org, lightning)
519a9ea1	19	AC_CONFIG_AUX_DIR([build-aux])
4a71579b PC	20	AC_CANONICAL_TARGET
	21	AC_CONFIG_SRCDIR([Makefile.am])
	22	AM_INIT_AUTOMAKE([dist-bzip2])
	23	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
519a9ea1	24	AC_CONFIG_MACRO_DIR([m4])
4a71579b	25
519a9ea1	26	AC_CONFIG_HEADERS([config.h])
4a71579b PC	27
4a71579b PC	28	AC_PROG_CC
519a9ea1 PC	29	gl_EARLY
	30	AM_PROG_AR
	31	LT_INIT
	32	gl_INIT
4a71579b PC	33
	34	case "$target_cpu" in
	35	ia64)
	36	case "$host_os" in
	37	# Only supported mode
	38	hpux)
	39	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -mlp64" ;;
	40	*) ;;
	41	esac ;;
	42	mips)
	43	case "$host_os" in
	44	# (Hack) Flags to pass configure with gcc 3.x
	45	# Should not set LIGHTNINT_CFLAGS
	46	irix)
	47	CFLAGS="$CFLAGS -D__c99 -Drestrict=";;
	48	*) ;;
	49	esac ;;
	50	alpha*)
	51	case "$host_os" in
	52	osf*)
	53	# Get proper varargs and mmap prototypes and definitions
	54	CFLAGS="$CFLAGS -D_ANSI_C_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_OSF_SOURCE -D_POSIX_C_SOURCE=199309L"
	55	# Want to generate NaN with 0.0/0.0 and Inf with 1.0/0.0
	56	if test x$GCC = "xyes"; then
	57	CFLAGS="$CFLAGS -mieee"
	58	else
	59	CFLAGS="$CFLAGS -ieee_with_no_inexact"
	60	fi ;;
	61	*) ;;
	62	esac ;;
	63	*) ;;
	64	esac
	65
	66	AC_CHECK_FUNCS(mremap ffsl getopt_long_only isnan isinf,,)
	67
	68	AC_CHECK_HEADERS([getopt.h stdint.h],,,)
	69
	70	AC_ARG_ENABLE(disassembler,
	71	AS_HELP_STRING([--enable-disassembler],
	72	[Enable jit disassembler using binutils]),
	73	[DISASSEMBLER=$enableval], [DISASSEMBLER=auto])
	74	if test "x$DISASSEMBLER" != "xno"; then
	75	# FIXME need to check for libiberty first or will fail to link
	76	AC_CHECK_LIB(iberty, htab_try_create, ,
	77	[HAVE_IBERTY="no"])
	78	AC_CHECK_LIB(bfd, bfd_init, ,
	79	[HAVE_BFD="no"])
	80	AC_CHECK_LIB(z, compressBound, ,
	81	[HAVE_Z="no"])
	82	AC_CHECK_LIB(opcodes, init_disassemble_info, ,
	83	[HAVE_OPCODES="no"])
	84	if test "x$HAVE_IBERTY" = "xno" -o \
	85	"x$HAVE_BFD" = "xno" -o \
	86	"x$HAVE_Z" = "xno" -o \
	87	"x$HAVE_OPCODES" = "xno"; then
	88	if test "x$DISASSEMBLER" != "xauto"; then
	89	AC_MSG_ERROR([binutils not found, see http://www.gnu.org/software/binutils/])
	90	else
	91	AC_MSG_WARN([binutils not found, see http://www.gnu.org/software/binutils/])
	92	DISASSEMBLER="no"
	93	fi
	94	fi
	95	fi
	96	AM_CONDITIONAL(with_disassembler, [test "x$DISASSEMBLER" != "xno"])
97	if test "x$DISASSEMBLER" != "xno"; then
98	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDISASSEMBLER=1"
99	save_CFLAGS=$CFLAGS
100	CFLAGS="$CFLAGS -I$PWD/include -D_GNU_SOURCE"
101	AC_COMPILE_IFELSE([AC_LANG_SOURCE(
102	#include <lightning.h>
103	#include <lightning/jit_private.h>
104	#include <dis-asm.h>
105	int main(int argc, char *argv[])
106	{
107	disassembler_ftype print;
108	bfd *abfd;
109	print = disassembler(abfd);
110	return 0;
111	}
112	)], [ac_cv_test_new_disassembler=no],,)
113	CFLAGS="$save_CFLAGS"
114	if test "x$ac_cv_test_new_disassembler" != "xno"; then
115	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_29=1"
116	fi
117	fi
118
119	AC_ARG_ENABLE(devel-disassembler,
120	AS_HELP_STRING([--enable-devel-disassembler],
121	[Enable extra disassembly options]),
122	[DEVEL_DISASSEMBLER=$enableval], [DEVEL_DISASSEMBLER=no])
123	if test "x$DEVEL_DISASSEMBLER" != "xno"; then
124	if test "x$DISASSEMBLER" = "xno"; then
125	AC_MSG_ERROR(devel-disassembler needs disassembler enabled)
126	fi
127	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEVEL_DISASSEMBLER=1"
128	fi
129
130	AC_ARG_ENABLE(assertions,
131	AS_HELP_STRING([--enable-assertions],
132	[Enable runtime code generation assertions]),
133	[DEBUG=$enableval], [DEBUG=auto])
134	if test "x$DEBUG" = xyes; then
135	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEBUG=1"
136	else
137	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DNDEBUG"
138	DEBUG=no
139	fi
140
141	# This option is only useful during development.
142	AC_ARG_ENABLE(devel-get-jit-size,
143	AS_HELP_STRING([--enable-devel-get-jit-size],
144	[Devel mode to regenerate jit size information]),
145	[GET_JIT_SIZE=$enableval], [GET_JIT_SIZE=no])
146	AM_CONDITIONAL(get_jit_size, [test $GET_JIT_SIZE = yes])
147
148	case "$host_os" in
149	bsd\|osf*) SHLIB="" ;;
150	hpux) SHLIB="-ldld" ;;
151	*) SHLIB="-ldl" ;;
152	esac
153	AC_SUBST(SHLIB)
154
155	cpu=
156	case "$target_cpu" in
157	i?86\|x86_64\|amd64) cpu=x86 ;;
158	arm) cpu=arm ;;
159	mips) cpu=mips ;;
160	powerpc) cpu=ppc ;;
161	sparc) cpu=sparc ;;
162	ia64) cpu=ia64 ;;
163	hppa*) cpu=hppa ;;
164	aarch64) cpu=aarch64 ;;
165	s390*) cpu=s390 ;;
166	alpha*) cpu=alpha ;;
167	riscv*) cpu=riscv ;;
168	*) ;;
169	esac
170	AM_CONDITIONAL(cpu_arm, [test cpu-$cpu = cpu-arm])
171	AM_CONDITIONAL(cpu_mips, [test cpu-$cpu = cpu-mips])
172	AM_CONDITIONAL(cpu_ppc, [test cpu-$cpu = cpu-ppc])
173	AM_CONDITIONAL(cpu_sparc, [test cpu-$cpu = cpu-sparc])
174	AM_CONDITIONAL(cpu_x86, [test cpu-$cpu = cpu-x86])
175	AM_CONDITIONAL(cpu_ia64, [test cpu-$cpu = cpu-ia64])
176	AM_CONDITIONAL(cpu_hppa, [test cpu-$cpu = cpu-hppa])
177	AM_CONDITIONAL(cpu_aarch64, [test cpu-$cpu = cpu-aarch64])
178	AM_CONDITIONAL(cpu_s390, [test cpu-$cpu = cpu-s390])
179	AM_CONDITIONAL(cpu_alpha, [test cpu-$cpu = cpu-alpha])
180	AM_CONDITIONAL(cpu_riscv, [test cpu-$cpu = cpu-riscv])
181
182	# Test x87 if both, x87 and sse2 available
183	ac_cv_test_x86_x87=
184	# Test arm instruction set if thumb instruction set available
185	ac_cv_test_arm_arm=
186	# Test sofware float if vfp available and not using hard float abi
187	ac_cv_test_arm_swf=
188
189	save_CFLAGS=$CFLAGS
190	CFLAGS="$CFLAGS -I$PWD/include -D_GNU_SOURCE"
191	if test x$cpu = x; then
192	AC_MSG_ERROR([cpu $target_cpu not supported])
193	elif test $cpu = x86; then
194	AC_RUN_IFELSE([AC_LANG_SOURCE([[
195	#include <lightning.h>
196	int main(void) {
197	int ac, flags;
198	unsigned int eax, ebx, ecx, edx;
199	if (__WORDSIZE == 64)
200	return 1;
201	__asm__ volatile ("pushfl;\n\t"
202	"popl %0;\n\t"
203	"movl \$0x240000, %1;\n\t"
204	"xorl %0, %1;\n\t"
205	"pushl %1;\n\t"
206	"popfl;\n\t"
207	"pushfl;\n\t"
208	"popl %1;\n\t"
209	"xorl %0, %1;\n\t"
210	"pushl %0;\n\t"
211	"popfl"
212	: "=r" (flags), "=r" (ac));
213	if ((ac & (1 << 21)) == 0)
214	return 1;
215	__asm__ volatile ("xchgl %%ebx, %1; cpuid; xchgl %%ebx, %1"
216	: "=a" (eax), "=r" (ebx),
217	"=c" (ecx), "=d" (edx)
218	: "0" (1));
219	return (edx & 1 << 26) ? 0 : 1;
220	}
221	]])],[ac_cv_test_x86_x87=yes],[],[ac_cv_test_x86_x87=no])
222	elif test $cpu = arm; then
223	AC_RUN_IFELSE([AC_LANG_SOURCE([[
224	#include <stdio.h>
225	int main(void) {
226	#if defined(__linux__)
227	FILE *fp;
228	char buf[128];
229	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
230	return 1;
231	while (fgets(buf, sizeof(buf), fp)) {
232	if (strncmp(buf, "Features\t:", 10) == 0 &&
233	strstr(buf + 10, "thumb")) {
234	fclose(fp);
235	return 0;
236	}
237	}
238	fclose(fp);
239	#elif defined(__thumb2__)
240	return 0;
241	#endif
242	return 1;
243	}
244	]])],[ac_cv_test_arm_arm=yes],[],[ac_cv_test_arm_arm=no])
245	AC_RUN_IFELSE([AC_LANG_SOURCE([[
246	#include <stdio.h>
247	int main(void) {
248	#if defined(__linux__)
249	FILE *fp;
250	char buf[128];
251	# if !defined(__ARM_PCS_VFP)
252	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
253	return 1;
254	while (fgets(buf, sizeof(buf), fp)) {
255	if (strncmp(buf, "Features\t:", 10) == 0 &&
256	strstr(buf + 10, "vfp")) {
257	fclose(fp);
258	return 0;
259	}
260	}
261	fclose(fp);
262	# endif
263	#endif
264	return 1;
265	}
266	]])],[ac_cv_test_arm_swf=yes],[],[ac_cv_test_arm_swf=no])
267	elif test $cpu = ppc; then
268	if test "x$DISASSEMBLER" != "xno"; then
269	save_LIBS="$LIBS"
270	LIBS="$LIBS $SHLIB"
271	AC_CHECK_FUNCS(disassemble_init_for_target disassemble_init_powerpc)
272	LIBS="$save_LIBS"
273	fi
274	fi
275	CFLAGS=$save_CFLAGS
276
277	AM_CONDITIONAL(test_x86_x87, [test x$ac_cv_test_x86_x87 = xyes])
278	AM_CONDITIONAL(test_arm_arm, [test x$ac_cv_test_arm_arm = xyes])
279	AM_CONDITIONAL(test_arm_swf, [test x$ac_cv_test_arm_swf = xyes])
280
281	AM_CONDITIONAL(test_nodata, [test cpu-$cpu = cpu-mips -o cpu-$cpu = cpu-ppc -o cpu-$cpu = cpu-sparc -o cpu-$cpu = cpu-x86 -o cpu-$cpu = cpu-ia64 -o cpu-$cpu = cpu-hppa -o cpu-$cpu = cpu-s390 -o cpu-$cpu = cpu-alpha])
282
283	if test $cpu = arm; then
284	AC_CHECK_LIB(m, sqrtf, ,
285	[AC_MSG_ERROR([sqrtf required but not available])])
286	fi
287	AC_SUBST(cpu)
288
289	AC_SUBST([LIGHTNING_CFLAGS])
290
291	if test $ac_cv_header_stdint_h = yes; then
292	AC_SUBST(MAYBE_INCLUDE_STDINT_H, ["#include <stdint.h>"])
293	fi
294
295	AC_OUTPUT([Makefile
296	lightning.pc
519a9ea1	297	gnulib-lib/Makefile
4a71579b PC	298	doc/Makefile
	299	include/Makefile
	300	include/lightning/Makefile
	301	include/lightning.h
	302	lib/Makefile
	303	check/Makefile])