+VBL:
+ addq.l #1,(vtimer).l
+ movem.l d0-d6/a0-a5,-(a7)
+
+ /* draw main stuff */
+ clr.l d1
+ move.l a6,d0
+ move.b d0,d1
+ lsr.l #8,d0
+ move.l d0,a1 /* current addr */
+ lsr.b #3,d1
+ neg.b d1
+ add.b #27-1,d1 /* line where the cursor sits */
+ swap d1
+
+ movea.l #0xe004,a2
+ move.l #27-1,d5 /* line counter for dbra */
+ or.l d1,d5
+
+draw_column:
+ move.l a2,a0
+ jsr load_prepare
+
+ /* addr */
+ move.l a1,d2
+ moveq.l #6,d3
+ jsr print_hex_preped
+
+ /* 4 shorts */
+ moveq.l #4,d3
+ moveq.l #4-1,d4
+draw_shorts:
+ move.w #' ',(a0)
+ move.w (a1)+,d2
+ jsr print_hex_preped
+ dbra d4,draw_shorts
+
+ move.l d5,d0
+ swap d0
+ cmp.w d5,d0
+ beq draw_cursor
+
+draw_chars_pre:
+ move.l #(' '<<16)|' ',(a0)
+
+ /* 8 chars */
+ subq.l #8,a1
+ moveq.l #8-1,d4
+draw_chars:
+ move.b (a1)+,d0
+ move.b d0,d1
+ sub.b #0x20,d1
+ cmp.b #0x60,d1
+ blo 0f
+ move.w #'.',d0
+0:
+ move.w d0,(a0)
+ dbra d4,draw_chars
+
+ add.w #0x80,a2
+ dbra d5,draw_column
+
+ /* status bar */
+ movea.l #0xe004+64*2*27,a0
+ jsr load_prepare
+ move.l a6,d2
+ moveq.l #0,d3
+ move.b d2,d3
+ lsr.l #8,d2
+ add.l d3,d2
+ move.l #0x4006,d3
+ jsr print_hex_preped
+
+ /* handle input */
+ jsr get_input /* x0cbrldu x1sa00du */
+
+ do_dpad 0, sub, subq, 0x0008, 0x0800
+ do_dpad 1, add, addq, 0x0008, 0x0800
+ do_dpad 10, sub, subq, 0x0001, 0xd800
+ do_dpad 11, add, addq, 0x0001, 0xd800
+input_end:
+
+ /* update addr */
+ move.l a6,d0
+ cmp.b #0xf0,d0
+ blo 0f
+ sub.l #0xd800,a6
+ add.w #0x00d8,a6
+ bra 1f
+0:
+ cmp.b #0xe0,d0
+ blo 1f
+ add.l #0xd800,a6
+ sub.w #0x00d8,a6
+1:
+
+end:
+ movem.l (a7)+,d0-d6/a0-a5
+ rte
+
+
+draw_cursor:
+ move.l a6,d0
+ and.l #7,d0 /* byte offs */
+ move.l d0,d1
+ lsr.b #1,d1 /* which word */
+ move.b d1,d2
+ lsl.b #2,d2
+ add.b d2,d1 /* num of chars to skip */
+ lsl.b #1,d1
+
+ /* FIXME */
+ move.w (-8,a1,d0),d2
+
+ lea (7*2,a2,d1),a0
+ jsr load_prepare
+
+ move.w #0x2004,d3
+ jsr print_hex_preped
+
+ move.l a2,a0
+ add.w #26*2,a0
+ jsr load_prepare /* restore a0 */
+
+ jmp draw_chars_pre
+
+