libpcsxcore/new_dynarec/linkage_arm64.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2021 notaz                                              *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "assem_arm64.h"
  25 #include "linkage_offsets.h"
  26
  27 #if (LO_mem_wtab & 7)
  28 #error misligned pointers
  29 #endif
  30
  31 .bss
  32         .align  4
  33         .global dynarec_local
  34         .type   dynarec_local, %object
  35         .size   dynarec_local, LO_dynarec_local_size
  36 dynarec_local:
  37         .space  LO_dynarec_local_size
  38
  39 #define DRC_VAR_(name, vname, size_) \
  40         vname = dynarec_local + LO_##name; \
  41         .global vname; \
  42         .type   vname, %object; \
  43         .size   vname, size_
  44
  45 #define DRC_VAR(name, size_) \
  46         DRC_VAR_(name, ESYM(name), size_)
  47
  48 DRC_VAR(next_interupt, 4)
  49 DRC_VAR(cycle_count, 4)
  50 DRC_VAR(last_count, 4)
  51 DRC_VAR(pending_exception, 4)
  52 DRC_VAR(stop, 4)
  53 DRC_VAR(branch_target, 4)
  54 DRC_VAR(address, 4)
  55 DRC_VAR(hack_addr, 4)
  56 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  57
  58 /* psxRegs */
  59 #DRC_VAR(reg, 128)
  60 DRC_VAR(lo, 4)
  61 DRC_VAR(hi, 4)
  62 DRC_VAR(reg_cop0, 128)
  63 DRC_VAR(reg_cop2d, 128)
  64 DRC_VAR(reg_cop2c, 128)
  65 DRC_VAR(pcaddr, 4)
  66 #DRC_VAR(code, 4)
  67 #DRC_VAR(cycle, 4)
  68 #DRC_VAR(interrupt, 4)
  69 #DRC_VAR(intCycle, 256)
  70
  71 DRC_VAR(rcnts, 7*4*4)
  72 DRC_VAR(inv_code_start, 4)
  73 DRC_VAR(inv_code_end, 4)
  74 DRC_VAR(mem_rtab, 8)
  75 DRC_VAR(mem_wtab, 8)
  76 DRC_VAR(psxH_ptr, 8)
  77 DRC_VAR(invc_ptr, 8)
  78 DRC_VAR(zeromem_ptr, 8)
  79 DRC_VAR(scratch_buf_ptr, 8)
  80 DRC_VAR(ram_offset, 8)
  81 DRC_VAR(mini_ht, 256)
  82
  83
  84         .text
  85         .align  2
  86
  87 FUNCTION(dyna_linker):
  88         /* r0 = virtual target address */
  89         /* r1 = instruction to patch */
  90         bl      ndrc_get_addr_ht
  91         br      x0
  92         .size   dyna_linker, .-dyna_linker
  93
  94         .align  2
  95 FUNCTION(cc_interrupt):
  96         ldr     w0, [rFP, #LO_last_count]
  97         add     rCC, w0, rCC
  98         str     wzr, [rFP, #LO_pending_exception]
  99         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 100 #       str     rCC, [rFP, #LO_reg_cop0+36]     /* Count */
 101         mov     x21, lr
 102 1:
 103         add     x0, rFP, #(LO_psxRegs + 34*4)   /* CP0 */
 104         bl      gen_interupt
 105         mov     lr, x21
 106         ldr     rCC, [rFP, #LO_cycle]
 107         ldr     w0, [rFP, #LO_next_interupt]
 108         ldr     w1, [rFP, #LO_pending_exception]
 109         ldr     w2, [rFP, #LO_stop]
 110         str     w0, [rFP, #LO_last_count]
 111         sub     rCC, rCC, w0
 112         cbnz    w2, new_dyna_leave
 113         cbnz    w1, 2f
 114         ret
 115 2:
 116         ldr     w0, [rFP, #LO_pcaddr]
 117         bl      ndrc_get_addr_ht
 118         br      x0
 119         .size   cc_interrupt, .-cc_interrupt
 120
 121         .align  2
 122 FUNCTION(jump_overflow_ds):
 123         mov     w0, #(12<<2)  /* R3000E_Ov */
 124         mov     w1, #1
 125         b       call_psxException
 126 FUNCTION(jump_overflow):
 127         mov     w0, #(12<<2)
 128         mov     w1, #0
 129         b       call_psxException
 130 FUNCTION(jump_break_ds):
 131         mov     w0, #(9<<2)  /* R3000E_Bp */
 132         mov     w1, #1
 133         b       call_psxException
 134 FUNCTION(jump_break):
 135         mov     w0, #(9<<2)
 136         mov     w1, #0
 137         b       call_psxException
 138 FUNCTION(jump_syscall_ds):
 139         mov     w0, #(8<<2)  /* R3000E_Syscall */
 140         mov     w1, #2
 141         b       call_psxException
 142 FUNCTION(jump_syscall):
 143         mov     w0, #(8<<2)
 144         mov     w1, #0
 145
 146 call_psxException:
 147         ldr     w3, [rFP, #LO_last_count]
 148         str     w2, [rFP, #LO_pcaddr]
 149         add     rCC, w3, rCC
 150         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 151         add     x2, rFP, #(LO_psxRegs + 34*4)   /* CP0 */
 152         bl      psxException
 153
 154         /* note: psxException might do recursive recompiler call from it's HLE code,
 155          * so be ready for this */
 156 FUNCTION(jump_to_new_pc):
 157         ldr     w1, [rFP, #LO_next_interupt]
 158         ldr     rCC, [rFP, #LO_cycle]
 159         ldr     w0, [rFP, #LO_pcaddr]
 160         sub     rCC, rCC, w1
 161         str     w1, [rFP, #LO_last_count]
 162         bl      ndrc_get_addr_ht
 163         br      x0
 164         .size   jump_to_new_pc, .-jump_to_new_pc
 165
 166         /* stack must be aligned by 16, and include space for save_regs() use */
 167         .align  2
 168 FUNCTION(new_dyna_start):
 169         stp     x29, x30, [sp, #-SSP_ALL]!
 170         ldr     w1,  [x0, #LO_next_interupt]
 171         ldr     w2,  [x0, #LO_cycle]
 172         stp     x19, x20, [sp, #16*1]
 173         stp     x21, x22, [sp, #16*2]
 174         stp     x23, x24, [sp, #16*3]
 175         stp     x25, x26, [sp, #16*4]
 176         stp     x27, x28, [sp, #16*5]
 177         mov     rFP, x0
 178         ldr     w0,  [rFP, #LO_pcaddr]
 179         str     w1,  [rFP, #LO_last_count]
 180         sub     rCC, w2, w1
 181         bl      ndrc_get_addr_ht
 182         br      x0
 183         .size   new_dyna_start, .-new_dyna_start
 184
 185         .align  2
 186 FUNCTION(new_dyna_leave):
 187         ldr     w0,  [rFP, #LO_last_count]
 188         add     rCC, rCC, w0
 189         str     rCC, [rFP, #LO_cycle]
 190         ldp     x19, x20, [sp, #16*1]
 191         ldp     x21, x22, [sp, #16*2]
 192         ldp     x23, x24, [sp, #16*3]
 193         ldp     x25, x26, [sp, #16*4]
 194         ldp     x27, x28, [sp, #16*5]
 195         ldp     x29, x30, [sp], #SSP_ALL
 196         ret
 197         .size   new_dyna_leave, .-new_dyna_leave
 198
 199 /* --------------------------------------- */
 200
 201 .align  2
 202
 203 .macro memhandler_pre
 204         /* w0 = adddr/data, x1 = rhandler, w2 = cycles, x3 = whandler */
 205         ldr     w4, [rFP, #LO_last_count]
 206         add     w4, w4, w2
 207         str     w4, [rFP, #LO_cycle]
 208 .endm
 209
 210 .macro memhandler_post
 211         ldr     w0, [rFP, #LO_next_interupt]
 212         ldr     w2, [rFP, #LO_cycle]        // memhandlers can modify cc, like dma
 213         str     w0, [rFP, #LO_last_count]
 214         sub     w0, w2, w0
 215 .endm
 216
 217 FUNCTION(do_memhandler_pre):
 218         memhandler_pre
 219         ret
 220
 221 FUNCTION(do_memhandler_post):
 222         memhandler_post
 223         ret
 224
 225 .macro pcsx_read_mem readop tab_shift
 226         /* w0 = address, x1 = handler_tab, w2 = cycles */
 227         ubfm    w4, w0, #\tab_shift, #11
 228         ldr     x3, [x1, w4, uxtw #3]
 229         adds    x3, x3, x3
 230         bcs     0f
 231         \readop w0, [x3, w4, uxtw #\tab_shift]
 232         ret
 233 0:
 234         stp     xzr, x30, [sp, #-16]!
 235         memhandler_pre
 236         blr     x3
 237 .endm
 238
 239 FUNCTION(jump_handler_read8):
 240         add     x1, x1, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 241         pcsx_read_mem ldrb, 0
 242         b       handler_read_end
 243
 244 FUNCTION(jump_handler_read16):
 245         add     x1, x1, #0x1000/4*8               /* shift to r16 part */
 246         pcsx_read_mem ldrh, 1
 247         b       handler_read_end
 248
 249 FUNCTION(jump_handler_read32):
 250         pcsx_read_mem ldr, 2
 251
 252 handler_read_end:
 253         ldp     xzr, x30, [sp], #16
 254         ret
 255
 256 .macro pcsx_write_mem wrtop movop tab_shift
 257         /* w0 = address, w1 = data, w2 = cycles, x3 = handler_tab */
 258         ubfm    w4, w0, #\tab_shift, #11
 259         ldr     x3, [x3, w4, uxtw #3]
 260         adds    x3, x3, x3
 261         bcs     0f
 262         mov     w0, w2                    /* cycle return */
 263         \wrtop  w1, [x3, w4, uxtw #\tab_shift]
 264         ret
 265 0:
 266         stp     xzr, x30, [sp, #-16]!
 267         str     w0, [rFP, #LO_address]    /* some handlers still need it... */
 268         \movop  w0, w1
 269         memhandler_pre
 270         blr     x3
 271 .endm
 272
 273 FUNCTION(jump_handler_write8):
 274         add     x3, x3, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 275         pcsx_write_mem strb uxtb 0
 276         b       handler_write_end
 277
 278 FUNCTION(jump_handler_write16):
 279         add     x3, x3, #0x1000/4*8               /* shift to r16 part */
 280         pcsx_write_mem strh uxth 1
 281         b       handler_write_end
 282
 283 FUNCTION(jump_handler_write32):
 284         pcsx_write_mem str mov 2
 285
 286 handler_write_end:
 287         memhandler_post
 288         ldp     xzr, x30, [sp], #16
 289         ret
 290
 291 FUNCTION(jump_handle_swl):
 292         /* w0 = address, w1 = data, w2 = cycles */
 293         ldr     x3, [rFP, #LO_mem_wtab]
 294         orr     w4, wzr, w0, lsr #12
 295         ldr     x3, [x3, w4, uxtw #3]
 296         adds    x3, x3, x3
 297         bcs     4f
 298         add     x3, x0, x3
 299         mov     w0, w2
 300         tbz     x3, #1, 10f     // & 2
 301         tbz     x3, #0, 2f      // & 1
 302 3:
 303         stur    w1, [x3, #-3]
 304         ret
 305 2:
 306         lsr     w2, w1, #8
 307         lsr     w1, w1, #24
 308         sturh   w2, [x3, #-2]
 309         strb    w1, [x3]
 310         ret
 311 10:
 312         tbz     x3, #0, 0f      // & 1
 313 1:
 314         lsr     w1, w1, #16
 315         sturh   w1, [x3, #-1]
 316         ret
 317 0:
 318         lsr     w2, w1, #24
 319         strb    w2, [x3]
 320         ret
 321 4:
 322         mov     w0, w2          // todo
 323         bl      abort
 324         ret
 325
 326 FUNCTION(jump_handle_swr):
 327         /* w0 = address, w1 = data, w2 = cycles */
 328         ldr     x3, [rFP, #LO_mem_wtab]
 329         orr     w4, wzr, w0, lsr #12
 330         ldr     x3, [x3, w4, uxtw #3]
 331         adds    x3, x3, x3
 332         bcs     4f
 333         add     x3, x0, x3
 334         mov     w0, w2
 335         tbz     x3, #1, 10f     // & 2
 336         tbz     x3, #0, 2f      // & 1
 337 3:
 338         strb    w1, [x3]
 339         ret
 340 2:
 341         strh    w1, [x3]
 342         ret
 343 10:
 344         tbz     x3, #0, 0f      // & 1
 345 1:
 346         lsr     w2, w1, #8
 347         strb    w1, [x3]
 348         sturh   w2, [x3, #1]
 349         ret
 350 0:
 351         str     w1, [x3]
 352         ret
 353 4:
 354         mov     w0, w2          // todo
 355         bl      abort
 356         ret
 357
 358 FUNCTION(call_gteStall):
 359         /* w0 = op_cycles, w1 = cycles */
 360         ldr     w2, [rFP, #LO_last_count]
 361         str     lr, [rFP, #LO_saved_lr]
 362         add     w1, w1, w2
 363         str     w1, [rFP, #LO_cycle]
 364         add     x1, rFP, #LO_psxRegs
 365         bl      gteCheckStallRaw
 366         ldr     lr, [rFP, #LO_saved_lr]
 367         add     rCC, rCC, w0
 368         ret
 369