| 1 | # ################################################################ |
| 2 | # Copyright (c) Meta Platforms, Inc. and affiliates. |
| 3 | # All rights reserved. |
| 4 | # |
| 5 | # This source code is licensed under both the BSD-style license (found in the |
| 6 | # LICENSE file in the root directory of this source tree) and the GPLv2 (found |
| 7 | # in the COPYING file in the root directory of this source tree). |
| 8 | # ################################################################ |
| 9 | |
| 10 | cmake_minimum_required(VERSION 3.5 FATAL_ERROR) |
| 11 | |
| 12 | # As of 2018-12-26 ZSTD has been validated to build with cmake version 3.13.2 new policies. |
| 13 | # Set and use the newest cmake policies that are validated to work |
| 14 | set(ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION "3") |
| 15 | set(ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION "13") #Policies never changed at PATCH level |
| 16 | if("${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}" EQUAL "${CMAKE_MAJOR_VERSION}" AND |
| 17 | "${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}" GREATER "${CMAKE_MINOR_VERSION}") |
| 18 | set(ZSTD_CMAKE_POLICY_VERSION "${CMAKE_VERSION}") |
| 19 | else() |
| 20 | set(ZSTD_CMAKE_POLICY_VERSION "${ZSTD_MAX_VALIDATED_CMAKE_MAJOR_VERSION}.${ZSTD_MAX_VALIDATED_CMAKE_MINOR_VERSION}.0") |
| 21 | endif() |
| 22 | cmake_policy(VERSION ${ZSTD_CMAKE_POLICY_VERSION}) |
| 23 | |
| 24 | set(CMAKE_BUILD_WITH_INSTALL_RPATH on) |
| 25 | |
| 26 | list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules") |
| 27 | set(ZSTD_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../..") |
| 28 | set(LIBRARY_DIR ${ZSTD_SOURCE_DIR}/lib) |
| 29 | # Parse version |
| 30 | include(GetZstdLibraryVersion) |
| 31 | GetZstdLibraryVersion(${LIBRARY_DIR}/zstd.h zstd_VERSION_MAJOR zstd_VERSION_MINOR zstd_VERSION_PATCH) |
| 32 | |
| 33 | project(zstd |
| 34 | VERSION "${zstd_VERSION_MAJOR}.${zstd_VERSION_MINOR}.${zstd_VERSION_PATCH}" |
| 35 | LANGUAGES C # Main library is in C |
| 36 | ASM # And ASM |
| 37 | CXX # Testing contributed code also utilizes CXX |
| 38 | ) |
| 39 | |
| 40 | message(STATUS "ZSTD VERSION: ${zstd_VERSION}") |
| 41 | set(zstd_HOMEPAGE_URL "https://facebook.github.io/zstd") |
| 42 | set(zstd_DESCRIPTION "Zstandard is a real-time compression algorithm, providing high compression ratios.") |
| 43 | |
| 44 | # Set a default build type if none was specified |
| 45 | if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES) |
| 46 | message(STATUS "Setting build type to 'Release' as none was specified.") |
| 47 | set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE) |
| 48 | # Set the possible values of build type for cmake-gui |
| 49 | set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo") |
| 50 | endif() |
| 51 | |
| 52 | include(GNUInstallDirs) |
| 53 | |
| 54 | #----------------------------------------------------------------------------- |
| 55 | # Add extra compilation flags |
| 56 | #----------------------------------------------------------------------------- |
| 57 | include(AddZstdCompilationFlags) |
| 58 | ADD_ZSTD_COMPILATION_FLAGS() |
| 59 | |
| 60 | # Always hide XXHash symbols |
| 61 | add_definitions(-DXXH_NAMESPACE=ZSTD_) |
| 62 | |
| 63 | #----------------------------------------------------------------------------- |
| 64 | # Installation variables |
| 65 | #----------------------------------------------------------------------------- |
| 66 | message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}") |
| 67 | message(STATUS "CMAKE_INSTALL_LIBDIR: ${CMAKE_INSTALL_LIBDIR}") |
| 68 | |
| 69 | #----------------------------------------------------------------------------- |
| 70 | # Options |
| 71 | #----------------------------------------------------------------------------- |
| 72 | |
| 73 | # Legacy support |
| 74 | option(ZSTD_LEGACY_SUPPORT "LEGACY SUPPORT" ON) |
| 75 | |
| 76 | if (ZSTD_LEGACY_SUPPORT) |
| 77 | message(STATUS "ZSTD_LEGACY_SUPPORT defined!") |
| 78 | set(ZSTD_LEGACY_LEVEL 5 CACHE STRING "") |
| 79 | add_definitions(-DZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_LEVEL}) |
| 80 | else () |
| 81 | message(STATUS "ZSTD_LEGACY_SUPPORT not defined!") |
| 82 | add_definitions(-DZSTD_LEGACY_SUPPORT=0) |
| 83 | endif () |
| 84 | |
| 85 | if (ANDROID) |
| 86 | set(ZSTD_MULTITHREAD_SUPPORT_DEFAULT OFF) |
| 87 | else() |
| 88 | set(ZSTD_MULTITHREAD_SUPPORT_DEFAULT ON) |
| 89 | endif() |
| 90 | |
| 91 | # Multi-threading support |
| 92 | option(ZSTD_MULTITHREAD_SUPPORT "MULTITHREADING SUPPORT" ${ZSTD_MULTITHREAD_SUPPORT_DEFAULT}) |
| 93 | |
| 94 | if (ZSTD_MULTITHREAD_SUPPORT) |
| 95 | message(STATUS "ZSTD_MULTITHREAD_SUPPORT is enabled") |
| 96 | else () |
| 97 | message(STATUS "ZSTD_MULTITHREAD_SUPPORT is disabled") |
| 98 | endif () |
| 99 | |
| 100 | option(ZSTD_BUILD_PROGRAMS "BUILD PROGRAMS" ON) |
| 101 | option(ZSTD_BUILD_CONTRIB "BUILD CONTRIB" OFF) |
| 102 | |
| 103 | # Respect the conventional CMake option for enabling tests if it was specified on the first configure |
| 104 | if (BUILD_TESTING) |
| 105 | set(ZSTD_BUILD_TESTS_default ON) |
| 106 | else() |
| 107 | set(ZSTD_BUILD_TESTS_default OFF) |
| 108 | endif() |
| 109 | option(ZSTD_BUILD_TESTS "BUILD TESTS" ${ZSTD_BUILD_TESTS_default}) |
| 110 | if (MSVC) |
| 111 | option(ZSTD_USE_STATIC_RUNTIME "LINK TO STATIC RUN-TIME LIBRARIES" OFF) |
| 112 | endif () |
| 113 | |
| 114 | #----------------------------------------------------------------------------- |
| 115 | # External dependencies |
| 116 | #----------------------------------------------------------------------------- |
| 117 | # Define a function to handle special thread settings for HP-UX |
| 118 | # See https://github.com/facebook/zstd/pull/3862 for details. |
| 119 | function(setup_hpux_threads) |
| 120 | find_package(Threads) |
| 121 | if (NOT Threads_FOUND) |
| 122 | set(CMAKE_USE_PTHREADS_INIT 1 PARENT_SCOPE) |
| 123 | set(CMAKE_THREAD_LIBS_INIT -lpthread PARENT_SCOPE) |
| 124 | set(CMAKE_HAVE_THREADS_LIBRARY 1 PARENT_SCOPE) |
| 125 | set(Threads_FOUND TRUE PARENT_SCOPE) |
| 126 | endif() |
| 127 | endfunction() |
| 128 | |
| 129 | if (ZSTD_MULTITHREAD_SUPPORT AND UNIX) |
| 130 | if (CMAKE_SYSTEM_NAME MATCHES "HP-UX") |
| 131 | setup_hpux_threads() |
| 132 | else() |
| 133 | set(THREADS_PREFER_PTHREAD_FLAG ON) |
| 134 | find_package(Threads REQUIRED) |
| 135 | endif() |
| 136 | if (CMAKE_USE_PTHREADS_INIT) |
| 137 | set(THREADS_LIBS "${CMAKE_THREAD_LIBS_INIT}") |
| 138 | else() |
| 139 | message(SEND_ERROR "ZSTD currently does not support thread libraries other than pthreads") |
| 140 | endif() |
| 141 | endif () |
| 142 | |
| 143 | #----------------------------------------------------------------------------- |
| 144 | # Add source directories |
| 145 | #----------------------------------------------------------------------------- |
| 146 | add_subdirectory(lib) |
| 147 | |
| 148 | option(ZSTD_PROGRAMS_LINK_SHARED "PROGRAMS LINK SHARED" OFF) |
| 149 | |
| 150 | if (ZSTD_BUILD_PROGRAMS) |
| 151 | if (NOT ZSTD_BUILD_STATIC AND NOT ZSTD_PROGRAMS_LINK_SHARED) |
| 152 | message(SEND_ERROR "You need to build static library to build zstd CLI") |
| 153 | elseif(NOT ZSTD_BUILD_SHARED AND ZSTD_PROGRAMS_LINK_SHARED) |
| 154 | message(SEND_ERROR "You need to build shared library to build zstd CLI") |
| 155 | endif () |
| 156 | |
| 157 | add_subdirectory(programs) |
| 158 | endif () |
| 159 | |
| 160 | if (ZSTD_BUILD_TESTS) |
| 161 | enable_testing() |
| 162 | if (NOT ZSTD_BUILD_STATIC) |
| 163 | message(SEND_ERROR "You need to build static library to build tests") |
| 164 | endif () |
| 165 | |
| 166 | add_subdirectory(tests) |
| 167 | endif () |
| 168 | |
| 169 | if (ZSTD_BUILD_CONTRIB) |
| 170 | add_subdirectory(contrib) |
| 171 | endif () |
| 172 | |
| 173 | #----------------------------------------------------------------------------- |
| 174 | # Add clean-all target |
| 175 | #----------------------------------------------------------------------------- |
| 176 | add_custom_target(clean-all |
| 177 | COMMAND ${CMAKE_BUILD_TOOL} clean |
| 178 | COMMAND rm -rf ${CMAKE_BINARY_DIR}/ |
| 179 | ) |
| 180 | |
| 181 | #----------------------------------------------------------------------------- |
| 182 | # Generate Package Config files |
| 183 | # |
| 184 | # This section is based on the boiler plate code from: |
| 185 | # https://cmake.org/cmake/help/latest/manual/cmake-packages.7.html#creating-packages |
| 186 | #----------------------------------------------------------------------------- |
| 187 | include(CMakePackageConfigHelpers) |
| 188 | write_basic_package_version_file( |
| 189 | "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake" |
| 190 | VERSION ${zstd_VERSION} |
| 191 | COMPATIBILITY SameMajorVersion |
| 192 | ) |
| 193 | |
| 194 | # A Package Config file that works from the build directory |
| 195 | export(EXPORT zstdExports |
| 196 | FILE "${CMAKE_CURRENT_BINARY_DIR}/zstdTargets.cmake" |
| 197 | NAMESPACE zstd:: |
| 198 | ) |
| 199 | |
| 200 | # A Package Config file that works from the installation directory |
| 201 | set(ConfigPackageLocation ${CMAKE_INSTALL_LIBDIR}/cmake/zstd) |
| 202 | install(EXPORT zstdExports |
| 203 | FILE zstdTargets.cmake |
| 204 | NAMESPACE zstd:: |
| 205 | DESTINATION ${ConfigPackageLocation} |
| 206 | ) |
| 207 | configure_package_config_file( |
| 208 | zstdConfig.cmake.in |
| 209 | "${CMAKE_CURRENT_BINARY_DIR}/zstdConfig.cmake" |
| 210 | INSTALL_DESTINATION ${ConfigPackageLocation} |
| 211 | ) |
| 212 | install(FILES |
| 213 | "${CMAKE_CURRENT_BINARY_DIR}/zstdConfig.cmake" |
| 214 | "${CMAKE_CURRENT_BINARY_DIR}/zstdConfigVersion.cmake" |
| 215 | DESTINATION ${ConfigPackageLocation} |
| 216 | ) |