libpcsxcore/new_dynarec/linkage_arm64.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2021 notaz                                              *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "assem_arm64.h"
  25 #include "linkage_offsets.h"
  26
  27 #if (LO_mem_wtab & 7)
  28 #error misligned pointers
  29 #endif
  30
  31 .bss
  32         .align  4
  33         .global dynarec_local
  34         .type   dynarec_local, %object
  35         .size   dynarec_local, LO_dynarec_local_size
  36 dynarec_local:
  37         .space  LO_dynarec_local_size
  38
  39 #define DRC_VAR_(name, vname, size_) \
  40         vname = dynarec_local + LO_##name; \
  41         .global vname; \
  42         .type   vname, %object; \
  43         .size   vname, size_
  44
  45 #define DRC_VAR(name, size_) \
  46         DRC_VAR_(name, ESYM(name), size_)
  47
  48 DRC_VAR(next_interupt, 4)
  49 DRC_VAR(cycle_count, 4)
  50 DRC_VAR(last_count, 4)
  51 DRC_VAR(pending_exception, 4)
  52 DRC_VAR(stop, 4)
  53 DRC_VAR(branch_target, 4)
  54 DRC_VAR(address, 4)
  55 DRC_VAR(hack_addr, 4)
  56 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  57
  58 /* psxRegs */
  59 #DRC_VAR(reg, 128)
  60 DRC_VAR(lo, 4)
  61 DRC_VAR(hi, 4)
  62 DRC_VAR(reg_cop0, 128)
  63 DRC_VAR(reg_cop2d, 128)
  64 DRC_VAR(reg_cop2c, 128)
  65 DRC_VAR(pcaddr, 4)
  66 #DRC_VAR(code, 4)
  67 #DRC_VAR(cycle, 4)
  68 #DRC_VAR(interrupt, 4)
  69 #DRC_VAR(intCycle, 256)
  70
  71 DRC_VAR(rcnts, 7*4*4)
  72 DRC_VAR(inv_code_start, 4)
  73 DRC_VAR(inv_code_end, 4)
  74 DRC_VAR(mem_rtab, 8)
  75 DRC_VAR(mem_wtab, 8)
  76 DRC_VAR(psxH_ptr, 8)
  77 DRC_VAR(invc_ptr, 8)
  78 DRC_VAR(zeromem_ptr, 8)
  79 DRC_VAR(scratch_buf_ptr, 8)
  80 DRC_VAR(ram_offset, 8)
  81 DRC_VAR(mini_ht, 256)
  82
  83
  84         .text
  85         .align  2
  86
  87 FUNCTION(dyna_linker):
  88         /* r0 = virtual target address */
  89         /* r1 = instruction to patch */
  90         bl      ndrc_get_addr_ht
  91         br      x0
  92         .size   dyna_linker, .-dyna_linker
  93
  94         .align  2
  95 FUNCTION(cc_interrupt):
  96         ldr     w0, [rFP, #LO_last_count]
  97         add     rCC, w0, rCC
  98         str     wzr, [rFP, #LO_pending_exception]
  99         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 100 #       str     rCC, [rFP, #LO_reg_cop0+36]     /* Count */
 101         mov     x21, lr
 102 1:
 103         add     x0, rFP, #(LO_psxRegs + 34*4)   /* CP0 */
 104         bl      gen_interupt
 105         mov     lr, x21
 106         ldr     rCC, [rFP, #LO_cycle]
 107         ldr     w0, [rFP, #LO_next_interupt]
 108         ldr     w1, [rFP, #LO_pending_exception]
 109         ldr     w2, [rFP, #LO_stop]
 110         str     w0, [rFP, #LO_last_count]
 111         sub     rCC, rCC, w0
 112         cbnz    w2, new_dyna_leave
 113         cbnz    w1, 2f
 114         ret
 115 2:
 116         ldr     w0, [rFP, #LO_pcaddr]
 117         bl      ndrc_get_addr_ht
 118         br      x0
 119         .size   cc_interrupt, .-cc_interrupt
 120
 121         .align  2
 122 FUNCTION(jump_addrerror_ds): /* R3000E_AdEL / R3000E_AdES in w0 */
 123         str     w1, [rFP, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
 124         mov     w1, #1
 125         b       call_psxException
 126 FUNCTION(jump_addrerror):
 127         str     w1, [rFP, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
 128         mov     w1, #0
 129         b       call_psxException
 130 FUNCTION(jump_overflow_ds):
 131         mov     w0, #(12<<2)  /* R3000E_Ov */
 132         mov     w1, #1
 133         b       call_psxException
 134 FUNCTION(jump_overflow):
 135         mov     w0, #(12<<2)
 136         mov     w1, #0
 137         b       call_psxException
 138 FUNCTION(jump_break_ds):
 139         mov     w0, #(9<<2)  /* R3000E_Bp */
 140         mov     w1, #1
 141         b       call_psxException
 142 FUNCTION(jump_break):
 143         mov     w0, #(9<<2)
 144         mov     w1, #0
 145         b       call_psxException
 146 FUNCTION(jump_syscall_ds):
 147         mov     w0, #(8<<2)  /* R3000E_Syscall */
 148         mov     w1, #2
 149         b       call_psxException
 150 FUNCTION(jump_syscall):
 151         mov     w0, #(8<<2)
 152         mov     w1, #0
 153
 154 call_psxException:
 155         ldr     w3, [rFP, #LO_last_count]
 156         str     w2, [rFP, #LO_pcaddr]
 157         add     rCC, w3, rCC
 158         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 159         add     x2, rFP, #(LO_psxRegs + 34*4)   /* CP0 */
 160         bl      psxException
 161
 162         /* note: psxException might do recursive recompiler call from it's HLE code,
 163          * so be ready for this */
 164 FUNCTION(jump_to_new_pc):
 165         ldr     w1, [rFP, #LO_next_interupt]
 166         ldr     rCC, [rFP, #LO_cycle]
 167         ldr     w0, [rFP, #LO_pcaddr]
 168         sub     rCC, rCC, w1
 169         str     w1, [rFP, #LO_last_count]
 170         bl      ndrc_get_addr_ht
 171         br      x0
 172         .size   jump_to_new_pc, .-jump_to_new_pc
 173
 174         /* stack must be aligned by 16, and include space for save_regs() use */
 175         .align  2
 176 FUNCTION(new_dyna_start):
 177         stp     x29, x30, [sp, #-SSP_ALL]!
 178         ldr     w1,  [x0, #LO_next_interupt]
 179         ldr     w2,  [x0, #LO_cycle]
 180         stp     x19, x20, [sp, #16*1]
 181         stp     x21, x22, [sp, #16*2]
 182         stp     x23, x24, [sp, #16*3]
 183         stp     x25, x26, [sp, #16*4]
 184         stp     x27, x28, [sp, #16*5]
 185         mov     rFP, x0
 186         ldr     w0,  [rFP, #LO_pcaddr]
 187         str     w1,  [rFP, #LO_last_count]
 188         sub     rCC, w2, w1
 189         bl      ndrc_get_addr_ht
 190         br      x0
 191         .size   new_dyna_start, .-new_dyna_start
 192
 193         .align  2
 194 FUNCTION(new_dyna_leave):
 195         ldr     w0,  [rFP, #LO_last_count]
 196         add     rCC, rCC, w0
 197         str     rCC, [rFP, #LO_cycle]
 198         ldp     x19, x20, [sp, #16*1]
 199         ldp     x21, x22, [sp, #16*2]
 200         ldp     x23, x24, [sp, #16*3]
 201         ldp     x25, x26, [sp, #16*4]
 202         ldp     x27, x28, [sp, #16*5]
 203         ldp     x29, x30, [sp], #SSP_ALL
 204         ret
 205         .size   new_dyna_leave, .-new_dyna_leave
 206
 207 /* --------------------------------------- */
 208
 209 .align  2
 210
 211 .macro memhandler_pre
 212         /* w0 = adddr/data, x1 = rhandler, w2 = cycles, x3 = whandler */
 213         ldr     w4, [rFP, #LO_last_count]
 214         add     w4, w4, w2
 215         str     w4, [rFP, #LO_cycle]
 216 .endm
 217
 218 .macro memhandler_post
 219         ldr     w0, [rFP, #LO_next_interupt]
 220         ldr     w2, [rFP, #LO_cycle]        // memhandlers can modify cc, like dma
 221         str     w0, [rFP, #LO_last_count]
 222         sub     w0, w2, w0
 223 .endm
 224
 225 FUNCTION(do_memhandler_pre):
 226         memhandler_pre
 227         ret
 228
 229 FUNCTION(do_memhandler_post):
 230         memhandler_post
 231         ret
 232
 233 .macro pcsx_read_mem readop tab_shift
 234         /* w0 = address, x1 = handler_tab, w2 = cycles */
 235         ubfm    w4, w0, #\tab_shift, #11
 236         ldr     x3, [x1, w4, uxtw #3]
 237         adds    x3, x3, x3
 238         bcs     0f
 239         \readop w0, [x3, w4, uxtw #\tab_shift]
 240         ret
 241 0:
 242         stp     xzr, x30, [sp, #-16]!
 243         memhandler_pre
 244         blr     x3
 245 .endm
 246
 247 FUNCTION(jump_handler_read8):
 248         add     x1, x1, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 249         pcsx_read_mem ldrb, 0
 250         b       handler_read_end
 251
 252 FUNCTION(jump_handler_read16):
 253         add     x1, x1, #0x1000/4*8               /* shift to r16 part */
 254         pcsx_read_mem ldrh, 1
 255         b       handler_read_end
 256
 257 FUNCTION(jump_handler_read32):
 258         pcsx_read_mem ldr, 2
 259
 260 handler_read_end:
 261         ldp     xzr, x30, [sp], #16
 262         ret
 263
 264 .macro pcsx_write_mem wrtop movop tab_shift
 265         /* w0 = address, w1 = data, w2 = cycles, x3 = handler_tab */
 266         ubfm    w4, w0, #\tab_shift, #11
 267         ldr     x3, [x3, w4, uxtw #3]
 268         adds    x3, x3, x3
 269         bcs     0f
 270         mov     w0, w2                    /* cycle return */
 271         \wrtop  w1, [x3, w4, uxtw #\tab_shift]
 272         ret
 273 0:
 274         stp     xzr, x30, [sp, #-16]!
 275         str     w0, [rFP, #LO_address]    /* some handlers still need it... */
 276         \movop  w0, w1
 277         memhandler_pre
 278         blr     x3
 279 .endm
 280
 281 FUNCTION(jump_handler_write8):
 282         add     x3, x3, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 283         pcsx_write_mem strb uxtb 0
 284         b       handler_write_end
 285
 286 FUNCTION(jump_handler_write16):
 287         add     x3, x3, #0x1000/4*8               /* shift to r16 part */
 288         pcsx_write_mem strh uxth 1
 289         b       handler_write_end
 290
 291 FUNCTION(jump_handler_write32):
 292         pcsx_write_mem str mov 2
 293
 294 handler_write_end:
 295         memhandler_post
 296         ldp     xzr, x30, [sp], #16
 297         ret
 298
 299 FUNCTION(jump_handle_swl):
 300         /* w0 = address, w1 = data, w2 = cycles */
 301         ldr     x3, [rFP, #LO_mem_wtab]
 302         orr     w4, wzr, w0, lsr #12
 303         ldr     x3, [x3, w4, uxtw #3]
 304         adds    x3, x3, x3
 305         bcs     4f
 306         add     x3, x0, x3
 307         mov     w0, w2
 308         tbz     x3, #1, 10f     // & 2
 309         tbz     x3, #0, 2f      // & 1
 310 3:
 311         stur    w1, [x3, #-3]
 312         ret
 313 2:
 314         lsr     w2, w1, #8
 315         lsr     w1, w1, #24
 316         sturh   w2, [x3, #-2]
 317         strb    w1, [x3]
 318         ret
 319 10:
 320         tbz     x3, #0, 0f      // & 1
 321 1:
 322         lsr     w1, w1, #16
 323         sturh   w1, [x3, #-1]
 324         ret
 325 0:
 326         lsr     w2, w1, #24
 327         strb    w2, [x3]
 328         ret
 329 4:
 330         mov     w0, w2          // todo
 331         bl      abort
 332         ret
 333
 334 FUNCTION(jump_handle_swr):
 335         /* w0 = address, w1 = data, w2 = cycles */
 336         ldr     x3, [rFP, #LO_mem_wtab]
 337         orr     w4, wzr, w0, lsr #12
 338         ldr     x3, [x3, w4, uxtw #3]
 339         adds    x3, x3, x3
 340         bcs     4f
 341         add     x3, x0, x3
 342         mov     w0, w2
 343         tbz     x3, #1, 10f     // & 2
 344         tbz     x3, #0, 2f      // & 1
 345 3:
 346         strb    w1, [x3]
 347         ret
 348 2:
 349         strh    w1, [x3]
 350         ret
 351 10:
 352         tbz     x3, #0, 0f      // & 1
 353 1:
 354         lsr     w2, w1, #8
 355         strb    w1, [x3]
 356         sturh   w2, [x3, #1]
 357         ret
 358 0:
 359         str     w1, [x3]
 360         ret
 361 4:
 362         mov     w0, w2          // todo
 363         bl      abort
 364         ret
 365
 366 FUNCTION(call_gteStall):
 367         /* w0 = op_cycles, w1 = cycles */
 368         ldr     w2, [rFP, #LO_last_count]
 369         str     lr, [rFP, #LO_saved_lr]
 370         add     w1, w1, w2
 371         str     w1, [rFP, #LO_cycle]
 372         add     x1, rFP, #LO_psxRegs
 373         bl      gteCheckStallRaw
 374         ldr     lr, [rFP, #LO_saved_lr]
 375         add     rCC, rCC, w0
 376         ret
 377