[pcsx_rearmed.git] / deps / lightning / configure.ac

dnl
dnl Copyright 2000, 2001, 2002, 2012-2019 Free Software Foundation, Inc.
dnl
dnl This file is part of GNU lightning.
dnl
dnl GNU lightning is free software; you can redistribute it and/or modify it
dnl under the terms of the GNU Lesser General Public License as published
dnl by the Free Software Foundation; either version 3, or (at your option)
dnl any later version.
dnl
dnl GNU lightning is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
dnl License for more details.
dnl

AC_PREREQ([2.71])
AC_INIT([GNU lightning],[2.1.3],[pcpa@gnu.org],[lightning])
AC_CONFIG_AUX_DIR([build-aux])
AC_CANONICAL_TARGET
AC_CONFIG_SRCDIR([Makefile.am])
AM_INIT_AUTOMAKE([dist-bzip2])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_HEADERS([config.h])

AC_PROG_CC
gl_EARLY
AM_PROG_AR
LT_INIT
gl_INIT

case "$target_cpu" in
    ia64)
	case "$host_os" in
	    # Only supported mode
	    *hpux*)
		LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -mlp64"		;;
	    *)					;;
	esac					;;
    *mips*)
	case "$host_os" in
	    # (Hack) Flags to pass configure with gcc 3.x
	    # Should not set LIGHTNINT_CFLAGS
	    *irix*)
		CFLAGS="$CFLAGS -D__c99 -Drestrict=";;
	    *)					;;
	esac					;;
    alpha*)
	case "$host_os" in
	    osf*)
		# Get proper varargs and mmap prototypes and definitions
		CFLAGS="$CFLAGS -D_ANSI_C_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_OSF_SOURCE -D_POSIX_C_SOURCE=199309L"
		# Want to generate NaN with 0.0/0.0 and Inf with 1.0/0.0
		if test x$GCC = "xyes"; then
		    CFLAGS="$CFLAGS -mieee"
		else
		    CFLAGS="$CFLAGS -ieee_with_no_inexact"
		fi				;;
	    *)					;;
	esac					;;
    *)						;;
esac

AC_CHECK_FUNCS(mmap mremap ffsl getopt_long_only isnan isinf,,)

AC_CHECK_HEADERS([getopt.h stdint.h],,,)

AC_ARG_ENABLE(disassembler,
	      AS_HELP_STRING([--enable-disassembler],
			     [Enable jit disassembler using binutils]),
	      [DISASSEMBLER=$enableval], [DISASSEMBLER=auto])
if test "x$DISASSEMBLER" != "xno"; then

    AC_CHECK_LIB(iberty, htab_try_create, ,
		 [HAVE_IBERTY="no"])
    AC_CHECK_LIB(bfd, bfd_init, ,
		 [HAVE_BFD="no"])
    AC_CHECK_LIB(z, compressBound, ,
		 [HAVE_Z="no"])
    AC_CHECK_LIB(opcodes, init_disassemble_info, ,
		 [HAVE_OPCODES="no"])

    if test "x$HAVE_IBERTY" = "xno"; then
        if test "x$DISASSEMBLER" = "xyes"; then
            AC_MSG_ERROR([libiberty not found])
        else
            AC_MSG_WARN([libiberty not found])
            DISASSEMBLER="no"
        fi
    fi

    if test "x$HAVE_BFD" = "xno"; then
        if test "x$DISASSEMBLER" = "xyes"; then
            AC_MSG_ERROR([binutils BFD not found, see http://www.gnu.org/software/binutils/])
        else
            AC_MSG_WARN([binutils BFD not found, see http://www.gnu.org/software/binutils/])
            DISASSEMBLER="no"
        fi
    fi

    if test "x$HAVE_Z" = "xno"; then
        if test "x$DISASSEMBLER" = "xyes"; then
            AC_MSG_ERROR([zlib not found, see https://zlib.net/])
        else
            AC_MSG_WARN([zlib not found, see https://zlib.net/])
            DISASSEMBLER="no"
        fi
    fi

    if test "x$HAVE_OPCODES" = "xno"; then
        if test "x$DISASSEMBLER" = "xyes"; then
            AC_MSG_ERROR([binutils opcodes not found, see https://www.gnu.org/software/binutils/])
        else
            AC_MSG_WARN([binutils opcodes not found, see https://www.gnu.org/software/binutils/])
            DISASSEMBLER="no"
        fi
    fi

fi
AM_CONDITIONAL(with_disassembler, [test "x$DISASSEMBLER" != "xno"])
if test "x$DISASSEMBLER" != "xno"; then
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDISASSEMBLER=1"
    save_CFLAGS=$CFLAGS
    CFLAGS="$CFLAGS -D_GNU_SOURCE"
    AC_COMPILE_IFELSE([AC_LANG_SOURCE(
	#include <dis-asm.h>
	int main(int argc, char *argv[])
	{
		disassembler_ftype	 print;
		bfd			*abfd;
		print = disassembler(abfd);
		return 0;
	}
    )], [ac_cv_test_new_disassembler=no],,)
    AC_COMPILE_IFELSE([AC_LANG_SOURCE(
	#include <dis-asm.h>
	int main(int argc, char *argv[])
	{
		struct disassemble_info dinfo;
		INIT_DISASSEMBLE_INFO(dinfo, NULL, NULL, NULL);
		return 0;
	}
    )], [ac_cv_test_new_disassemble_info=yes],[ac_cv_test_new_disassemble_info=no],)
    CFLAGS="$save_CFLAGS"
    if test "x$ac_cv_test_new_disassembler" != "xno"; then
	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_29=1"
    fi
    if test "x$ac_cv_test_new_disassemble_info" != "xno"; then
	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_38=1"
    fi
fi

AC_ARG_ENABLE(devel-disassembler,
	      AS_HELP_STRING([--enable-devel-disassembler],
			     [Enable extra disassembly options]),
	      [DEVEL_DISASSEMBLER=$enableval], [DEVEL_DISASSEMBLER=no])
if test "x$DEVEL_DISASSEMBLER" != "xno"; then
    if test "x$DISASSEMBLER" = "xno"; then
	AC_MSG_ERROR(devel-disassembler needs disassembler enabled)
    fi
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEVEL_DISASSEMBLER=1"
fi

AC_ARG_ENABLE(assertions,
	      AS_HELP_STRING([--enable-assertions],
			     [Enable runtime code generation assertions]),
	      [DEBUG=$enableval], [DEBUG=auto])
if test "x$DEBUG" = xyes; then
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEBUG=1"
else
    LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DNDEBUG"
    DEBUG=no
fi

# This option is only useful during development.
AC_ARG_ENABLE(devel-get-jit-size,
	      AS_HELP_STRING([--enable-devel-get-jit-size],
			     [Devel mode to regenerate jit size information]),
	      [GET_JIT_SIZE=$enableval], [GET_JIT_SIZE=no])
AM_CONDITIONAL(get_jit_size, [test $GET_JIT_SIZE = yes])

case "$host_os" in
    *bsd*|osf*)		SHLIB=""	;;
    *hpux*)		SHLIB="-ldld"	;;
    *)			SHLIB="-ldl"	;;
esac
AC_SUBST(SHLIB)

cpu=
case "$target_cpu" in
    i?86|x86_64|amd64)	cpu=x86		;;
    *arm*)		cpu=arm		;;
    *mips*)		cpu=mips	;;
    *powerpc*)		cpu=ppc		;;
    *sparc*)		cpu=sparc	;;
    ia64)		cpu=ia64	;;
    hppa*)		cpu=hppa	;;
    aarch64)		cpu=aarch64	;;
    s390*)		cpu=s390	;;
    alpha*)		cpu=alpha	;;
    riscv*)		cpu=riscv	;;
    loongarch*)		cpu=loongarch	;;
    *)					;;
esac
AM_CONDITIONAL(cpu_arm,       [test cpu-$cpu = cpu-arm])
AM_CONDITIONAL(cpu_mips,      [test cpu-$cpu = cpu-mips])
AM_CONDITIONAL(cpu_ppc,       [test cpu-$cpu = cpu-ppc])
AM_CONDITIONAL(cpu_sparc,     [test cpu-$cpu = cpu-sparc])
AM_CONDITIONAL(cpu_x86,       [test cpu-$cpu = cpu-x86])
AM_CONDITIONAL(cpu_ia64,      [test cpu-$cpu = cpu-ia64])
AM_CONDITIONAL(cpu_hppa,      [test cpu-$cpu = cpu-hppa])
AM_CONDITIONAL(cpu_aarch64,   [test cpu-$cpu = cpu-aarch64])
AM_CONDITIONAL(cpu_s390,      [test cpu-$cpu = cpu-s390])
AM_CONDITIONAL(cpu_alpha,     [test cpu-$cpu = cpu-alpha])
AM_CONDITIONAL(cpu_riscv,     [test cpu-$cpu = cpu-riscv])
AM_CONDITIONAL(cpu_loongarch, [test cpu-$cpu = cpu-loongarch])

# Test x87 if both, x87 and sse2 available
ac_cv_test_x86_x87=
# Test arm instruction set if thumb instruction set available
ac_cv_test_arm_arm=
# Test sofware float if vfp available and not using hard float abi
ac_cv_test_arm_swf=

save_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -D_GNU_SOURCE"
if test x$cpu = x; then
    AC_MSG_ERROR([cpu $target_cpu not supported])
elif test $cpu = x86; then
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    int main(void) {
	int		    ac, flags;
	unsigned int	    eax, ebx, ecx, edx;
	if (__WORDSIZE == 64)
	    return 1;
	__asm__ volatile ("pushfl;\n\t"
			  "popl %0;\n\t"
			  "movl \$0x240000, %1;\n\t"
			  "xorl %0, %1;\n\t"
			  "pushl %1;\n\t"
			  "popfl;\n\t"
			  "pushfl;\n\t"
			  "popl %1;\n\t"
			  "xorl %0, %1;\n\t"
			  "pushl %0;\n\t"
			  "popfl"
			  : "=r" (flags), "=r" (ac));
	if ((ac & (1 << 21)) == 0)
	    return 1;
	__asm__ volatile ("xchgl %%ebx, %1; cpuid; xchgl %%ebx, %1"
			  : "=a" (eax), "=r" (ebx),
			  "=c" (ecx), "=d" (edx)
			  : "0" (1));
	return (edx & 1 << 26) ? 0 : 1;
    }
    ]])],[ac_cv_test_x86_x87=yes],[],[ac_cv_test_x86_x87=no])
elif test $cpu = arm; then
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <stdio.h>
    int main(void) {
    #if defined(__linux__)
	FILE	*fp;
	char	 buf[128];
	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	    return 1;
	while (fgets(buf, sizeof(buf), fp)) {
	    if (strncmp(buf, "Features\t:", 10) == 0 &&
		strstr(buf + 10, "thumb")) {
		fclose(fp);
		return 0;
	    }
	}
	fclose(fp);
    #elif defined(__thumb2__)
	return 0;
    #endif
	return 1;
    }
    ]])],[ac_cv_test_arm_arm=yes],[],[ac_cv_test_arm_arm=no])
    AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <stdio.h>
    int main(void) {
    #if defined(__linux__)
	FILE	*fp;
	char	 buf[128];
    #  if !defined(__ARM_PCS_VFP)
	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	    return 1;
	while (fgets(buf, sizeof(buf), fp)) {
	    if (strncmp(buf, "Features\t:", 10) == 0 &&
		strstr(buf + 10, "vfp")) {
		fclose(fp);
		return 0;
	    }
	}
	fclose(fp);
    #  endif
    #endif
	return 1;
    }
    ]])],[ac_cv_test_arm_swf=yes],[],[ac_cv_test_arm_swf=no])
elif test $cpu = ppc; then
    if test "x$DISASSEMBLER" != "xno"; then
	save_LIBS="$LIBS"
	LIBS="$LIBS $SHLIB"
	AC_CHECK_FUNCS(disassemble_init_for_target disassemble_init_powerpc)
	LIBS="$save_LIBS"
    fi
fi
CFLAGS=$save_CFLAGS

AM_CONDITIONAL(test_x86_x87, [test x$ac_cv_test_x86_x87 = xyes])
AM_CONDITIONAL(test_arm_arm, [test x$ac_cv_test_arm_arm = xyes])
AM_CONDITIONAL(test_arm_swf, [test x$ac_cv_test_arm_swf = xyes])

AM_CONDITIONAL(test_nodata, [test cpu-$cpu = cpu-mips -o cpu-$cpu = cpu-ppc -o cpu-$cpu = cpu-sparc -o cpu-$cpu = cpu-x86 -o cpu-$cpu = cpu-ia64 -o cpu-$cpu = cpu-hppa -o cpu-$cpu = cpu-s390 -o cpu-$cpu = cpu-alpha])

if test $cpu = arm; then
     AC_CHECK_LIB(m, sqrtf, ,
        [AC_MSG_ERROR([sqrtf required but not available])])
fi
AC_SUBST(cpu)

AC_SUBST([LIGHTNING_CFLAGS])

if test $ac_cv_header_stdint_h = yes; then
    AC_SUBST(MAYBE_INCLUDE_STDINT_H, ["#include <stdint.h>"])
fi

AC_CONFIG_FILES([Makefile
	   lightning.pc
           gnulib-lib/Makefile
	   doc/Makefile
	   include/Makefile
	   include/lightning/Makefile
	   include/lightning.h
	   lib/Makefile
	   check/Makefile])
AC_OUTPUT
Commit	Line	Data
	1	dnl
	2	dnl Copyright 2000, 2001, 2002, 2012-2019 Free Software Foundation, Inc.
	3	dnl
	4	dnl This file is part of GNU lightning.
	5	dnl
	6	dnl GNU lightning is free software; you can redistribute it and/or modify it
	7	dnl under the terms of the GNU Lesser General Public License as published
	8	dnl by the Free Software Foundation; either version 3, or (at your option)
	9	dnl any later version.
	10	dnl
	11	dnl GNU lightning is distributed in the hope that it will be useful, but
	12	dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
	13	dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
	14	dnl License for more details.
	15	dnl
	16
	17	AC_PREREQ([2.71])
	18	AC_INIT([GNU lightning],[2.1.3],[pcpa@gnu.org],[lightning])
	19	AC_CONFIG_AUX_DIR([build-aux])
	20	AC_CANONICAL_TARGET
	21	AC_CONFIG_SRCDIR([Makefile.am])
	22	AM_INIT_AUTOMAKE([dist-bzip2])
	23	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	24	AC_CONFIG_MACRO_DIR([m4])
	25
	26	AC_CONFIG_HEADERS([config.h])
	27
	28	AC_PROG_CC
	29	gl_EARLY
	30	AM_PROG_AR
	31	LT_INIT
	32	gl_INIT
	33
	34	case "$target_cpu" in
	35	ia64)
	36	case "$host_os" in
	37	# Only supported mode
	38	hpux)
	39	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -mlp64" ;;
	40	*) ;;
	41	esac ;;
	42	mips)
	43	case "$host_os" in
	44	# (Hack) Flags to pass configure with gcc 3.x
	45	# Should not set LIGHTNINT_CFLAGS
	46	irix)
	47	CFLAGS="$CFLAGS -D__c99 -Drestrict=";;
	48	*) ;;
	49	esac ;;
	50	alpha*)
	51	case "$host_os" in
	52	osf*)
	53	# Get proper varargs and mmap prototypes and definitions
	54	CFLAGS="$CFLAGS -D_ANSI_C_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_OSF_SOURCE -D_POSIX_C_SOURCE=199309L"
	55	# Want to generate NaN with 0.0/0.0 and Inf with 1.0/0.0
	56	if test x$GCC = "xyes"; then
	57	CFLAGS="$CFLAGS -mieee"
	58	else
	59	CFLAGS="$CFLAGS -ieee_with_no_inexact"
	60	fi ;;
	61	*) ;;
	62	esac ;;
	63	*) ;;
	64	esac
	65
	66	AC_CHECK_FUNCS(mmap mremap ffsl getopt_long_only isnan isinf,,)
	67
	68	AC_CHECK_HEADERS([getopt.h stdint.h],,,)
	69
	70	AC_ARG_ENABLE(disassembler,
	71	AS_HELP_STRING([--enable-disassembler],
	72	[Enable jit disassembler using binutils]),
	73	[DISASSEMBLER=$enableval], [DISASSEMBLER=auto])
	74	if test "x$DISASSEMBLER" != "xno"; then
	75
	76	AC_CHECK_LIB(iberty, htab_try_create, ,
	77	[HAVE_IBERTY="no"])
	78	AC_CHECK_LIB(bfd, bfd_init, ,
	79	[HAVE_BFD="no"])
	80	AC_CHECK_LIB(z, compressBound, ,
	81	[HAVE_Z="no"])
	82	AC_CHECK_LIB(opcodes, init_disassemble_info, ,
	83	[HAVE_OPCODES="no"])
	84
	85	if test "x$HAVE_IBERTY" = "xno"; then
	86	if test "x$DISASSEMBLER" = "xyes"; then
	87	AC_MSG_ERROR([libiberty not found])
	88	else
	89	AC_MSG_WARN([libiberty not found])
	90	DISASSEMBLER="no"
	91	fi
	92	fi
	93
	94	if test "x$HAVE_BFD" = "xno"; then
	95	if test "x$DISASSEMBLER" = "xyes"; then
	96	AC_MSG_ERROR([binutils BFD not found, see http://www.gnu.org/software/binutils/])
	97	else
	98	AC_MSG_WARN([binutils BFD not found, see http://www.gnu.org/software/binutils/])
	99	DISASSEMBLER="no"
	100	fi
	101	fi
	102
	103	if test "x$HAVE_Z" = "xno"; then
	104	if test "x$DISASSEMBLER" = "xyes"; then
	105	AC_MSG_ERROR([zlib not found, see https://zlib.net/])
	106	else
	107	AC_MSG_WARN([zlib not found, see https://zlib.net/])
	108	DISASSEMBLER="no"
	109	fi
	110	fi
	111
	112	if test "x$HAVE_OPCODES" = "xno"; then
	113	if test "x$DISASSEMBLER" = "xyes"; then
	114	AC_MSG_ERROR([binutils opcodes not found, see https://www.gnu.org/software/binutils/])
	115	else
	116	AC_MSG_WARN([binutils opcodes not found, see https://www.gnu.org/software/binutils/])
	117	DISASSEMBLER="no"
	118	fi
	119	fi
	120
	121	fi
	122	AM_CONDITIONAL(with_disassembler, [test "x$DISASSEMBLER" != "xno"])
	123	if test "x$DISASSEMBLER" != "xno"; then
	124	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDISASSEMBLER=1"
	125	save_CFLAGS=$CFLAGS
	126	CFLAGS="$CFLAGS -D_GNU_SOURCE"
	127	AC_COMPILE_IFELSE([AC_LANG_SOURCE(
	128	#include <dis-asm.h>
	129	int main(int argc, char *argv[])
	130	{
	131	disassembler_ftype print;
	132	bfd *abfd;
	133	print = disassembler(abfd);
	134	return 0;
	135	}
	136	)], [ac_cv_test_new_disassembler=no],,)
	137	AC_COMPILE_IFELSE([AC_LANG_SOURCE(
	138	#include <dis-asm.h>
	139	int main(int argc, char *argv[])
	140	{
	141	struct disassemble_info dinfo;
	142	INIT_DISASSEMBLE_INFO(dinfo, NULL, NULL, NULL);
	143	return 0;
	144	}
	145	)], [ac_cv_test_new_disassemble_info=yes],[ac_cv_test_new_disassemble_info=no],)
	146	CFLAGS="$save_CFLAGS"
	147	if test "x$ac_cv_test_new_disassembler" != "xno"; then
	148	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_29=1"
	149	fi
	150	if test "x$ac_cv_test_new_disassemble_info" != "xno"; then
	151	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DBINUTILS_2_38=1"
	152	fi
	153	fi
	154
	155	AC_ARG_ENABLE(devel-disassembler,
	156	AS_HELP_STRING([--enable-devel-disassembler],
	157	[Enable extra disassembly options]),
	158	[DEVEL_DISASSEMBLER=$enableval], [DEVEL_DISASSEMBLER=no])
	159	if test "x$DEVEL_DISASSEMBLER" != "xno"; then
	160	if test "x$DISASSEMBLER" = "xno"; then
	161	AC_MSG_ERROR(devel-disassembler needs disassembler enabled)
	162	fi
	163	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEVEL_DISASSEMBLER=1"
	164	fi
	165
	166	AC_ARG_ENABLE(assertions,
	167	AS_HELP_STRING([--enable-assertions],
	168	[Enable runtime code generation assertions]),
	169	[DEBUG=$enableval], [DEBUG=auto])
	170	if test "x$DEBUG" = xyes; then
	171	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DDEBUG=1"
	172	else
	173	LIGHTNING_CFLAGS="$LIGHTNING_CFLAGS -DNDEBUG"
	174	DEBUG=no
	175	fi
	176
	177	# This option is only useful during development.
	178	AC_ARG_ENABLE(devel-get-jit-size,
	179	AS_HELP_STRING([--enable-devel-get-jit-size],
	180	[Devel mode to regenerate jit size information]),
	181	[GET_JIT_SIZE=$enableval], [GET_JIT_SIZE=no])
	182	AM_CONDITIONAL(get_jit_size, [test $GET_JIT_SIZE = yes])
	183
	184	case "$host_os" in
	185	bsd\|osf*) SHLIB="" ;;
	186	hpux) SHLIB="-ldld" ;;
	187	*) SHLIB="-ldl" ;;
	188	esac
	189	AC_SUBST(SHLIB)
	190
	191	cpu=
	192	case "$target_cpu" in
	193	i?86\|x86_64\|amd64) cpu=x86 ;;
	194	arm) cpu=arm ;;
	195	mips) cpu=mips ;;
	196	powerpc) cpu=ppc ;;
	197	sparc) cpu=sparc ;;
	198	ia64) cpu=ia64 ;;
	199	hppa*) cpu=hppa ;;
	200	aarch64) cpu=aarch64 ;;
	201	s390*) cpu=s390 ;;
	202	alpha*) cpu=alpha ;;
	203	riscv*) cpu=riscv ;;
	204	loongarch*) cpu=loongarch ;;
	205	*) ;;
	206	esac
	207	AM_CONDITIONAL(cpu_arm, [test cpu-$cpu = cpu-arm])
	208	AM_CONDITIONAL(cpu_mips, [test cpu-$cpu = cpu-mips])
	209	AM_CONDITIONAL(cpu_ppc, [test cpu-$cpu = cpu-ppc])
	210	AM_CONDITIONAL(cpu_sparc, [test cpu-$cpu = cpu-sparc])
	211	AM_CONDITIONAL(cpu_x86, [test cpu-$cpu = cpu-x86])
	212	AM_CONDITIONAL(cpu_ia64, [test cpu-$cpu = cpu-ia64])
	213	AM_CONDITIONAL(cpu_hppa, [test cpu-$cpu = cpu-hppa])
	214	AM_CONDITIONAL(cpu_aarch64, [test cpu-$cpu = cpu-aarch64])
	215	AM_CONDITIONAL(cpu_s390, [test cpu-$cpu = cpu-s390])
	216	AM_CONDITIONAL(cpu_alpha, [test cpu-$cpu = cpu-alpha])
	217	AM_CONDITIONAL(cpu_riscv, [test cpu-$cpu = cpu-riscv])
	218	AM_CONDITIONAL(cpu_loongarch, [test cpu-$cpu = cpu-loongarch])
	219
	220	# Test x87 if both, x87 and sse2 available
	221	ac_cv_test_x86_x87=
	222	# Test arm instruction set if thumb instruction set available
	223	ac_cv_test_arm_arm=
	224	# Test sofware float if vfp available and not using hard float abi
	225	ac_cv_test_arm_swf=
	226
	227	save_CFLAGS=$CFLAGS
	228	CFLAGS="$CFLAGS -D_GNU_SOURCE"
	229	if test x$cpu = x; then
	230	AC_MSG_ERROR([cpu $target_cpu not supported])
	231	elif test $cpu = x86; then
	232	AC_RUN_IFELSE([AC_LANG_SOURCE([[
	233	int main(void) {
	234	int ac, flags;
	235	unsigned int eax, ebx, ecx, edx;
	236	if (__WORDSIZE == 64)
	237	return 1;
	238	__asm__ volatile ("pushfl;\n\t"
	239	"popl %0;\n\t"
	240	"movl \$0x240000, %1;\n\t"
	241	"xorl %0, %1;\n\t"
	242	"pushl %1;\n\t"
	243	"popfl;\n\t"
	244	"pushfl;\n\t"
	245	"popl %1;\n\t"
	246	"xorl %0, %1;\n\t"
	247	"pushl %0;\n\t"
	248	"popfl"
	249	: "=r" (flags), "=r" (ac));
	250	if ((ac & (1 << 21)) == 0)
	251	return 1;
	252	__asm__ volatile ("xchgl %%ebx, %1; cpuid; xchgl %%ebx, %1"
	253	: "=a" (eax), "=r" (ebx),
	254	"=c" (ecx), "=d" (edx)
	255	: "0" (1));
	256	return (edx & 1 << 26) ? 0 : 1;
	257	}
	258	]])],[ac_cv_test_x86_x87=yes],[],[ac_cv_test_x86_x87=no])
	259	elif test $cpu = arm; then
	260	AC_RUN_IFELSE([AC_LANG_SOURCE([[
	261	#include <stdio.h>
	262	int main(void) {
	263	#if defined(__linux__)
	264	FILE *fp;
	265	char buf[128];
	266	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	267	return 1;
	268	while (fgets(buf, sizeof(buf), fp)) {
	269	if (strncmp(buf, "Features\t:", 10) == 0 &&
	270	strstr(buf + 10, "thumb")) {
	271	fclose(fp);
	272	return 0;
	273	}
	274	}
	275	fclose(fp);
	276	#elif defined(__thumb2__)
	277	return 0;
	278	#endif
	279	return 1;
	280	}
	281	]])],[ac_cv_test_arm_arm=yes],[],[ac_cv_test_arm_arm=no])
	282	AC_RUN_IFELSE([AC_LANG_SOURCE([[
	283	#include <stdio.h>
	284	int main(void) {
	285	#if defined(__linux__)
	286	FILE *fp;
	287	char buf[128];
	288	# if !defined(__ARM_PCS_VFP)
	289	if ((fp = fopen("/proc/cpuinfo", "r")) == NULL)
	290	return 1;
	291	while (fgets(buf, sizeof(buf), fp)) {
	292	if (strncmp(buf, "Features\t:", 10) == 0 &&
	293	strstr(buf + 10, "vfp")) {
	294	fclose(fp);
	295	return 0;
	296	}
	297	}
	298	fclose(fp);
	299	# endif
	300	#endif
	301	return 1;
	302	}
	303	]])],[ac_cv_test_arm_swf=yes],[],[ac_cv_test_arm_swf=no])
	304	elif test $cpu = ppc; then
	305	if test "x$DISASSEMBLER" != "xno"; then
	306	save_LIBS="$LIBS"
	307	LIBS="$LIBS $SHLIB"
	308	AC_CHECK_FUNCS(disassemble_init_for_target disassemble_init_powerpc)
	309	LIBS="$save_LIBS"
	310	fi
	311	fi
	312	CFLAGS=$save_CFLAGS
	313
	314	AM_CONDITIONAL(test_x86_x87, [test x$ac_cv_test_x86_x87 = xyes])
	315	AM_CONDITIONAL(test_arm_arm, [test x$ac_cv_test_arm_arm = xyes])
	316	AM_CONDITIONAL(test_arm_swf, [test x$ac_cv_test_arm_swf = xyes])
	317
	318	AM_CONDITIONAL(test_nodata, [test cpu-$cpu = cpu-mips -o cpu-$cpu = cpu-ppc -o cpu-$cpu = cpu-sparc -o cpu-$cpu = cpu-x86 -o cpu-$cpu = cpu-ia64 -o cpu-$cpu = cpu-hppa -o cpu-$cpu = cpu-s390 -o cpu-$cpu = cpu-alpha])
	319
	320	if test $cpu = arm; then
	321	AC_CHECK_LIB(m, sqrtf, ,
	322	[AC_MSG_ERROR([sqrtf required but not available])])
	323	fi
	324	AC_SUBST(cpu)
	325
	326	AC_SUBST([LIGHTNING_CFLAGS])
	327
	328	if test $ac_cv_header_stdint_h = yes; then
	329	AC_SUBST(MAYBE_INCLUDE_STDINT_H, ["#include <stdint.h>"])
	330	fi
	331
	332	AC_CONFIG_FILES([Makefile
	333	lightning.pc
	334	gnulib-lib/Makefile
	335	doc/Makefile
	336	include/Makefile
	337	include/lightning/Makefile
	338	include/lightning.h
	339	lib/Makefile
	340	check/Makefile])
	341	AC_OUTPUT