a773ac06 |
1 | /* Teensyduino Core Library |
2 | * http://www.pjrc.com/teensy/ |
3 | * Copyright (c) 2013 PJRC.COM, LLC. |
4 | * |
5 | * Permission is hereby granted, free of charge, to any person obtaining |
6 | * a copy of this software and associated documentation files (the |
7 | * "Software"), to deal in the Software without restriction, including |
8 | * without limitation the rights to use, copy, modify, merge, publish, |
9 | * distribute, sublicense, and/or sell copies of the Software, and to |
10 | * permit persons to whom the Software is furnished to do so, subject to |
11 | * the following conditions: |
12 | * |
13 | * 1. The above copyright notice and this permission notice shall be |
14 | * included in all copies or substantial portions of the Software. |
15 | * |
16 | * 2. If the Software is incorporated into a build system that allows |
17 | * selection among a list of target devices, then similar target |
18 | * devices manufactured by PJRC.COM must be included in the list of |
19 | * target devices and selectable in the same manner. |
20 | * |
21 | * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, |
22 | * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF |
23 | * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND |
24 | * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS |
25 | * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN |
26 | * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN |
27 | * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE |
28 | * SOFTWARE. |
29 | */ |
30 | |
31 | MEMORY |
32 | { |
33 | FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 128K |
34 | RAM (rwx) : ORIGIN = 0x1FFFE000, LENGTH = 16K |
35 | } |
36 | |
37 | |
38 | SECTIONS |
39 | { |
40 | .text : { |
41 | . = 0; |
42 | KEEP(*(.vectors)) |
43 | *(.startup*) |
44 | /* TODO: does linker detect startup overflow onto flashconfig? */ |
45 | . = 0x400; |
46 | KEEP(*(.flashconfig*)) |
47 | *(.text*) |
48 | *(.rodata*) |
49 | . = ALIGN(4); |
50 | KEEP(*(.init)) |
51 | . = ALIGN(4); |
52 | __preinit_array_start = .; |
53 | KEEP (*(.preinit_array)) |
54 | __preinit_array_end = .; |
55 | __init_array_start = .; |
56 | KEEP (*(SORT(.init_array.*))) |
57 | KEEP (*(.init_array)) |
58 | __init_array_end = .; |
59 | } > FLASH = 0xFF |
60 | |
61 | .ARM.exidx : { |
62 | __exidx_start = .; |
63 | *(.ARM.exidx* .gnu.linkonce.armexidx.*) |
64 | __exidx_end = .; |
65 | } > FLASH |
66 | _etext = .; |
67 | |
68 | .usbdescriptortable (NOLOAD) : { |
69 | /* . = ORIGIN(RAM); */ |
70 | . = ALIGN(512); |
71 | *(.usbdescriptortable*) |
72 | } > RAM |
73 | |
74 | .dmabuffers (NOLOAD) : { |
75 | . = ALIGN(4); |
76 | *(.dmabuffers*) |
77 | } > RAM |
78 | |
79 | .usbbuffers (NOLOAD) : { |
80 | . = ALIGN(4); |
81 | *(.usbbuffers*) |
82 | } > RAM |
83 | |
84 | .data : AT (_etext) { |
85 | . = ALIGN(4); |
86 | _sdata = .; |
87 | *(.fastrun*) |
88 | *(.data*) |
89 | . = ALIGN(4); |
90 | _edata = .; |
91 | } > RAM |
92 | |
93 | .noinit (NOLOAD) : { |
94 | *(.noinit*) |
95 | } > RAM |
96 | |
97 | .bss : { |
98 | . = ALIGN(4); |
99 | _sbss = .; |
100 | *(.bss*) |
101 | *(COMMON) |
102 | . = ALIGN(4); |
103 | _ebss = .; |
104 | __bss_end = .; |
105 | } > RAM |
106 | |
107 | _estack = ORIGIN(RAM) + LENGTH(RAM); |
108 | } |
109 | |
110 | |