--- /dev/null
+.align 2\r
+\r
+.global expand_blend\r
+.global expand_normal\r
+\r
+@ Input:\r
+@ r0 = screen_src_ptr\r
+@ r1 = screen_dest_ptr\r
+@ r2 = start\r
+@ r3 = end\r
+\r
+6:\r
+ .word io_registers\r
+ .word palette_ram_converted\r
+ .word 0x04000200 @ combine test mask\r
+ .word 0x07E0F81F @ clamp mask\r
+ .word 0x000003FE @ palette index mask\r
+ .word 0x08010020 @ saturation mask\r
+\r
+expand_blend:\r
+ stmdb sp!, { r4, r5, r6, r9, r10, r11, r14 }\r
+\r
+ add r0, r0, r2, lsl #2 @ screen_src_ptr += start\r
+ add r1, r1, r2, lsl #1 @ screen_dest_ptr += start\r
+ sub r2, r3, r2 @ r2 = end - start\r
+ ldr r3, 6b @ r3 = io_registers\r
+ ldr r3, [r3, #0x52] @ r3 = bldalpha\r
+ mov r4, r3, lsr #8 @ r4 = bldalpha >> 8\r
+ and r3, r3, #0x1F @ r3 = blend_a\r
+ and r4, r4, #0x1F @ r4 = blend_b\r
+ cmp r3, #16 @ if(blend_a > 16)\r
+ movgt r3, #16 @ blend_a = 16\r
+ cmp r4, #16 @ if(blend_b > 16)\r
+ movgt r3, #16 @ blend_b = 16\r
+\r
+ ldr r14, 6b + 4 @ r14 = palette_ram_converted\r
+ ldr r12, 6b + 8 @ r12 = 0x04000200\r
+ ldr r11, 6b + 12 @ r11 = 0x07E0F81F\r
+ ldr r10, 6b + 16 @ r10 = 0x000003FE\r
+\r
+ add r5, r3, r4 @ r5 = blend_a + blend_b\r
+ cmp r5, #16 @ if((blend_a + blend_b) > 16)\r
+ bgt 3f @ goto loop w/saturation\r
+\r
+\r
+ @ loop w/o saturation\r
+1:\r
+ ldr r5, [r0], #4 @ r5 = pixel_pair, screen_src_ptr++\r
+ and r6, r5, r12 @ r6 = r5 & 0x04000200\r
+ cmp r6, r12 @ if(r6 != 0x4000200)\r
+ bne 2f @ goto no_blend\r
+\r
+ and r6, r10, r5, lsl #1 @ r6 = (pixel_pair & 0x1FF) << 1\r
+ ldrh r6, [r14, r6] @ r6 = pixel_top\r
+ orr r6, r6, r6, lsl #16 @ r6 = pixel_top | (pixel_top << 16)\r
+ and r6, r6, r11 @ r6 = pixel_top_dilated\r
+\r
+ and r5, r10, r5, lsr #15 @ r5 = ((pixel_pair >> 16) & 0x1FF) << 1\r
+ ldrh r5, [r14, r5] @ r5 = pixel_bottom\r
+ orr r5, r5, r5, lsl #16 @ r5 = pixel_bottom | (pixel_bottom << 16)\r
+ and r5, r5, r11 @ r5 = pixel_bottom_dilated\r
+\r
+ mul r5, r4, r5 @ r5 = pixel_bottom * blend_b = bottom_mul\r
+ mla r5, r3, r6, r5 @ r5 = (pixel_top * blend_a) + bottom_mul\r
+\r
+ and r5, r11, r5, lsr #4 @ r5 = (color_dilated >> 4) & 0x07E0F81F\r
+ orr r5, r5, r5, lsr #16 @ r5 = color_dilated | (color_dilated >> 16)\r
+\r
+ strh r5, [r1], #2 @ *screen_dest_ptr = r5, screen_dest_ptr++\r
+ subs r2, r2, #1 @ counter--\r
+ bne 1b @ go again\r
+\r
+ ldmia sp!, { r4, r5, r6, r9, r10, r11, pc }\r
+\r
+2:\r
+ and r5, r10, r5, lsl #1 @ r5 = (pixel_pair & 0x1FF) << 1\r
+ ldrh r5, [r14, r5] @ r5 = pixel_top\r
+ strh r5, [r1], #2 @ *screen_dest_ptr = r5, screen_dest_ptr++\r
+\r
+ subs r2, r2, #1 @ counter--\r
+ bne 1b @ go again\r
+\r
+ ldmia sp!, { r4, r5, r6, r9, r10, r11, pc }\r
+\r
+@ loop w/saturation\r
+\r
+3:\r
+ ldr r9, 6b + 20 @ r9 = 0x08010020\r
+\r
+4:\r
+ ldr r5, [r0], #4 @ r5 = pixel_pair, screen_src_ptr++\r
+ and r6, r5, r12 @ r6 = r5 & 0x04000200\r
+ cmp r6, r12 @ if(r6 != 0x4000200)\r
+ bne 5f @ goto no_blend\r
+\r
+ and r6, r10, r5, lsl #1 @ r6 = (pixel_pair & 0x1FF) << 1\r
+ ldrh r6, [r14, r6] @ r6 = pixel_top\r
+ orr r6, r6, r6, lsl #16 @ r6 = pixel_top | (pixel_top << 16)\r
+ and r6, r6, r11 @ r6 = pixel_top_dilated\r
+\r
+ and r5, r10, r5, lsr #15 @ r5 = ((pixel_pair >> 16) & 0x1FF) << 1\r
+ ldrh r5, [r14, r5] @ r5 = pixel_bottom\r
+ orr r5, r5, r5, lsl #16 @ r5 = pixel_bottom | (pixel_bottom << 16)\r
+ and r5, r5, r11 @ r5 = pixel_bottom_dilated\r
+\r
+ mul r5, r4, r5 @ r5 = pixel_bottom * blend_b = bottom_mul\r
+ mla r5, r3, r6, r5 @ r5 = (pixel_top * blend_a) + bottom_mul\r
+\r
+ and r6, r9, r5, lsr #4 @ r6 = saturation bits\r
+ orr r6, r6, r6, lsr #1 @ propogate saturation down msb\r
+ orr r6, r6, r6, lsr #2 @ propogate down next two bits\r
+ orr r6, r6, r6, lsr #3 @ propogate down next three bits\r
+ orr r5, r6, r5, lsr #4 @ mask over result w/saturation\r
+\r
+ and r5, r11, r5 @ r5 = (color_dilated >> 4) & 0x07E0F81F\r
+ orr r5, r5, r5, lsr #16 @ r5 = color_dilated | (color_dilated >> 16)\r
+ strh r5, [r1], #2 @ *screen_dest_ptr = r5, screen_dest_ptr++\r
+\r
+ subs r2, r2, #1 @ counter--\r
+ bne 4b @ go again\r
+\r
+ ldmia sp!, { r4, r5, r6, r9, r10, r11, pc }\r
+\r
+5:\r
+ and r5, r10, r5, lsl #1 @ r5 = (pixel_pair & 0x1FF) << 1\r
+ ldrh r5, [r14, r5] @ r5 = pixel_top\r
+ strh r5, [r1], #2 @ *screen_dest_ptr = r5, screen_dest_ptr++\r
+\r
+ subs r2, r2, #1 @ counter--\r
+ bne 4b @ go again\r
+\r
+ ldmia sp!, { r4, r5, r6, r9, r10, r11, pc }\r
+\r
+\r
+\r
+@ The following function isn't complete (only works on run multiples of 8),\r
+@ but unfortunately I don't see much potential for actually being able to\r
+@ use it..\r
+\r
+#define expand_pixel_pair(reg, temp) ;\\r
+ and temp, r3, reg, lsr #15 ;\\r
+ ldrh temp, [r2, temp] ;\\r
+ ;\\r
+ and reg, r3, reg, lsl #1 ;\\r
+ ldrh reg, [r2, reg] ;\\r
+ ;\\r
+ orr reg, reg, temp, lsl #16 ;\\r
+\r
+\r
+@ Input:\r
+@ r0 = screen_ptr\r
+@ r1 = start\r
+@ r2 = end\r
+\r
+1:\r
+ .word palette_ram_converted\r
+ .word 0x3FE\r
+\r
+expand_normal:\r
+ stmdb sp!, { r4, r5, r6, r7, r14 }\r
+\r
+ add r0, r0, r1, lsl #1 @ screen_ptr += start\r
+ sub r1, r2, r1 @ r1 = end - start\r
+ ldr r2, 1b @ r2 = palette_ram_converted\r
+ ldr r3, 1b + 4 @ r3 = 0x3FE\r
+\r
+2:\r
+ ldmia r0, { r4, r5, r6, r7 }\r
+\r
+ expand_pixel_pair(r4, r14)\r
+ expand_pixel_pair(r5, r14)\r
+ expand_pixel_pair(r6, r14)\r
+ expand_pixel_pair(r7, r14)\r
+\r
+ stmia r0!, { r4, r5, r6, r7 }\r
+\r
+ subs r1, r1, #8\r
+ bne 2b\r
+\r
+ ldmia sp!, { r4, r5, r6, r7, pc }\r
+\r
notaz.gp2x.de / gpsp.git / blobdiff