deps/libchdr/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.9)
   2
   3 project(chdr C)
   4
   5 set(CHDR_VERSION_MAJOR 0)
   6 set(CHDR_VERSION_MINOR 1)
   7
   8 if(CMAKE_PROJECT_NAME STREQUAL "chdr")
   9   option(BUILD_SHARED_LIBS "Build libchdr also as a shared library" ON)
  10 endif()
  11 option(INSTALL_STATIC_LIBS "Install static libraries" OFF)
  12 option(WITH_SYSTEM_ZLIB "Use system provided zlib library" OFF)
  13
  14 if(CMAKE_C_COMPILER_ID MATCHES "GNU")
  15   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fPIC -O3 -flto")
  16   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION ON)
  17 elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
  18   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O3")
  19   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION OFF)
  20 endif()
  21
  22 include(FindPkgConfig)
  23 include(GNUInstallDirs)
  24
  25 # Detect processor type.
  26 if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86_64" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "amd64")
  27   set(CPU_ARCH "x64")
  28 elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "AMD64")
  29   # MSVC x86/x64
  30   if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  31     set(CPU_ARCH "x64")
  32   else()
  33     set(CPU_ARCH "x86")
  34   endif()
  35 elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i386" OR
  36        ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i686")
  37   set(CPU_ARCH "x86")
  38 elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "aarch64")
  39   set(CPU_ARCH "aarch64")
  40 elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "armv7-a")
  41   set(CPU_ARCH "arm")
  42 else()
  43   message(FATAL_ERROR "Unknown system processor: " ${CMAKE_SYSTEM_PROCESSOR})
  44 endif()
  45
  46 #--------------------------------------------------
  47 # dependencies
  48 #--------------------------------------------------
  49
  50
  51 # lzma
  52 add_subdirectory(deps/lzma-19.00 EXCLUDE_FROM_ALL)
  53   list(APPEND CHDR_LIBS lzma)
  54   list(APPEND CHDR_INCLUDES lzma)
  55
  56 # zlib
  57 if (WITH_SYSTEM_ZLIB)
  58   pkg_check_modules(ZLIB REQUIRED zlib)
  59   list(APPEND PLATFORM_INCLUDES ${ZLIB_INCLUDE_DIRS})
  60   list(APPEND PLATFORM_LIBS ${ZLIB_LIBRARIES})
  61 else()
  62   add_subdirectory(deps/zlib-1.2.11 EXCLUDE_FROM_ALL)
  63   list(APPEND CHDR_LIBS zlib)
  64   list(APPEND CHDR_INCLUDES zlib)
  65 endif()
  66
  67 #--------------------------------------------------
  68 # chdr
  69 #--------------------------------------------------
  70
  71 set(CHDR_SOURCES
  72   src/libchdr_bitstream.c
  73   src/libchdr_cdrom.c
  74   src/libchdr_chd.c
  75   src/libchdr_flac.c
  76   src/libchdr_huffman.c
  77 )
  78
  79 list(APPEND CHDR_INCLUDES ${CMAKE_CURRENT_BINARY_DIR}/include)
  80
  81 add_library(chdr-static STATIC ${CHDR_SOURCES})
  82 target_include_directories(chdr-static PRIVATE ${CHDR_INCLUDES} ${PLATFORM_INCLUDES} PUBLIC include)
  83 target_compile_definitions(chdr-static PRIVATE ${CHDR_DEFS})
  84 target_link_libraries(chdr-static PRIVATE ${CHDR_LIBS} ${PLATFORM_LIBS})
  85
  86 if (INSTALL_STATIC_LIBS)
  87   install(TARGETS chdr-static ${CHDR_LIBS}
  88     ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
  89   )
  90 endif()
  91
  92 if (BUILD_SHARED_LIBS)
  93   set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  94   set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  95
  96   add_library(chdr SHARED ${CHDR_SOURCES})
  97   target_include_directories(chdr PRIVATE ${CHDR_INCLUDES} ${PLATFORM_INCLUDES} PUBLIC include)
  98   target_compile_definitions(chdr PRIVATE ${CHDR_DEFS})
  99   target_link_libraries(chdr PRIVATE ${CHDR_LIBS} ${PLATFORM_LIBS})
 100
 101   if(MSVC)
 102     target_compile_definitions(chdr PUBLIC "CHD_DLL")
 103     target_compile_definitions(chdr PRIVATE "CHD_DLL_EXPORTS")
 104   elseif(APPLE)
 105     target_link_options(chdr PRIVATE -Wl,-dead_strip -Wl,-exported_symbol,_chd_*)
 106   else()
 107     target_link_options(chdr PRIVATE -Wl,--version-script ${CMAKE_CURRENT_SOURCE_DIR}/src/link.T -Wl,--no-undefined)
 108   endif()
 109
 110   set_target_properties(chdr PROPERTIES PUBLIC_HEADER "include/libchdr/bitstream.h;include/libchdr/cdrom.h;include/libchdr/chd.h;include/libchdr/chdconfig.h;include/libchdr/coretypes.h;include/libchdr/flac.h;include/libchdr/huffman.h")
 111   set_target_properties(chdr PROPERTIES VERSION "${CHDR_VERSION_MAJOR}.${CHDR_VERSION_MINOR}")
 112
 113   if (CMAKE_BUILD_TYPE MATCHES Release)
 114     #add_custom_command(TARGET chdr POST_BUILD COMMAND ${CMAKE_STRIP} libchdr.so)
 115   endif (CMAKE_BUILD_TYPE MATCHES Release)
 116
 117   install(TARGETS chdr
 118     LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
 119     ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
 120     PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/libchdr"
 121   )
 122
 123   configure_file(pkg-config.pc.in ${CMAKE_BINARY_DIR}/libchdr.pc @ONLY)
 124   install(FILES ${CMAKE_BINARY_DIR}/libchdr.pc DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
 125 endif()
 126