Pico/Memory.s

   1 @ vim:filetype=armasm\r
   2 \r
   3 @ memory handlers with banking support for SSF II - The New Challengers\r
   4 @ mostly based on Gens code\r
   5 \r
   6 @ (c) Copyright 2006-2007, Grazvydas "notaz" Ignotas\r
   7 @ All Rights Reserved\r
   8 \r
   9 \r
  10 .include "port_config.s"\r
  11 \r
  12 .text\r
  13 .align 4\r
  14 \r
  15 @ default jump tables\r
  16 \r
  17 m_read8_def_table:\r
  18     .long   m_read8_rom0    @ 0x000000 - 0x07FFFF\r
  19     .long   m_read8_rom1    @ 0x080000 - 0x0FFFFF\r
  20     .long   m_read8_rom2    @ 0x100000 - 0x17FFFF\r
  21     .long   m_read8_rom3    @ 0x180000 - 0x1FFFFF\r
  22     .long   m_read8_rom4    @ 0x200000 - 0x27FFFF\r
  23     .long   m_read8_rom5    @ 0x280000 - 0x2FFFFF\r
  24     .long   m_read8_rom6    @ 0x300000 - 0x37FFFF\r
  25     .long   m_read8_rom7    @ 0x380000 - 0x3FFFFF\r
  26     .long   m_read8_rom8    @ 0x400000 - 0x47FFFF - for all those large ROM hacks\r
  27     .long   m_read8_rom9    @ 0x480000 - 0x4FFFFF\r
  28     .long   m_read8_romA    @ 0x500000 - 0x57FFFF\r
  29     .long   m_read8_romB    @ 0x580000 - 0x5FFFFF\r
  30     .long   m_read8_romC    @ 0x600000 - 0x67FFFF\r
  31     .long   m_read8_romD    @ 0x680000 - 0x6FFFFF\r
  32     .long   m_read8_romE    @ 0x700000 - 0x77FFFF\r
  33     .long   m_read8_romF    @ 0x780000 - 0x7FFFFF\r
  34     .long   m_read8_rom10   @ 0x800000 - 0x87FFFF\r
  35     .long   m_read8_rom11   @ 0x880000 - 0x8FFFFF\r
  36     .long   m_read8_rom12   @ 0x900000 - 0x97FFFF\r
  37     .long   m_read8_rom13   @ 0x980000 - 0x9FFFFF\r
  38     .long   m_read8_misc    @ 0xA00000 - 0xA7FFFF\r
  39     .long   m_read_null     @ 0xA80000 - 0xAFFFFF\r
  40     .long   m_read_null     @ 0xB00000 - 0xB7FFFF\r
  41     .long   m_read_null     @ 0xB80000 - 0xBFFFFF\r
  42     .long   m_read8_vdp     @ 0xC00000 - 0xC7FFFF\r
  43     .long   m_read8_vdp     @ 0xC80000 - 0xCFFFFF\r
  44     .long   m_read8_vdp     @ 0xD00000 - 0xD7FFFF\r
  45     .long   m_read8_vdp     @ 0xD80000 - 0xDFFFFF\r
  46     .long   m_read8_ram     @ 0xE00000 - 0xE7FFFF\r
  47     .long   m_read8_ram     @ 0xE80000 - 0xEFFFFF\r
  48     .long   m_read8_ram     @ 0xF00000 - 0xF7FFFF\r
  49     .long   m_read8_ram     @ 0xF80000 - 0xFFFFFF\r
  50 \r
  51 m_read16_def_table:\r
  52     .long   m_read16_rom0    @ 0x000000 - 0x07FFFF\r
  53     .long   m_read16_rom1    @ 0x080000 - 0x0FFFFF\r
  54     .long   m_read16_rom2    @ 0x100000 - 0x17FFFF\r
  55     .long   m_read16_rom3    @ 0x180000 - 0x1FFFFF\r
  56     .long   m_read16_rom4    @ 0x200000 - 0x27FFFF\r
  57     .long   m_read16_rom5    @ 0x280000 - 0x2FFFFF\r
  58     .long   m_read16_rom6    @ 0x300000 - 0x37FFFF\r
  59     .long   m_read16_rom7    @ 0x380000 - 0x3FFFFF\r
  60     .long   m_read16_rom8    @ 0x400000 - 0x47FFFF\r
  61     .long   m_read16_rom9    @ 0x480000 - 0x4FFFFF\r
  62     .long   m_read16_romA    @ 0x500000 - 0x57FFFF\r
  63     .long   m_read16_romB    @ 0x580000 - 0x5FFFFF\r
  64     .long   m_read16_romC    @ 0x600000 - 0x67FFFF\r
  65     .long   m_read16_romD    @ 0x680000 - 0x6FFFFF\r
  66     .long   m_read16_romE    @ 0x700000 - 0x77FFFF\r
  67     .long   m_read16_romF    @ 0x780000 - 0x7FFFFF\r
  68     .long   m_read16_rom10   @ 0x800000 - 0x87FFFF\r
  69     .long   m_read16_rom11   @ 0x880000 - 0x8FFFFF\r
  70     .long   m_read16_rom12   @ 0x900000 - 0x97FFFF\r
  71     .long   m_read16_rom13   @ 0x980000 - 0x9FFFFF\r
  72     .long   m_read16_misc    @ 0xA00000 - 0xA7FFFF\r
  73     .long   m_read_null      @ 0xA80000 - 0xAFFFFF\r
  74     .long   m_read_null      @ 0xB00000 - 0xB7FFFF\r
  75     .long   m_read_null      @ 0xB80000 - 0xBFFFFF\r
  76     .long   m_read16_vdp     @ 0xC00000 - 0xC7FFFF\r
  77     .long   m_read16_vdp     @ 0xC80000 - 0xCFFFFF\r
  78     .long   m_read16_vdp     @ 0xD00000 - 0xD7FFFF\r
  79     .long   m_read16_vdp     @ 0xD80000 - 0xDFFFFF\r
  80     .long   m_read16_ram     @ 0xE00000 - 0xE7FFFF\r
  81     .long   m_read16_ram     @ 0xE80000 - 0xEFFFFF\r
  82     .long   m_read16_ram     @ 0xF00000 - 0xF7FFFF\r
  83     .long   m_read16_ram     @ 0xF80000 - 0xFFFFFF\r
  84 \r
  85 m_read32_def_table:\r
  86     .long   m_read32_rom0    @ 0x000000 - 0x07FFFF\r
  87     .long   m_read32_rom1    @ 0x080000 - 0x0FFFFF\r
  88     .long   m_read32_rom2    @ 0x100000 - 0x17FFFF\r
  89     .long   m_read32_rom3    @ 0x180000 - 0x1FFFFF\r
  90     .long   m_read32_rom4    @ 0x200000 - 0x27FFFF\r
  91     .long   m_read32_rom5    @ 0x280000 - 0x2FFFFF\r
  92     .long   m_read32_rom6    @ 0x300000 - 0x37FFFF\r
  93     .long   m_read32_rom7    @ 0x380000 - 0x3FFFFF\r
  94     .long   m_read32_rom8    @ 0x400000 - 0x47FFFF\r
  95     .long   m_read32_rom9    @ 0x480000 - 0x4FFFFF\r
  96     .long   m_read32_romA    @ 0x500000 - 0x57FFFF\r
  97     .long   m_read32_romB    @ 0x580000 - 0x5FFFFF\r
  98     .long   m_read32_romC    @ 0x600000 - 0x67FFFF\r
  99     .long   m_read32_romD    @ 0x680000 - 0x6FFFFF\r
 100     .long   m_read32_romE    @ 0x700000 - 0x77FFFF\r
 101     .long   m_read32_romF    @ 0x780000 - 0x7FFFFF\r
 102     .long   m_read32_rom10   @ 0x800000 - 0x87FFFF\r
 103     .long   m_read32_rom11   @ 0x880000 - 0x8FFFFF\r
 104     .long   m_read32_rom12   @ 0x900000 - 0x97FFFF\r
 105     .long   m_read32_rom13   @ 0x980000 - 0x9FFFFF\r
 106     .long   m_read32_misc    @ 0xA00000 - 0xA7FFFF\r
 107     .long   m_read_null      @ 0xA80000 - 0xAFFFFF\r
 108     .long   m_read_null      @ 0xB00000 - 0xB7FFFF\r
 109     .long   m_read_null      @ 0xB80000 - 0xBFFFFF\r
 110     .long   m_read32_vdp     @ 0xC00000 - 0xC7FFFF\r
 111     .long   m_read32_vdp     @ 0xC80000 - 0xCFFFFF\r
 112     .long   m_read32_vdp     @ 0xD00000 - 0xD7FFFF\r
 113     .long   m_read32_vdp     @ 0xD80000 - 0xDFFFFF\r
 114     .long   m_read32_ram     @ 0xE00000 - 0xE7FFFF\r
 115     .long   m_read32_ram     @ 0xE80000 - 0xEFFFFF\r
 116     .long   m_read32_ram     @ 0xF00000 - 0xF7FFFF\r
 117     .long   m_read32_ram     @ 0xF80000 - 0xFFFFFF\r
 118 \r
 119 \r
 120 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 121 \r
 122 .bss\r
 123 .align 4\r
 124 @.section .bss, "brw"\r
 125 @.data\r
 126 \r
 127 @ used tables\r
 128 m_read8_table:\r
 129     .skip 32*4\r
 130 \r
 131 m_read16_table:\r
 132     .skip 32*4\r
 133 \r
 134 m_read32_table:\r
 135     .skip 32*4\r
 136 \r
 137 \r
 138 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 139 \r
 140 .text\r
 141 .align 4\r
 142 \r
 143 .global PicoMemReset\r
 144 .global PicoRead8\r
 145 .global PicoRead16\r
 146 .global PicoRead32\r
 147 .global PicoWrite8\r
 148 .global PicoWriteRomHW_SSF2\r
 149 .global m_m68k_read8_misc\r
 150 .global m_m68k_write8_misc\r
 151 \r
 152 \r
 153 PicoMemReset:\r
 154     ldr     r12,=(Pico+0x22204)\r
 155     ldr     r12,[r12]                @ romsize\r
 156     add     r12,r12,#0x80000\r
 157     sub     r12,r12,#1\r
 158     mov     r12,r12,lsr #19\r
 159 \r
 160     ldr     r0, =m_read8_table\r
 161     ldr     r1, =m_read8_def_table\r
 162     mov     r2, #32\r
 163 1:\r
 164     ldr     r3, [r1], #4\r
 165     str     r3, [r0], #4\r
 166     subs    r2, r2, #1\r
 167     bne     1b\r
 168 \r
 169     ldr     r0, =m_read16_table\r
 170     ldr     r1, =m_read16_def_table\r
 171     mov     r2, #32\r
 172 1:\r
 173     subs    r2, r2, #1\r
 174     ldr     r3, [r1], #4\r
 175     str     r3, [r0], #4\r
 176     bne     1b\r
 177 \r
 178     ldr     r0, =m_read32_table\r
 179     ldr     r1, =m_read32_def_table\r
 180     mov     r2, #32\r
 181 1:\r
 182     subs    r2, r2, #1\r
 183     ldr     r3, [r1], #4\r
 184     str     r3, [r0], #4\r
 185     bne     1b\r
 186 \r
 187     @ update memhandlers according to ROM size\r
 188     ldr     r1, =m_read8_above_rom\r
 189     ldr     r0, =m_read8_table\r
 190     mov     r2, #20\r
 191 1:\r
 192     sub     r2, r2, #1\r
 193     cmp     r2, r12\r
 194     blt     2f\r
 195     cmp     r2, #4\r
 196     beq     1b                      @ do not touch the SRAM area\r
 197     str     r1, [r0, r2, lsl #2]\r
 198     b       1b\r
 199 2:\r
 200     ldr     r1, =m_read16_above_rom\r
 201     ldr     r0, =m_read16_table\r
 202     mov     r2, #20\r
 203 1:\r
 204     sub     r2, r2, #1\r
 205     cmp     r2, r12\r
 206     blt     2f\r
 207     cmp     r2, #4\r
 208     beq     1b\r
 209     str     r1, [r0, r2, lsl #2]\r
 210     b       1b\r
 211 2:\r
 212     ldr     r1, =m_read32_above_rom\r
 213     ldr     r0, =m_read32_table\r
 214     mov     r2, #20\r
 215 1:\r
 216     sub     r2, r2, #1\r
 217     cmp     r2, r12\r
 218     blt     2f\r
 219     cmp     r2, #4\r
 220     beq     1b\r
 221     str     r1, [r0, r2, lsl #2]\r
 222     b       1b\r
 223 2:\r
 224     bx      lr\r
 225 \r
 226 .pool\r
 227 \r
 228 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 229 \r
 230 PicoRead8: @ u32 a\r
 231     ldr     r2, =m_read8_table\r
 232     bic     r0, r0, #0xff000000\r
 233     and     r1, r0, #0x00f80000\r
 234     ldr     pc, [r2, r1, lsr #17]\r
 235 \r
 236 PicoRead16: @ u32 a\r
 237     ldr     r2, =m_read16_table\r
 238     bic     r0, r0, #0xff000000\r
 239     and     r1, r0, #0x00f80000\r
 240     ldr     pc, [r2, r1, lsr #17]\r
 241 \r
 242 PicoRead32: @ u32 a\r
 243     ldr     r2, =m_read32_table\r
 244     bic     r0, r0, #0xff000000\r
 245     and     r1, r0, #0x00f80000\r
 246     ldr     pc, [r2, r1, lsr #17]\r
 247 \r
 248 .pool\r
 249 \r
 250 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 251 \r
 252 m_read_null:\r
 253     mov     r0, #0\r
 254     bx      lr\r
 255 \r
 256 \r
 257 .macro m_read8_rom sect\r
 258     ldr     r1, =(Pico+0x22200)\r
 259     bic     r0, r0, #0xf80000\r
 260     ldr     r1, [r1]\r
 261 .if \sect\r
 262     orr     r0, r0, #0x080000*\sect\r
 263 .endif\r
 264     eor     r0, r0, #1\r
 265     ldrb    r0, [r1, r0]\r
 266     bx      lr\r
 267 .endm\r
 268 \r
 269 \r
 270 m_read8_rom0: @ 0x000000 - 0x07ffff\r
 271     m_read8_rom 0\r
 272 \r
 273 m_read8_rom1: @ 0x080000 - 0x0fffff\r
 274     m_read8_rom 1\r
 275 \r
 276 m_read8_rom2: @ 0x100000 - 0x17ffff\r
 277     m_read8_rom 2\r
 278 \r
 279 m_read8_rom3: @ 0x180000 - 0x1fffff\r
 280     m_read8_rom 3\r
 281 \r
 282 m_read8_rom4: @ 0x200000 - 0x27ffff, SRAM area\r
 283     ldr     r2, =(SRam)\r
 284     ldr     r3, =(Pico+0x22200)\r
 285     ldr     r1, [r2, #8]    @ SRam.end\r
 286     bic     r0, r0, #0xf80000\r
 287     orr     r0, r0, #0x200000\r
 288     cmp     r0, r1\r
 289     bgt     m_read8_nosram\r
 290     ldr     r1, [r2, #4]    @ SRam.start\r
 291     cmp     r0, r1\r
 292     blt     m_read8_nosram\r
 293     ldrb    r1, [r3, #0x11] @ Pico.m.sram_reg\r
 294     tst     r1, #5\r
 295     bne     SRAMRead\r
 296 m_read8_nosram:\r
 297     ldr     r1, [r3, #4]    @ romsize\r
 298     cmp     r0, r1\r
 299     movgt   r0, #0\r
 300     bxgt    lr              @ bad location\r
 301     ldr     r1, [r3]\r
 302     eor     r0, r0, #1\r
 303     ldrb    r0, [r1, r0]\r
 304     bx      lr\r
 305 \r
 306 m_read8_rom5: @ 0x280000 - 0x2fffff\r
 307     m_read8_rom 5\r
 308 \r
 309 m_read8_rom6: @ 0x300000 - 0x37ffff\r
 310     m_read8_rom 6\r
 311 \r
 312 m_read8_rom7: @ 0x380000 - 0x3fffff\r
 313     m_read8_rom 7\r
 314 \r
 315 m_read8_rom8: @ 0x400000 - 0x47ffff\r
 316     m_read8_rom 8\r
 317 \r
 318 m_read8_rom9: @ 0x480000 - 0x4fffff\r
 319     m_read8_rom 9\r
 320 \r
 321 m_read8_romA: @ 0x500000 - 0x57ffff\r
 322     m_read8_rom 0xA\r
 323 \r
 324 m_read8_romB: @ 0x580000 - 0x5fffff\r
 325     m_read8_rom 0xB\r
 326 \r
 327 m_read8_romC: @ 0x600000 - 0x67ffff\r
 328     m_read8_rom 0xC\r
 329 \r
 330 m_read8_romD: @ 0x680000 - 0x6fffff\r
 331     m_read8_rom 0xD\r
 332 \r
 333 m_read8_romE: @ 0x700000 - 0x77ffff\r
 334     m_read8_rom 0xE\r
 335 \r
 336 m_read8_romF: @ 0x780000 - 0x7fffff\r
 337     m_read8_rom 0xF\r
 338 \r
 339 m_read8_rom10: @ 0x800000 - 0x87ffff\r
 340     m_read8_rom 0x10\r
 341 \r
 342 m_read8_rom11: @ 0x880000 - 0x8fffff\r
 343     m_read8_rom 0x11\r
 344 \r
 345 m_read8_rom12: @ 0x900000 - 0x97ffff\r
 346     m_read8_rom 0x12\r
 347 \r
 348 m_read8_rom13: @ 0x980000 - 0x9fffff\r
 349     m_read8_rom 0x13\r
 350 \r
 351 \r
 352 m_m68k_read8_misc:\r
 353 m_read8_misc:\r
 354     bic     r2, r0, #0x001f @ most commonly we get i/o port read,\r
 355     cmp     r2, #0xa10000   @ so check for it first\r
 356     bne     m_read8_misc2\r
 357 m_read8_misc_io:\r
 358     ands    r0, r0, #0x1e\r
 359     beq     m_read8_misc_hwreg\r
 360     cmp     r0, #4\r
 361     movlt   r0, #0\r
 362     moveq   r0, #1\r
 363     ble     PadRead\r
 364     ldr     r3, =(Pico+0x22000)\r
 365     mov     r0, r0, lsr #1  @ other IO ports (Pico.ioports[a])\r
 366     ldrb    r0, [r3, r0]\r
 367     bx      lr\r
 368 \r
 369 m_read8_misc_hwreg:\r
 370     ldr     r3, =(Pico+0x22200)\r
 371     ldrb    r0, [r3, #0x0f] @ Pico.m.hardware\r
 372     bx      lr\r
 373 \r
 374 m_read8_misc2:\r
 375     mov     r2,     #0xa10000 @ games also like to poll busreq,\r
 376     orr     r2, r2, #0x001100 @ so we'll try it now\r
 377     cmp     r0, r2\r
 378     beq     z80ReadBusReq\r
 379 \r
 380     and     r2, r0, #0xff0000 @ finally it might be\r
 381     cmp     r2,     #0xa00000 @ z80 area\r
 382     bne     m_read8_misc3\r
 383     tst     r0, #0x4000\r
 384     beq     z80Read8          @ z80 RAM\r
 385     and     r2, r0, #0x6000\r
 386     cmp     r2, #0x4000\r
 387     mvnne   r0, #0\r
 388     bxne    lr                @ invalid\r
 389     ldr     r1, =PicoOpt\r
 390     ldr     r1, [r1]\r
 391     tst     r1, #1\r
 392 \r
 393     ldrne   r1, =ym2612_st\r
 394     ldrne   r1, [r1]\r
 395     ldrneb  r0, [r1, #0x11]   @ ym2612_st->status\r
 396     bxne    lr\r
 397 \r
 398 m_read8_fake_ym2612:\r
 399     ldr     r3, =(Pico+0x22200)\r
 400     ldrb    r0, [r3, #8]      @ Pico.m.rotate\r
 401     add     r1, r0, #1\r
 402     strb    r1, [r3, #8]\r
 403     and     r0, r0, #3\r
 404     bx      lr\r
 405 \r
 406 m_read8_misc3:\r
 407     @ if everything else fails, use generic handler\r
 408     stmfd   sp!,{r0,lr}\r
 409     bic     r0, r0, #1\r
 410     mov     r1, #8\r
 411     bl      OtherRead16\r
 412     ldmfd   sp!,{r1,lr}\r
 413     tst     r1, #1\r
 414     moveq   r0, r0, lsr #8\r
 415     bx      lr\r
 416 \r
 417 \r
 418 m_read8_vdp:\r
 419     tst     r0, #0x70000\r
 420     tsteq   r0, #0x000e0\r
 421     bxne    lr              @ invalid read\r
 422     stmfd   sp!,{r0,lr}\r
 423     bic     r0, r0, #1\r
 424     bl      PicoVideoRead\r
 425     ldmfd   sp!,{r1,lr}\r
 426     tst     r1, #1\r
 427     moveq   r0, r0, lsr #8\r
 428     bx      lr\r
 429 \r
 430 m_read8_ram:\r
 431     ldr     r1, =Pico\r
 432     bic     r0, r0, #0xff0000\r
 433     eor     r0, r0, #1\r
 434     ldrb    r0, [r1, r0]\r
 435     bx      lr\r
 436 \r
 437 m_read8_above_rom:\r
 438     @ might still be SRam (Micro Machines, HardBall '95)\r
 439     ldr     r2, =(SRam)\r
 440     ldr     r3, =(Pico+0x22200)\r
 441     ldr     r1, [r2, #8]    @ SRam.end\r
 442     cmp     r0, r1\r
 443     bgt     m_read8_ar_nosram\r
 444     ldr     r1, [r2, #4]    @ SRam.start\r
 445     cmp     r0, r1\r
 446     blt     m_read8_ar_nosram\r
 447     ldrb    r1, [r3, #0x11] @ Pico.m.sram_reg\r
 448     tst     r1, #5\r
 449     bne     SRAMRead\r
 450 m_read8_ar_nosram:\r
 451     stmfd   sp!,{r0,lr}\r
 452     bic     r0, r0, #1\r
 453     mov     r1, #8\r
 454     bl      OtherRead16End\r
 455     ldmfd   sp!,{r1,lr}\r
 456     tst     r1, #1\r
 457     moveq   r0, r0, lsr #8\r
 458     bx      lr\r
 459 \r
 460 .pool\r
 461 \r
 462 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 463 \r
 464 .macro m_read16_rom sect\r
 465     ldr     r1, =(Pico+0x22200)\r
 466     bic     r0, r0, #0xf80000\r
 467     ldr     r1, [r1]\r
 468     bic     r0, r0, #1\r
 469 .if \sect\r
 470     orr     r0, r0, #0x080000*\sect\r
 471 .endif\r
 472     ldrh    r0, [r1, r0]\r
 473     bx      lr\r
 474 .endm\r
 475 \r
 476 \r
 477 m_read16_rom0: @ 0x000000 - 0x07ffff\r
 478     m_read16_rom 0\r
 479 \r
 480 m_read16_rom1: @ 0x080000 - 0x0fffff\r
 481     m_read16_rom 1\r
 482 \r
 483 m_read16_rom2: @ 0x100000 - 0x17ffff\r
 484     m_read16_rom 2\r
 485 \r
 486 m_read16_rom3: @ 0x180000 - 0x1fffff\r
 487     m_read16_rom 3\r
 488 \r
 489 m_read16_rom4: @ 0x200000 - 0x27ffff, SRAM area (NBA Live 95)\r
 490     ldr     r2, =(SRam)\r
 491     ldr     r3, =(Pico+0x22200)\r
 492     ldr     r1, [r2, #8]    @ SRam.end\r
 493     bic     r0, r0, #0xf80000\r
 494     bic     r0, r0, #1\r
 495     orr     r0, r0, #0x200000\r
 496     cmp     r0, r1\r
 497     bgt     m_read16_nosram\r
 498     ldr     r1, [r2, #4]    @ SRam.start\r
 499     cmp     r0, r1\r
 500     blt     m_read16_nosram\r
 501     ldrb    r1, [r3, #0x11] @ Pico.m.sram_reg\r
 502     tst     r1, #5\r
 503     beq     m_read16_nosram\r
 504     stmfd   sp!,{lr}\r
 505     bl      SRAMRead16\r
 506     ldmfd   sp!,{pc}\r
 507 m_read16_nosram:\r
 508     ldr     r1, [r3, #4]    @ romsize\r
 509     cmp     r0, r1\r
 510     movgt   r0, #0\r
 511     bxgt    lr              @ bad location\r
 512     ldr     r1, [r3]        @ 1ci\r
 513     ldrh    r0, [r1, r0]\r
 514     bx      lr\r
 515 \r
 516 m_read16_rom5: @ 0x280000 - 0x2fffff\r
 517     m_read16_rom 5\r
 518 \r
 519 m_read16_rom6: @ 0x300000 - 0x37ffff\r
 520     m_read16_rom 6\r
 521 \r
 522 m_read16_rom7: @ 0x380000 - 0x3fffff\r
 523     m_read16_rom 7\r
 524 \r
 525 m_read16_rom8: @ 0x400000 - 0x47ffff\r
 526     m_read16_rom 8\r
 527 \r
 528 m_read16_rom9: @ 0x480000 - 0x4fffff\r
 529     m_read16_rom 9\r
 530 \r
 531 m_read16_romA: @ 0x500000 - 0x57ffff\r
 532     m_read16_rom 0xA\r
 533 \r
 534 m_read16_romB: @ 0x580000 - 0x5fffff\r
 535     m_read16_rom 0xB\r
 536 \r
 537 m_read16_romC: @ 0x600000 - 0x67ffff\r
 538     m_read16_rom 0xC\r
 539 \r
 540 m_read16_romD: @ 0x680000 - 0x6fffff\r
 541     m_read16_rom 0xD\r
 542 \r
 543 m_read16_romE: @ 0x700000 - 0x77ffff\r
 544     m_read16_rom 0xE\r
 545 \r
 546 m_read16_romF: @ 0x780000 - 0x7fffff\r
 547     m_read16_rom 0xF\r
 548 \r
 549 m_read16_rom10: @ 0x800000 - 0x87ffff\r
 550     m_read16_rom 0x10\r
 551 \r
 552 m_read16_rom11: @ 0x880000 - 0x8fffff\r
 553     m_read16_rom 0x11\r
 554 \r
 555 m_read16_rom12: @ 0x900000 - 0x97ffff\r
 556     m_read16_rom 0x12\r
 557 \r
 558 m_read16_rom13: @ 0x980000 - 0x9fffff\r
 559     m_read16_rom 0x13\r
 560 \r
 561 m_read16_misc:\r
 562     bic     r0, r0, #1\r
 563     mov     r1, #16\r
 564     b       OtherRead16\r
 565 \r
 566 m_read16_vdp:\r
 567     tst     r0, #0x70000    @ if ((a&0xe700e0)==0xc00000)\r
 568     tsteq   r0, #0x000e0\r
 569     bxne    lr              @ invalid read\r
 570     bic     r0, r0, #1\r
 571     b       PicoVideoRead\r
 572 \r
 573 m_read16_ram:\r
 574     ldr     r1, =Pico\r
 575     bic     r0, r0, #0xff0000\r
 576     bic     r0, r0, #1\r
 577     ldrh    r0, [r1, r0]\r
 578     bx      lr\r
 579 \r
 580 m_read16_above_rom:\r
 581     @ might still be SRam\r
 582     ldr     r2, =(SRam)\r
 583     ldr     r3, =(Pico+0x22200)\r
 584     ldr     r1, [r2, #8]    @ SRam.end\r
 585     bic     r0, r0, #1\r
 586     cmp     r0, r1\r
 587     bgt     m_read16_ar_nosram\r
 588     ldr     r1, [r2, #4]    @ SRam.start\r
 589     cmp     r0, r1\r
 590     blt     m_read16_ar_nosram\r
 591     ldrb    r1, [r3, #0x11] @ Pico.m.sram_reg\r
 592     tst     r1, #5\r
 593     beq     m_read16_ar_nosram\r
 594     stmfd   sp!,{lr}\r
 595     bl      SRAMRead16\r
 596     ldmfd   sp!,{pc}\r
 597 m_read16_ar_nosram:\r
 598     mov     r1, #16\r
 599     b       OtherRead16End\r
 600 \r
 601 .pool\r
 602 \r
 603 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 604 \r
 605 .macro m_read32_rom sect\r
 606     ldr     r1, =(Pico+0x22200)\r
 607     bic     r0, r0, #0xf80000\r
 608     ldr     r1, [r1]\r
 609     bic     r0, r0, #1\r
 610 .if \sect\r
 611     orr     r0, r0, #0x080000*\sect\r
 612 .endif\r
 613     ldrh    r0, [r1, r0]!\r
 614     ldrh    r1, [r1, #2]           @ 1ci\r
 615     orr     r0, r1, r0, lsl #16\r
 616     bx      lr\r
 617 .endm\r
 618 \r
 619 \r
 620 m_read32_rom0: @ 0x000000 - 0x07ffff\r
 621     m_read32_rom 0\r
 622 \r
 623 m_read32_rom1: @ 0x080000 - 0x0fffff\r
 624     m_read32_rom 1\r
 625 \r
 626 m_read32_rom2: @ 0x100000 - 0x17ffff\r
 627     m_read32_rom 2\r
 628 \r
 629 m_read32_rom3: @ 0x180000 - 0x1fffff\r
 630     m_read32_rom 3\r
 631 \r
 632 m_read32_rom4: @ 0x200000 - 0x27ffff, SRAM area (does any game do long reads?)\r
 633     ldr     r2, =(SRam)\r
 634     ldr     r3, =(Pico+0x22200)\r
 635     ldr     r1, [r2, #8]    @ SRam.end\r
 636     bic     r0, r0, #0xf80000\r
 637     bic     r0, r0, #1\r
 638     orr     r0, r0, #0x200000\r
 639     cmp     r0, r1\r
 640     bgt     m_read32_nosram\r
 641     ldr     r1, [r2, #4]    @ SRam.start\r
 642     cmp     r0, r1\r
 643     blt     m_read32_nosram\r
 644     ldrb    r1, [r3, #0x11] @ Pico.m.sram_reg\r
 645     tst     r1, #5\r
 646     beq     m_read32_nosram\r
 647     stmfd   sp!,{r0,lr}\r
 648     bl      SRAMRead16\r
 649     ldmfd   sp!,{r1,lr}\r
 650     stmfd   sp!,{r0,lr}\r
 651     add     r0, r1, #2\r
 652     bl      SRAMRead16\r
 653     ldmfd   sp!,{r1,lr}\r
 654     orr     r0, r0, r1, lsl #16\r
 655     bx      lr\r
 656 m_read32_nosram:\r
 657     ldr     r1, [r3, #4]    @ romsize\r
 658     cmp     r0, r1\r
 659     movgt   r0, #0\r
 660     bxgt    lr              @ bad location\r
 661     ldr     r1, [r3]        @ (1ci)\r
 662     ldrh    r0, [r1, r0]!\r
 663     ldrh    r1, [r1, #2]    @ (2ci)\r
 664     orr     r0, r1, r0, lsl #16\r
 665     bx      lr\r
 666 \r
 667 m_read32_rom5: @ 0x280000 - 0x2fffff\r
 668     m_read32_rom 5\r
 669 \r
 670 m_read32_rom6: @ 0x300000 - 0x37ffff\r
 671     m_read32_rom 6\r
 672 \r
 673 m_read32_rom7: @ 0x380000 - 0x3fffff\r
 674     m_read32_rom 7\r
 675 \r
 676 m_read32_rom8: @ 0x400000 - 0x47ffff\r
 677     m_read32_rom 8\r
 678 \r
 679 m_read32_rom9: @ 0x480000 - 0x4fffff\r
 680     m_read32_rom 9\r
 681 \r
 682 m_read32_romA: @ 0x500000 - 0x57ffff\r
 683     m_read32_rom 0xA\r
 684 \r
 685 m_read32_romB: @ 0x580000 - 0x5fffff\r
 686     m_read32_rom 0xB\r
 687 \r
 688 m_read32_romC: @ 0x600000 - 0x67ffff\r
 689     m_read32_rom 0xC\r
 690 \r
 691 m_read32_romD: @ 0x680000 - 0x6fffff\r
 692     m_read32_rom 0xD\r
 693 \r
 694 m_read32_romE: @ 0x700000 - 0x77ffff\r
 695     m_read32_rom 0xE\r
 696 \r
 697 m_read32_romF: @ 0x780000 - 0x7fffff\r
 698     m_read32_rom 0xF\r
 699 \r
 700 m_read32_rom10: @ 0x800000 - 0x87ffff\r
 701     m_read32_rom 0x10\r
 702 \r
 703 m_read32_rom11: @ 0x880000 - 0x8fffff\r
 704     m_read32_rom 0x11\r
 705 \r
 706 m_read32_rom12: @ 0x900000 - 0x97ffff\r
 707     m_read32_rom 0x12\r
 708 \r
 709 m_read32_rom13: @ 0x980000 - 0x9fffff\r
 710     m_read32_rom 0x13\r
 711 \r
 712 m_read32_misc:\r
 713     bic     r0, r0, #1\r
 714     stmfd   sp!,{r0,lr}\r
 715     mov     r1, #32\r
 716     bl      OtherRead16\r
 717     mov     r1, r0\r
 718     ldmfd   sp!,{r0}\r
 719     stmfd   sp!,{r1}\r
 720     add     r0, r0, #2\r
 721     mov     r1, #32\r
 722     bl      OtherRead16\r
 723     ldmfd   sp!,{r1,lr}\r
 724     orr     r0, r0, r1, lsl #16\r
 725     bx      lr\r
 726 \r
 727 m_read32_vdp:\r
 728     tst     r0, #0x70000\r
 729     tsteq   r0, #0x000e0\r
 730     bxne    lr              @ invalid read\r
 731     bic     r0, r0, #1\r
 732     add     r1, r0, #2\r
 733     stmfd   sp!,{r1,lr}\r
 734     bl      PicoVideoRead\r
 735     swp     r0, r0, [sp]\r
 736     bl      PicoVideoRead\r
 737     ldmfd   sp!,{r1,lr}\r
 738     orr     r0, r0, r1, lsl #16\r
 739     bx      lr\r
 740 \r
 741 m_read32_ram:\r
 742     ldr     r1, =Pico\r
 743     bic     r0, r0, #0xff0000\r
 744     bic     r0, r0, #1\r
 745     ldrh    r0, [r1, r0]!\r
 746     ldrh    r1, [r1, #2]    @ 2ci\r
 747     orr     r0, r1, r0, lsl #16\r
 748     bx      lr\r
 749 \r
 750 m_read32_above_rom:\r
 751     bic     r0, r0, #1\r
 752     stmfd   sp!,{r0,lr}\r
 753     mov     r1, #32\r
 754     bl      OtherRead16End\r
 755     mov     r1, r0\r
 756     ldmfd   sp!,{r0}\r
 757     stmfd   sp!,{r1}\r
 758     add     r0, r0, #2\r
 759     mov     r1, #32\r
 760     bl      OtherRead16End\r
 761     ldmfd   sp!,{r1,lr}\r
 762     orr     r0, r0, r1, lsl #16\r
 763     bx      lr\r
 764 \r
 765 .pool\r
 766 \r
 767 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 768 \r
 769 PicoWriteRomHW_SSF2: @ u32 a, u32 d\r
 770     and     r0, r0, #0xe\r
 771     movs    r0, r0, lsr #1\r
 772     bne     pwr_banking\r
 773 \r
 774     @ sram register\r
 775     ldr     r2, =(Pico+0x22211) @ Pico.m.sram_reg\r
 776     ldrb    r0, [r2]\r
 777     and     r1, r1, #3\r
 778     bic     r0, r0, #3\r
 779     orr     r0, r0, r1\r
 780     strb    r0, [r2]\r
 781     bx      lr\r
 782 \r
 783 pwr_banking:\r
 784     and     r1, r1, #0x1f\r
 785 \r
 786     ldr     r3, =m_read8_def_table\r
 787     ldr     r2, =m_read8_table\r
 788     ldr     r12, [r3, r1, lsl #2]\r
 789     str     r12, [r2, r0, lsl #2]\r
 790 \r
 791     ldr     r3, =m_read16_def_table\r
 792     ldr     r2, =m_read16_table\r
 793     ldr     r12, [r3, r1, lsl #2]\r
 794     str     r12, [r2, r0, lsl #2]\r
 795 \r
 796     ldr     r3, =m_read32_def_table\r
 797     ldr     r2, =m_read32_table\r
 798     ldr     r12, [r3, r1, lsl #2]\r
 799     str     r12, [r2, r0, lsl #2]\r
 800  \r
 801     bx      lr\r
 802 \r
 803 @ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@\r
 804 \r
 805 @ Here we only handle most often used locations,\r
 806 @ everything else is passed to generic handlers\r
 807 \r
 808 PicoWrite8: @ u32 a, u8 d\r
 809     bic     r0, r0, #0xff000000\r
 810     and     r2, r0, #0x00e00000\r
 811     cmp     r2,     #0x00e00000 @ RAM?\r
 812     ldr     r3, =Pico\r
 813     biceq   r0, r0, #0x00ff0000\r
 814     eoreq   r0, r0, #1\r
 815     streqb  r1, [r3, r0]\r
 816     bxeq    lr\r
 817 \r
 818 m_m68k_write8_misc:\r
 819     bic     r2, r0, #0x1f    @ most commonly we get i/o port write,\r
 820     cmp     r2, #0xa10000    @ so check for it first\r
 821     bne     m_write8_misc2\r
 822 m_write8_io:\r
 823     ldr     r2, =PicoOpt\r
 824     and     r0, r0, #0x1e\r
 825     ldr     r2, [r2]\r
 826     ldr     r3, =(Pico+0x22000) @ Pico.ioports\r
 827     tst     r2, #0x20        @ 6 button pad?\r
 828     streqb  r1, [r3, r0, lsr #1]\r
 829     bxeq    lr\r
 830     cmp     r0, #2\r
 831     cmpne   r0, #4\r
 832     bne     m_write8_io_done @ not likely to happen\r
 833     add     r2, r3, #0x200   @ Pico+0x22200\r
 834     mov     r12,#0\r
 835     cmp     r0, #2\r
 836     streqb  r12,[r2,#0x18]\r
 837     strneb  r12,[r2,#0x19]   @ Pico.m.padDelay[i] = 0\r
 838     tst     r1, #0x40        @ TH\r
 839     beq     m_write8_io_done\r
 840     ldrb    r12,[r3, r0, lsr #1]\r
 841     tst     r12,#0x40\r
 842     bne     m_write8_io_done\r
 843     cmp     r0, #2\r
 844     ldreqb  r12,[r2,#0x0a]\r
 845     ldrneb  r12,[r2,#0x0b]   @ Pico.m.padTHPhase\r
 846     add     r12,r12,#1\r
 847     streqb  r12,[r2,#0x0a]\r
 848     strneb  r12,[r2,#0x0b]   @ Pico.m.padTHPhase\r
 849 m_write8_io_done:\r
 850     strb    r1, [r3, r0, lsr #1]\r
 851     bx      lr\r
 852 \r
 853 \r
 854 m_write8_misc2:\r
 855     and     r2, r0, #0xff0000\r
 856     cmp     r2,     #0xa00000 @ z80 area?\r
 857     bne     m_write8_not_z80\r
 858     tst     r0, #0x4000\r
 859     bne     m_write8_z80_not_ram\r
 860     ldr     r3, =(Pico+0x20000) @ Pico.zram\r
 861     add     r2, r3, #0x02200 @ Pico+0x22200\r
 862     ldrb    r2, [r2, #9]     @ Pico.m.z80Run\r
 863     bic     r0, r0, #0xff0000\r
 864     bic     r0, r0, #0x00e000\r
 865     tst     r2, #1\r
 866     streqb  r1, [r3, r0]     @ zram\r
 867     bx      lr\r
 868 \r
 869 m_write8_z80_not_ram:\r
 870     and     r2, r0, #0x6000\r
 871     cmp     r2,     #0x4000\r
 872     bne     m_write8_z80_not_ym2612\r
 873     ldr     r2, =PicoOpt\r
 874     and     r0, r0, #3\r
 875     ldr     r2, [r2]\r
 876     tst     r2, #1\r
 877     bxeq    lr\r
 878     stmfd   sp!,{lr}\r
 879 .if EXTERNAL_YM2612\r
 880     tst     r2, #0x200\r
 881     ldreq   r2, =YM2612Write_\r
 882     ldrne   r2, =YM2612Write_940\r
 883     mov     lr, pc\r
 884     bx      r2\r
 885 .else\r
 886     bl      YM2612Write_\r
 887 .endif\r
 888     ldr     r2, =emustatus\r
 889     ldmfd   sp!,{lr}\r
 890     ldr     r1, [r2]\r
 891     and     r0, r0, #1\r
 892     orr     r1, r0, r1\r
 893     str     r1, [r2]         @ emustatus|=YM2612Write(a&3, d);\r
 894     bx      lr\r
 895 \r
 896 m_write8_z80_not_ym2612:     @ not too likely\r
 897     mov     r2, r0, lsl #17\r
 898     bic     r2, r2, #6<<17\r
 899     mov     r3,     #0x7f00\r
 900     orr     r3, r3, #0x0011\r
 901     cmp     r3, r2, lsr #17  @ psg @ z80 area?\r
 902     beq     m_write8_psg\r
 903     and     r2, r0, #0x7f00\r
 904     cmp     r2,     #0x6000  @ bank register?\r
 905     bxne    lr               @ invalid write\r
 906 \r
 907 m_write8_z80_bank_reg:\r
 908     ldr     r3, =(Pico+0x22208) @ Pico.m\r
 909     ldrh    r2, [r3, #0x0a]\r
 910     mov     r1, r1, lsr #8\r
 911     orr     r2, r1, r2, lsr #1\r
 912     bic     r2, r2, #0xfe00\r
 913     strh    r2, [r3, #0x0a]\r
 914     bx      lr\r
 915 \r
 916 \r
 917 m_write8_not_z80:\r
 918     and     r2, r0, #0xe70000\r
 919     cmp     r2, #0xc00000    @ VDP area?\r
 920     bne     OtherWrite8      @ passthrough\r
 921     and     r2, r0, #0xf9\r
 922     cmp     r2, #0x11\r
 923     bne     OtherWrite8\r
 924 m_write8_psg:\r
 925     ldr     r2, =PicoOpt\r
 926     mov     r0, r1\r
 927     ldr     r2, [r2]\r
 928     tst     r2, #2\r
 929     bxeq    lr\r
 930     b       SN76496Write\r
 931 \r