| e14743d1 |
1 | ############################################################################## |
| 2 | # ltdl.m4 - Configure ltdl for the target system. -*-Autoconf-*- |
| 3 | # |
| 4 | # Copyright (C) 1999-2006, 2007, 2008 Free Software Foundation, Inc. |
| 5 | # Written by Thomas Tanner, 1999 |
| 6 | # |
| 7 | # This file is free software; the Free Software Foundation gives |
| 8 | # unlimited permission to copy and/or distribute it, with or without |
| 9 | # modifications, as long as this notice is preserved. |
| 10 | |
| 11 | # serial 17 LTDL_INIT |
| 12 | |
| 13 | # LT_CONFIG_LTDL_DIR(DIRECTORY, [LTDL-MODE]) |
| 14 | # ------------------------------------------ |
| 15 | # DIRECTORY contains the libltdl sources. It is okay to call this |
| 16 | # function multiple times, as long as the same DIRECTORY is always given. |
| 17 | AC_DEFUN([LT_CONFIG_LTDL_DIR], |
| 18 | [AC_BEFORE([$0], [LTDL_INIT]) |
| 19 | _$0($*) |
| 20 | ])# LT_CONFIG_LTDL_DIR |
| 21 | |
| 22 | # We break this out into a separate macro, so that we can call it safely |
| 23 | # internally without being caught accidentally by the sed scan in libtoolize. |
| 24 | m4_defun([_LT_CONFIG_LTDL_DIR], |
| 25 | [dnl remove trailing slashes |
| 26 | m4_pushdef([_ARG_DIR], m4_bpatsubst([$1], [/*$])) |
| 27 | m4_case(_LTDL_DIR, |
| 28 | [], [dnl only set lt_ltdl_dir if _ARG_DIR is not simply `.' |
| 29 | m4_if(_ARG_DIR, [.], |
| 30 | [], |
| 31 | [m4_define([_LTDL_DIR], _ARG_DIR) |
| 32 | _LT_SHELL_INIT([lt_ltdl_dir=']_ARG_DIR['])])], |
| 33 | [m4_if(_ARG_DIR, _LTDL_DIR, |
| 34 | [], |
| 35 | [m4_fatal([multiple libltdl directories: `]_LTDL_DIR[', `]_ARG_DIR['])])]) |
| 36 | m4_popdef([_ARG_DIR]) |
| 37 | ])# _LT_CONFIG_LTDL_DIR |
| 38 | |
| 39 | # Initialise: |
| 40 | m4_define([_LTDL_DIR], []) |
| 41 | |
| 42 | |
| 43 | # _LT_BUILD_PREFIX |
| 44 | # ---------------- |
| 45 | # If Autoconf is new enough, expand to `${top_build_prefix}', otherwise |
| 46 | # to `${top_builddir}/'. |
| 47 | m4_define([_LT_BUILD_PREFIX], |
| 48 | [m4_ifdef([AC_AUTOCONF_VERSION], |
| 49 | [m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.62]), |
| 50 | [-1], [m4_ifdef([_AC_HAVE_TOP_BUILD_PREFIX], |
| 51 | [${top_build_prefix}], |
| 52 | [${top_builddir}/])], |
| 53 | [${top_build_prefix}])], |
| 54 | [${top_builddir}/])[]dnl |
| 55 | ]) |
| 56 | |
| 57 | |
| 58 | # LTDL_CONVENIENCE |
| 59 | # ---------------- |
| 60 | # sets LIBLTDL to the link flags for the libltdl convenience library and |
| 61 | # LTDLINCL to the include flags for the libltdl header and adds |
| 62 | # --enable-ltdl-convenience to the configure arguments. Note that |
| 63 | # AC_CONFIG_SUBDIRS is not called here. LIBLTDL will be prefixed with |
| 64 | # '${top_build_prefix}' if available, otherwise with '${top_builddir}/', |
| 65 | # and LTDLINCL will be prefixed with '${top_srcdir}/' (note the single |
| 66 | # quotes!). If your package is not flat and you're not using automake, |
| 67 | # define top_build_prefix, top_builddir, and top_srcdir appropriately |
| 68 | # in your Makefiles. |
| 69 | AC_DEFUN([LTDL_CONVENIENCE], |
| 70 | [AC_BEFORE([$0], [LTDL_INIT])dnl |
| 71 | dnl Although the argument is deprecated and no longer documented, |
| 72 | dnl LTDL_CONVENIENCE used to take a DIRECTORY orgument, if we have one |
| 73 | dnl here make sure it is the same as any other declaration of libltdl's |
| 74 | dnl location! This also ensures lt_ltdl_dir is set when configure.ac is |
| 75 | dnl not yet using an explicit LT_CONFIG_LTDL_DIR. |
| 76 | m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl |
| 77 | _$0() |
| 78 | ])# LTDL_CONVENIENCE |
| 79 | |
| 80 | # AC_LIBLTDL_CONVENIENCE accepted a directory argument in older libtools, |
| 81 | # now we have LT_CONFIG_LTDL_DIR: |
| 82 | AU_DEFUN([AC_LIBLTDL_CONVENIENCE], |
| 83 | [_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])]) |
| 84 | _LTDL_CONVENIENCE]) |
| 85 | |
| 86 | dnl aclocal-1.4 backwards compatibility: |
| 87 | dnl AC_DEFUN([AC_LIBLTDL_CONVENIENCE], []) |
| 88 | |
| 89 | |
| 90 | # _LTDL_CONVENIENCE |
| 91 | # ----------------- |
| 92 | # Code shared by LTDL_CONVENIENCE and LTDL_INIT([convenience]). |
| 93 | m4_defun([_LTDL_CONVENIENCE], |
| 94 | [case $enable_ltdl_convenience in |
| 95 | no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;; |
| 96 | "") enable_ltdl_convenience=yes |
| 97 | ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;; |
| 98 | esac |
| 99 | LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdlc.la" |
| 100 | LTDLDEPS=$LIBLTDL |
| 101 | LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}" |
| 102 | |
| 103 | AC_SUBST([LIBLTDL]) |
| 104 | AC_SUBST([LTDLDEPS]) |
| 105 | AC_SUBST([LTDLINCL]) |
| 106 | |
| 107 | # For backwards non-gettext consistent compatibility... |
| 108 | INCLTDL="$LTDLINCL" |
| 109 | AC_SUBST([INCLTDL]) |
| 110 | ])# _LTDL_CONVENIENCE |
| 111 | |
| 112 | |
| 113 | # LTDL_INSTALLABLE |
| 114 | # ---------------- |
| 115 | # sets LIBLTDL to the link flags for the libltdl installable library |
| 116 | # and LTDLINCL to the include flags for the libltdl header and adds |
| 117 | # --enable-ltdl-install to the configure arguments. Note that |
| 118 | # AC_CONFIG_SUBDIRS is not called from here. If an installed libltdl |
| 119 | # is not found, LIBLTDL will be prefixed with '${top_build_prefix}' if |
| 120 | # available, otherwise with '${top_builddir}/', and LTDLINCL will be |
| 121 | # prefixed with '${top_srcdir}/' (note the single quotes!). If your |
| 122 | # package is not flat and you're not using automake, define top_build_prefix, |
| 123 | # top_builddir, and top_srcdir appropriately in your Makefiles. |
| 124 | # In the future, this macro may have to be called after LT_INIT. |
| 125 | AC_DEFUN([LTDL_INSTALLABLE], |
| 126 | [AC_BEFORE([$0], [LTDL_INIT])dnl |
| 127 | dnl Although the argument is deprecated and no longer documented, |
| 128 | dnl LTDL_INSTALLABLE used to take a DIRECTORY orgument, if we have one |
| 129 | dnl here make sure it is the same as any other declaration of libltdl's |
| 130 | dnl location! This also ensures lt_ltdl_dir is set when configure.ac is |
| 131 | dnl not yet using an explicit LT_CONFIG_LTDL_DIR. |
| 132 | m4_ifval([$1], [_LT_CONFIG_LTDL_DIR([$1])])dnl |
| 133 | _$0() |
| 134 | ])# LTDL_INSTALLABLE |
| 135 | |
| 136 | # AC_LIBLTDL_INSTALLABLE accepted a directory argument in older libtools, |
| 137 | # now we have LT_CONFIG_LTDL_DIR: |
| 138 | AU_DEFUN([AC_LIBLTDL_INSTALLABLE], |
| 139 | [_LT_CONFIG_LTDL_DIR([m4_default([$1], [libltdl])]) |
| 140 | _LTDL_INSTALLABLE]) |
| 141 | |
| 142 | dnl aclocal-1.4 backwards compatibility: |
| 143 | dnl AC_DEFUN([AC_LIBLTDL_INSTALLABLE], []) |
| 144 | |
| 145 | |
| 146 | # _LTDL_INSTALLABLE |
| 147 | # ----------------- |
| 148 | # Code shared by LTDL_INSTALLABLE and LTDL_INIT([installable]). |
| 149 | m4_defun([_LTDL_INSTALLABLE], |
| 150 | [if test -f $prefix/lib/libltdl.la; then |
| 151 | lt_save_LDFLAGS="$LDFLAGS" |
| 152 | LDFLAGS="-L$prefix/lib $LDFLAGS" |
| 153 | AC_CHECK_LIB([ltdl], [lt_dlinit], [lt_lib_ltdl=yes]) |
| 154 | LDFLAGS="$lt_save_LDFLAGS" |
| 155 | if test x"${lt_lib_ltdl-no}" = xyes; then |
| 156 | if test x"$enable_ltdl_install" != xyes; then |
| 157 | # Don't overwrite $prefix/lib/libltdl.la without --enable-ltdl-install |
| 158 | AC_MSG_WARN([not overwriting libltdl at $prefix, force with `--enable-ltdl-install']) |
| 159 | enable_ltdl_install=no |
| 160 | fi |
| 161 | elif test x"$enable_ltdl_install" = xno; then |
| 162 | AC_MSG_WARN([libltdl not installed, but installation disabled]) |
| 163 | fi |
| 164 | fi |
| 165 | |
| 166 | # If configure.ac declared an installable ltdl, and the user didn't override |
| 167 | # with --disable-ltdl-install, we will install the shipped libltdl. |
| 168 | case $enable_ltdl_install in |
| 169 | no) ac_configure_args="$ac_configure_args --enable-ltdl-install=no" |
| 170 | LIBLTDL="-lltdl" |
| 171 | LTDLDEPS= |
| 172 | LTDLINCL= |
| 173 | ;; |
| 174 | *) enable_ltdl_install=yes |
| 175 | ac_configure_args="$ac_configure_args --enable-ltdl-install" |
| 176 | LIBLTDL='_LT_BUILD_PREFIX'"${lt_ltdl_dir+$lt_ltdl_dir/}libltdl.la" |
| 177 | LTDLDEPS=$LIBLTDL |
| 178 | LTDLINCL='-I${top_srcdir}'"${lt_ltdl_dir+/$lt_ltdl_dir}" |
| 179 | ;; |
| 180 | esac |
| 181 | |
| 182 | AC_SUBST([LIBLTDL]) |
| 183 | AC_SUBST([LTDLDEPS]) |
| 184 | AC_SUBST([LTDLINCL]) |
| 185 | |
| 186 | # For backwards non-gettext consistent compatibility... |
| 187 | INCLTDL="$LTDLINCL" |
| 188 | AC_SUBST([INCLTDL]) |
| 189 | ])# LTDL_INSTALLABLE |
| 190 | |
| 191 | |
| 192 | # _LTDL_MODE_DISPATCH |
| 193 | # ------------------- |
| 194 | m4_define([_LTDL_MODE_DISPATCH], |
| 195 | [dnl If _LTDL_DIR is `.', then we are configuring libltdl itself: |
| 196 | m4_if(_LTDL_DIR, [], |
| 197 | [], |
| 198 | dnl if _LTDL_MODE was not set already, the default value is `subproject': |
| 199 | [m4_case(m4_default(_LTDL_MODE, [subproject]), |
| 200 | [subproject], [AC_CONFIG_SUBDIRS(_LTDL_DIR) |
| 201 | _LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"])], |
| 202 | [nonrecursive], [_LT_SHELL_INIT([lt_dlopen_dir="$lt_ltdl_dir"; lt_libobj_prefix="$lt_ltdl_dir/"])], |
| 203 | [recursive], [], |
| 204 | [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])])dnl |
| 205 | dnl Be careful not to expand twice: |
| 206 | m4_define([$0], []) |
| 207 | ])# _LTDL_MODE_DISPATCH |
| 208 | |
| 209 | |
| 210 | # _LT_LIBOBJ(MODULE_NAME) |
| 211 | # ----------------------- |
| 212 | # Like AC_LIBOBJ, except that MODULE_NAME goes into _LT_LIBOBJS instead |
| 213 | # of into LIBOBJS. |
| 214 | AC_DEFUN([_LT_LIBOBJ], [ |
| 215 | m4_pattern_allow([^_LT_LIBOBJS$]) |
| 216 | _LT_LIBOBJS="$_LT_LIBOBJS $1.$ac_objext" |
| 217 | ])# _LT_LIBOBJS |
| 218 | |
| 219 | |
| 220 | # LTDL_INIT([OPTIONS]) |
| 221 | # -------------------- |
| 222 | # Clients of libltdl can use this macro to allow the installer to |
| 223 | # choose between a shipped copy of the ltdl sources or a preinstalled |
| 224 | # version of the library. If the shipped ltdl sources are not in a |
| 225 | # subdirectory named libltdl, the directory name must be given by |
| 226 | # LT_CONFIG_LTDL_DIR. |
| 227 | AC_DEFUN([LTDL_INIT], |
| 228 | [dnl Parse OPTIONS |
| 229 | _LT_SET_OPTIONS([$0], [$1]) |
| 230 | |
| 231 | dnl We need to keep our own list of libobjs separate from our parent project, |
| 232 | dnl and the easiest way to do that is redefine the AC_LIBOBJs macro while |
| 233 | dnl we look for our own LIBOBJs. |
| 234 | m4_pushdef([AC_LIBOBJ], m4_defn([_LT_LIBOBJ])) |
| 235 | m4_pushdef([AC_LIBSOURCES]) |
| 236 | |
| 237 | dnl If not otherwise defined, default to the 1.5.x compatible subproject mode: |
| 238 | m4_if(_LTDL_MODE, [], |
| 239 | [m4_define([_LTDL_MODE], m4_default([$2], [subproject])) |
| 240 | m4_if([-1], [m4_bregexp(_LTDL_MODE, [\(subproject\|\(non\)?recursive\)])], |
| 241 | [m4_fatal([unknown libltdl mode: ]_LTDL_MODE)])]) |
| 242 | |
| 243 | AC_ARG_WITH([included_ltdl], |
| 244 | [AS_HELP_STRING([--with-included-ltdl], |
| 245 | [use the GNU ltdl sources included here])]) |
| 246 | |
| 247 | if test "x$with_included_ltdl" != xyes; then |
| 248 | # We are not being forced to use the included libltdl sources, so |
| 249 | # decide whether there is a useful installed version we can use. |
| 250 | AC_CHECK_HEADER([ltdl.h], |
| 251 | [AC_CHECK_DECL([lt_dlinterface_register], |
| 252 | [AC_CHECK_LIB([ltdl], [lt_dladvise_preload], |
| 253 | [with_included_ltdl=no], |
| 254 | [with_included_ltdl=yes])], |
| 255 | [with_included_ltdl=yes], |
| 256 | [AC_INCLUDES_DEFAULT |
| 257 | #include <ltdl.h>])], |
| 258 | [with_included_ltdl=yes], |
| 259 | [AC_INCLUDES_DEFAULT] |
| 260 | ) |
| 261 | fi |
| 262 | |
| 263 | dnl If neither LT_CONFIG_LTDL_DIR, LTDL_CONVENIENCE nor LTDL_INSTALLABLE |
| 264 | dnl was called yet, then for old times' sake, we assume libltdl is in an |
| 265 | dnl eponymous directory: |
| 266 | AC_PROVIDE_IFELSE([LT_CONFIG_LTDL_DIR], [], [_LT_CONFIG_LTDL_DIR([libltdl])]) |
| 267 | |
| 268 | AC_ARG_WITH([ltdl_include], |
| 269 | [AS_HELP_STRING([--with-ltdl-include=DIR], |
| 270 | [use the ltdl headers installed in DIR])]) |
| 271 | |
| 272 | if test -n "$with_ltdl_include"; then |
| 273 | if test -f "$with_ltdl_include/ltdl.h"; then : |
| 274 | else |
| 275 | AC_MSG_ERROR([invalid ltdl include directory: `$with_ltdl_include']) |
| 276 | fi |
| 277 | else |
| 278 | with_ltdl_include=no |
| 279 | fi |
| 280 | |
| 281 | AC_ARG_WITH([ltdl_lib], |
| 282 | [AS_HELP_STRING([--with-ltdl-lib=DIR], |
| 283 | [use the libltdl.la installed in DIR])]) |
| 284 | |
| 285 | if test -n "$with_ltdl_lib"; then |
| 286 | if test -f "$with_ltdl_lib/libltdl.la"; then : |
| 287 | else |
| 288 | AC_MSG_ERROR([invalid ltdl library directory: `$with_ltdl_lib']) |
| 289 | fi |
| 290 | else |
| 291 | with_ltdl_lib=no |
| 292 | fi |
| 293 | |
| 294 | case ,$with_included_ltdl,$with_ltdl_include,$with_ltdl_lib, in |
| 295 | ,yes,no,no,) |
| 296 | m4_case(m4_default(_LTDL_TYPE, [convenience]), |
| 297 | [convenience], [_LTDL_CONVENIENCE], |
| 298 | [installable], [_LTDL_INSTALLABLE], |
| 299 | [m4_fatal([unknown libltdl build type: ]_LTDL_TYPE)]) |
| 300 | ;; |
| 301 | ,no,no,no,) |
| 302 | # If the included ltdl is not to be used, then use the |
| 303 | # preinstalled libltdl we found. |
| 304 | AC_DEFINE([HAVE_LTDL], [1], |
| 305 | [Define this if a modern libltdl is already installed]) |
| 306 | LIBLTDL=-lltdl |
| 307 | LTDLDEPS= |
| 308 | LTDLINCL= |
| 309 | ;; |
| 310 | ,no*,no,*) |
| 311 | AC_MSG_ERROR([`--with-ltdl-include' and `--with-ltdl-lib' options must be used together]) |
| 312 | ;; |
| 313 | *) with_included_ltdl=no |
| 314 | LIBLTDL="-L$with_ltdl_lib -lltdl" |
| 315 | LTDLDEPS= |
| 316 | LTDLINCL="-I$with_ltdl_include" |
| 317 | ;; |
| 318 | esac |
| 319 | INCLTDL="$LTDLINCL" |
| 320 | |
| 321 | # Report our decision... |
| 322 | AC_MSG_CHECKING([where to find libltdl headers]) |
| 323 | AC_MSG_RESULT([$LTDLINCL]) |
| 324 | AC_MSG_CHECKING([where to find libltdl library]) |
| 325 | AC_MSG_RESULT([$LIBLTDL]) |
| 326 | |
| 327 | _LTDL_SETUP |
| 328 | |
| 329 | dnl restore autoconf definition. |
| 330 | m4_popdef([AC_LIBOBJ]) |
| 331 | m4_popdef([AC_LIBSOURCES]) |
| 332 | |
| 333 | AC_CONFIG_COMMANDS_PRE([ |
| 334 | _ltdl_libobjs= |
| 335 | _ltdl_ltlibobjs= |
| 336 | if test -n "$_LT_LIBOBJS"; then |
| 337 | # Remove the extension. |
| 338 | _lt_sed_drop_objext='s/\.o$//;s/\.obj$//' |
| 339 | for i in `for i in $_LT_LIBOBJS; do echo "$i"; done | sed "$_lt_sed_drop_objext" | sort -u`; do |
| 340 | _ltdl_libobjs="$_ltdl_libobjs $lt_libobj_prefix$i.$ac_objext" |
| 341 | _ltdl_ltlibobjs="$_ltdl_ltlibobjs $lt_libobj_prefix$i.lo" |
| 342 | done |
| 343 | fi |
| 344 | AC_SUBST([ltdl_LIBOBJS], [$_ltdl_libobjs]) |
| 345 | AC_SUBST([ltdl_LTLIBOBJS], [$_ltdl_ltlibobjs]) |
| 346 | ]) |
| 347 | |
| 348 | # Only expand once: |
| 349 | m4_define([LTDL_INIT]) |
| 350 | ])# LTDL_INIT |
| 351 | |
| 352 | # Old names: |
| 353 | AU_DEFUN([AC_LIB_LTDL], [LTDL_INIT($@)]) |
| 354 | AU_DEFUN([AC_WITH_LTDL], [LTDL_INIT($@)]) |
| 355 | AU_DEFUN([LT_WITH_LTDL], [LTDL_INIT($@)]) |
| 356 | dnl aclocal-1.4 backwards compatibility: |
| 357 | dnl AC_DEFUN([AC_LIB_LTDL], []) |
| 358 | dnl AC_DEFUN([AC_WITH_LTDL], []) |
| 359 | dnl AC_DEFUN([LT_WITH_LTDL], []) |
| 360 | |
| 361 | |
| 362 | # _LTDL_SETUP |
| 363 | # ----------- |
| 364 | # Perform all the checks necessary for compilation of the ltdl objects |
| 365 | # -- including compiler checks and header checks. This is a public |
| 366 | # interface mainly for the benefit of libltdl's own configure.ac, most |
| 367 | # other users should call LTDL_INIT instead. |
| 368 | AC_DEFUN([_LTDL_SETUP], |
| 369 | [AC_REQUIRE([AC_PROG_CC])dnl |
| 370 | AC_REQUIRE([LT_SYS_MODULE_EXT])dnl |
| 371 | AC_REQUIRE([LT_SYS_MODULE_PATH])dnl |
| 372 | AC_REQUIRE([LT_SYS_DLSEARCH_PATH])dnl |
| 373 | AC_REQUIRE([LT_LIB_DLLOAD])dnl |
| 374 | AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl |
| 375 | AC_REQUIRE([LT_FUNC_DLSYM_USCORE])dnl |
| 376 | AC_REQUIRE([LT_SYS_DLOPEN_DEPLIBS])dnl |
| 377 | AC_REQUIRE([gl_FUNC_ARGZ])dnl |
| 378 | |
| 379 | m4_require([_LT_CHECK_OBJDIR])dnl |
| 380 | m4_require([_LT_HEADER_DLFCN])dnl |
| 381 | m4_require([_LT_CHECK_DLPREOPEN])dnl |
| 382 | m4_require([_LT_DECL_SED])dnl |
| 383 | |
| 384 | dnl Don't require this, or it will be expanded earlier than the code |
| 385 | dnl that sets the variables it relies on: |
| 386 | _LT_ENABLE_INSTALL |
| 387 | |
| 388 | dnl _LTDL_MODE specific code must be called at least once: |
| 389 | _LTDL_MODE_DISPATCH |
| 390 | |
| 391 | # In order that ltdl.c can compile, find out the first AC_CONFIG_HEADERS |
| 392 | # the user used. This is so that ltdl.h can pick up the parent projects |
| 393 | # config.h file, The first file in AC_CONFIG_HEADERS must contain the |
| 394 | # definitions required by ltdl.c. |
| 395 | # FIXME: Remove use of undocumented AC_LIST_HEADERS (2.59 compatibility). |
| 396 | AC_CONFIG_COMMANDS_PRE([dnl |
| 397 | m4_pattern_allow([^LT_CONFIG_H$])dnl |
| 398 | m4_ifset([AH_HEADER], |
| 399 | [LT_CONFIG_H=AH_HEADER], |
| 400 | [m4_ifset([AC_LIST_HEADERS], |
| 401 | [LT_CONFIG_H=`echo "AC_LIST_HEADERS" | $SED 's,^[[ ]]*,,;s,[[ :]].*$,,'`], |
| 402 | [])])]) |
| 403 | AC_SUBST([LT_CONFIG_H]) |
| 404 | |
| 405 | AC_CHECK_HEADERS([unistd.h dl.h sys/dl.h dld.h mach-o/dyld.h dirent.h], |
| 406 | [], [], [AC_INCLUDES_DEFAULT]) |
| 407 | |
| 408 | AC_CHECK_FUNCS([closedir opendir readdir], [], [AC_LIBOBJ([lt__dirent])]) |
| 409 | AC_CHECK_FUNCS([strlcat strlcpy], [], [AC_LIBOBJ([lt__strl])]) |
| 410 | |
| 411 | AC_DEFINE_UNQUOTED([LT_LIBEXT],["$libext"],[The archive extension]) |
| 412 | |
| 413 | name=ltdl |
| 414 | LTDLOPEN=`eval "\\$ECHO \"$libname_spec\""` |
| 415 | AC_SUBST([LTDLOPEN]) |
| 416 | ])# _LTDL_SETUP |
| 417 | |
| 418 | |
| 419 | # _LT_ENABLE_INSTALL |
| 420 | # ------------------ |
| 421 | m4_define([_LT_ENABLE_INSTALL], |
| 422 | [AC_ARG_ENABLE([ltdl-install], |
| 423 | [AS_HELP_STRING([--enable-ltdl-install], [install libltdl])]) |
| 424 | |
| 425 | case ,${enable_ltdl_install},${enable_ltdl_convenience} in |
| 426 | *yes*) ;; |
| 427 | *) enable_ltdl_convenience=yes ;; |
| 428 | esac |
| 429 | |
| 430 | m4_ifdef([AM_CONDITIONAL], |
| 431 | [AM_CONDITIONAL(INSTALL_LTDL, test x"${enable_ltdl_install-no}" != xno) |
| 432 | AM_CONDITIONAL(CONVENIENCE_LTDL, test x"${enable_ltdl_convenience-no}" != xno)]) |
| 433 | ])# _LT_ENABLE_INSTALL |
| 434 | |
| 435 | |
| 436 | # LT_SYS_DLOPEN_DEPLIBS |
| 437 | # --------------------- |
| 438 | AC_DEFUN([LT_SYS_DLOPEN_DEPLIBS], |
| 439 | [AC_REQUIRE([AC_CANONICAL_HOST])dnl |
| 440 | AC_CACHE_CHECK([whether deplibs are loaded by dlopen], |
| 441 | [lt_cv_sys_dlopen_deplibs], |
| 442 | [# PORTME does your system automatically load deplibs for dlopen? |
| 443 | # or its logical equivalent (e.g. shl_load for HP-UX < 11) |
| 444 | # For now, we just catch OSes we know something about -- in the |
| 445 | # future, we'll try test this programmatically. |
| 446 | lt_cv_sys_dlopen_deplibs=unknown |
| 447 | case $host_os in |
| 448 | aix3*|aix4.1.*|aix4.2.*) |
| 449 | # Unknown whether this is true for these versions of AIX, but |
| 450 | # we want this `case' here to explicitly catch those versions. |
| 451 | lt_cv_sys_dlopen_deplibs=unknown |
| 452 | ;; |
| 453 | aix[[4-9]]*) |
| 454 | lt_cv_sys_dlopen_deplibs=yes |
| 455 | ;; |
| 456 | amigaos*) |
| 457 | case $host_cpu in |
| 458 | powerpc) |
| 459 | lt_cv_sys_dlopen_deplibs=no |
| 460 | ;; |
| 461 | esac |
| 462 | ;; |
| 463 | darwin*) |
| 464 | # Assuming the user has installed a libdl from somewhere, this is true |
| 465 | # If you are looking for one http://www.opendarwin.org/projects/dlcompat |
| 466 | lt_cv_sys_dlopen_deplibs=yes |
| 467 | ;; |
| 468 | freebsd* | dragonfly*) |
| 469 | lt_cv_sys_dlopen_deplibs=yes |
| 470 | ;; |
| 471 | gnu* | linux* | k*bsd*-gnu) |
| 472 | # GNU and its variants, using gnu ld.so (Glibc) |
| 473 | lt_cv_sys_dlopen_deplibs=yes |
| 474 | ;; |
| 475 | hpux10*|hpux11*) |
| 476 | lt_cv_sys_dlopen_deplibs=yes |
| 477 | ;; |
| 478 | interix*) |
| 479 | lt_cv_sys_dlopen_deplibs=yes |
| 480 | ;; |
| 481 | irix[[12345]]*|irix6.[[01]]*) |
| 482 | # Catch all versions of IRIX before 6.2, and indicate that we don't |
| 483 | # know how it worked for any of those versions. |
| 484 | lt_cv_sys_dlopen_deplibs=unknown |
| 485 | ;; |
| 486 | irix*) |
| 487 | # The case above catches anything before 6.2, and it's known that |
| 488 | # at 6.2 and later dlopen does load deplibs. |
| 489 | lt_cv_sys_dlopen_deplibs=yes |
| 490 | ;; |
| 491 | netbsd*) |
| 492 | lt_cv_sys_dlopen_deplibs=yes |
| 493 | ;; |
| 494 | openbsd*) |
| 495 | lt_cv_sys_dlopen_deplibs=yes |
| 496 | ;; |
| 497 | osf[[1234]]*) |
| 498 | # dlopen did load deplibs (at least at 4.x), but until the 5.x series, |
| 499 | # it did *not* use an RPATH in a shared library to find objects the |
| 500 | # library depends on, so we explicitly say `no'. |
| 501 | lt_cv_sys_dlopen_deplibs=no |
| 502 | ;; |
| 503 | osf5.0|osf5.0a|osf5.1) |
| 504 | # dlopen *does* load deplibs and with the right loader patch applied |
| 505 | # it even uses RPATH in a shared library to search for shared objects |
| 506 | # that the library depends on, but there's no easy way to know if that |
| 507 | # patch is installed. Since this is the case, all we can really |
| 508 | # say is unknown -- it depends on the patch being installed. If |
| 509 | # it is, this changes to `yes'. Without it, it would be `no'. |
| 510 | lt_cv_sys_dlopen_deplibs=unknown |
| 511 | ;; |
| 512 | osf*) |
| 513 | # the two cases above should catch all versions of osf <= 5.1. Read |
| 514 | # the comments above for what we know about them. |
| 515 | # At > 5.1, deplibs are loaded *and* any RPATH in a shared library |
| 516 | # is used to find them so we can finally say `yes'. |
| 517 | lt_cv_sys_dlopen_deplibs=yes |
| 518 | ;; |
| 519 | qnx*) |
| 520 | lt_cv_sys_dlopen_deplibs=yes |
| 521 | ;; |
| 522 | solaris*) |
| 523 | lt_cv_sys_dlopen_deplibs=yes |
| 524 | ;; |
| 525 | sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*) |
| 526 | libltdl_cv_sys_dlopen_deplibs=yes |
| 527 | ;; |
| 528 | esac |
| 529 | ]) |
| 530 | if test "$lt_cv_sys_dlopen_deplibs" != yes; then |
| 531 | AC_DEFINE([LTDL_DLOPEN_DEPLIBS], [1], |
| 532 | [Define if the OS needs help to load dependent libraries for dlopen().]) |
| 533 | fi |
| 534 | ])# LT_SYS_DLOPEN_DEPLIBS |
| 535 | |
| 536 | # Old name: |
| 537 | AU_ALIAS([AC_LTDL_SYS_DLOPEN_DEPLIBS], [LT_SYS_DLOPEN_DEPLIBS]) |
| 538 | dnl aclocal-1.4 backwards compatibility: |
| 539 | dnl AC_DEFUN([AC_LTDL_SYS_DLOPEN_DEPLIBS], []) |
| 540 | |
| 541 | |
| 542 | # LT_SYS_MODULE_EXT |
| 543 | # ----------------- |
| 544 | AC_DEFUN([LT_SYS_MODULE_EXT], |
| 545 | [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl |
| 546 | AC_CACHE_CHECK([which extension is used for runtime loadable modules], |
| 547 | [libltdl_cv_shlibext], |
| 548 | [ |
| 549 | module=yes |
| 550 | eval libltdl_cv_shlibext=$shrext_cmds |
| 551 | ]) |
| 552 | if test -n "$libltdl_cv_shlibext"; then |
| 553 | m4_pattern_allow([LT_MODULE_EXT])dnl |
| 554 | AC_DEFINE_UNQUOTED([LT_MODULE_EXT], ["$libltdl_cv_shlibext"], |
| 555 | [Define to the extension used for runtime loadable modules, say, ".so".]) |
| 556 | fi |
| 557 | ])# LT_SYS_MODULE_EXT |
| 558 | |
| 559 | # Old name: |
| 560 | AU_ALIAS([AC_LTDL_SHLIBEXT], [LT_SYS_MODULE_EXT]) |
| 561 | dnl aclocal-1.4 backwards compatibility: |
| 562 | dnl AC_DEFUN([AC_LTDL_SHLIBEXT], []) |
| 563 | |
| 564 | |
| 565 | # LT_SYS_MODULE_PATH |
| 566 | # ------------------ |
| 567 | AC_DEFUN([LT_SYS_MODULE_PATH], |
| 568 | [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl |
| 569 | AC_CACHE_CHECK([which variable specifies run-time module search path], |
| 570 | [lt_cv_module_path_var], [lt_cv_module_path_var="$shlibpath_var"]) |
| 571 | if test -n "$lt_cv_module_path_var"; then |
| 572 | m4_pattern_allow([LT_MODULE_PATH_VAR])dnl |
| 573 | AC_DEFINE_UNQUOTED([LT_MODULE_PATH_VAR], ["$lt_cv_module_path_var"], |
| 574 | [Define to the name of the environment variable that determines the run-time module search path.]) |
| 575 | fi |
| 576 | ])# LT_SYS_MODULE_PATH |
| 577 | |
| 578 | # Old name: |
| 579 | AU_ALIAS([AC_LTDL_SHLIBPATH], [LT_SYS_MODULE_PATH]) |
| 580 | dnl aclocal-1.4 backwards compatibility: |
| 581 | dnl AC_DEFUN([AC_LTDL_SHLIBPATH], []) |
| 582 | |
| 583 | |
| 584 | # LT_SYS_DLSEARCH_PATH |
| 585 | # -------------------- |
| 586 | AC_DEFUN([LT_SYS_DLSEARCH_PATH], |
| 587 | [m4_require([_LT_SYS_DYNAMIC_LINKER])dnl |
| 588 | AC_CACHE_CHECK([for the default library search path], |
| 589 | [lt_cv_sys_dlsearch_path], |
| 590 | [lt_cv_sys_dlsearch_path="$sys_lib_dlsearch_path_spec"]) |
| 591 | if test -n "$lt_cv_sys_dlsearch_path"; then |
| 592 | sys_dlsearch_path= |
| 593 | for dir in $lt_cv_sys_dlsearch_path; do |
| 594 | if test -z "$sys_dlsearch_path"; then |
| 595 | sys_dlsearch_path="$dir" |
| 596 | else |
| 597 | sys_dlsearch_path="$sys_dlsearch_path$PATH_SEPARATOR$dir" |
| 598 | fi |
| 599 | done |
| 600 | m4_pattern_allow([LT_DLSEARCH_PATH])dnl |
| 601 | AC_DEFINE_UNQUOTED([LT_DLSEARCH_PATH], ["$sys_dlsearch_path"], |
| 602 | [Define to the system default library search path.]) |
| 603 | fi |
| 604 | ])# LT_SYS_DLSEARCH_PATH |
| 605 | |
| 606 | # Old name: |
| 607 | AU_ALIAS([AC_LTDL_SYSSEARCHPATH], [LT_SYS_DLSEARCH_PATH]) |
| 608 | dnl aclocal-1.4 backwards compatibility: |
| 609 | dnl AC_DEFUN([AC_LTDL_SYSSEARCHPATH], []) |
| 610 | |
| 611 | |
| 612 | # _LT_CHECK_DLPREOPEN |
| 613 | # ------------------- |
| 614 | m4_defun([_LT_CHECK_DLPREOPEN], |
| 615 | [m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl |
| 616 | AC_CACHE_CHECK([whether libtool supports -dlopen/-dlpreopen], |
| 617 | [libltdl_cv_preloaded_symbols], |
| 618 | [if test -n "$lt_cv_sys_global_symbol_pipe"; then |
| 619 | libltdl_cv_preloaded_symbols=yes |
| 620 | else |
| 621 | libltdl_cv_preloaded_symbols=no |
| 622 | fi |
| 623 | ]) |
| 624 | if test x"$libltdl_cv_preloaded_symbols" = xyes; then |
| 625 | AC_DEFINE([HAVE_PRELOADED_SYMBOLS], [1], |
| 626 | [Define if libtool can extract symbol lists from object files.]) |
| 627 | fi |
| 628 | ])# _LT_CHECK_DLPREOPEN |
| 629 | |
| 630 | |
| 631 | # LT_LIB_DLLOAD |
| 632 | # ------------- |
| 633 | AC_DEFUN([LT_LIB_DLLOAD], |
| 634 | [m4_pattern_allow([^LT_DLLOADERS$]) |
| 635 | LT_DLLOADERS= |
| 636 | AC_SUBST([LT_DLLOADERS]) |
| 637 | |
| 638 | AC_LANG_PUSH([C]) |
| 639 | |
| 640 | LIBADD_DLOPEN= |
| 641 | AC_SEARCH_LIBS([dlopen], [dl], |
| 642 | [AC_DEFINE([HAVE_LIBDL], [1], |
| 643 | [Define if you have the libdl library or equivalent.]) |
| 644 | if test "$ac_cv_search_dlopen" != "none required" ; then |
| 645 | LIBADD_DLOPEN="-ldl" |
| 646 | fi |
| 647 | libltdl_cv_lib_dl_dlopen="yes" |
| 648 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"], |
| 649 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if HAVE_DLFCN_H |
| 650 | # include <dlfcn.h> |
| 651 | #endif |
| 652 | ]], [[dlopen(0, 0);]])], |
| 653 | [AC_DEFINE([HAVE_LIBDL], [1], |
| 654 | [Define if you have the libdl library or equivalent.]) |
| 655 | libltdl_cv_func_dlopen="yes" |
| 656 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"], |
| 657 | [AC_CHECK_LIB([svld], [dlopen], |
| 658 | [AC_DEFINE([HAVE_LIBDL], [1], |
| 659 | [Define if you have the libdl library or equivalent.]) |
| 660 | LIBADD_DLOPEN="-lsvld" libltdl_cv_func_dlopen="yes" |
| 661 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dlopen.la"])])]) |
| 662 | if test x"$libltdl_cv_func_dlopen" = xyes || test x"$libltdl_cv_lib_dl_dlopen" = xyes |
| 663 | then |
| 664 | lt_save_LIBS="$LIBS" |
| 665 | LIBS="$LIBS $LIBADD_DLOPEN" |
| 666 | AC_CHECK_FUNCS([dlerror]) |
| 667 | LIBS="$lt_save_LIBS" |
| 668 | fi |
| 669 | AC_SUBST([LIBADD_DLOPEN]) |
| 670 | |
| 671 | LIBADD_SHL_LOAD= |
| 672 | AC_CHECK_FUNC([shl_load], |
| 673 | [AC_DEFINE([HAVE_SHL_LOAD], [1], |
| 674 | [Define if you have the shl_load function.]) |
| 675 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la"], |
| 676 | [AC_CHECK_LIB([dld], [shl_load], |
| 677 | [AC_DEFINE([HAVE_SHL_LOAD], [1], |
| 678 | [Define if you have the shl_load function.]) |
| 679 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}shl_load.la" |
| 680 | LIBADD_SHL_LOAD="-ldld"])]) |
| 681 | AC_SUBST([LIBADD_SHL_LOAD]) |
| 682 | |
| 683 | case $host_os in |
| 684 | darwin[[1567]].*) |
| 685 | # We only want this for pre-Mac OS X 10.4. |
| 686 | AC_CHECK_FUNC([_dyld_func_lookup], |
| 687 | [AC_DEFINE([HAVE_DYLD], [1], |
| 688 | [Define if you have the _dyld_func_lookup function.]) |
| 689 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dyld.la"]) |
| 690 | ;; |
| 691 | beos*) |
| 692 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}load_add_on.la" |
| 693 | ;; |
| 694 | cygwin* | mingw* | os2* | pw32*) |
| 695 | AC_CHECK_DECLS([cygwin_conv_path], [], [], [[#include <sys/cygwin.h>]]) |
| 696 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}loadlibrary.la" |
| 697 | ;; |
| 698 | esac |
| 699 | |
| 700 | AC_CHECK_LIB([dld], [dld_link], |
| 701 | [AC_DEFINE([HAVE_DLD], [1], |
| 702 | [Define if you have the GNU dld library.]) |
| 703 | LT_DLLOADERS="$LT_DLLOADERS ${lt_dlopen_dir+$lt_dlopen_dir/}dld_link.la"]) |
| 704 | AC_SUBST([LIBADD_DLD_LINK]) |
| 705 | |
| 706 | m4_pattern_allow([^LT_DLPREOPEN$]) |
| 707 | LT_DLPREOPEN= |
| 708 | if test -n "$LT_DLLOADERS" |
| 709 | then |
| 710 | for lt_loader in $LT_DLLOADERS; do |
| 711 | LT_DLPREOPEN="$LT_DLPREOPEN-dlpreopen $lt_loader " |
| 712 | done |
| 713 | AC_DEFINE([HAVE_LIBDLLOADER], [1], |
| 714 | [Define if libdlloader will be built on this platform]) |
| 715 | fi |
| 716 | AC_SUBST([LT_DLPREOPEN]) |
| 717 | |
| 718 | dnl This isn't used anymore, but set it for backwards compatibility |
| 719 | LIBADD_DL="$LIBADD_DLOPEN $LIBADD_SHL_LOAD" |
| 720 | AC_SUBST([LIBADD_DL]) |
| 721 | |
| 722 | AC_LANG_POP |
| 723 | ])# LT_LIB_DLLOAD |
| 724 | |
| 725 | # Old name: |
| 726 | AU_ALIAS([AC_LTDL_DLLIB], [LT_LIB_DLLOAD]) |
| 727 | dnl aclocal-1.4 backwards compatibility: |
| 728 | dnl AC_DEFUN([AC_LTDL_DLLIB], []) |
| 729 | |
| 730 | |
| 731 | # LT_SYS_SYMBOL_USCORE |
| 732 | # -------------------- |
| 733 | # does the compiler prefix global symbols with an underscore? |
| 734 | AC_DEFUN([LT_SYS_SYMBOL_USCORE], |
| 735 | [m4_require([_LT_CMD_GLOBAL_SYMBOLS])dnl |
| 736 | AC_CACHE_CHECK([for _ prefix in compiled symbols], |
| 737 | [lt_cv_sys_symbol_underscore], |
| 738 | [lt_cv_sys_symbol_underscore=no |
| 739 | cat > conftest.$ac_ext <<_LT_EOF |
| 740 | void nm_test_func(){} |
| 741 | int main(){nm_test_func;return 0;} |
| 742 | _LT_EOF |
| 743 | if AC_TRY_EVAL(ac_compile); then |
| 744 | # Now try to grab the symbols. |
| 745 | ac_nlist=conftest.nm |
| 746 | if AC_TRY_EVAL(NM conftest.$ac_objext \| $lt_cv_sys_global_symbol_pipe \> $ac_nlist) && test -s "$ac_nlist"; then |
| 747 | # See whether the symbols have a leading underscore. |
| 748 | if grep '^. _nm_test_func' "$ac_nlist" >/dev/null; then |
| 749 | lt_cv_sys_symbol_underscore=yes |
| 750 | else |
| 751 | if grep '^. nm_test_func ' "$ac_nlist" >/dev/null; then |
| 752 | : |
| 753 | else |
| 754 | echo "configure: cannot find nm_test_func in $ac_nlist" >&AS_MESSAGE_LOG_FD |
| 755 | fi |
| 756 | fi |
| 757 | else |
| 758 | echo "configure: cannot run $lt_cv_sys_global_symbol_pipe" >&AS_MESSAGE_LOG_FD |
| 759 | fi |
| 760 | else |
| 761 | echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD |
| 762 | cat conftest.c >&AS_MESSAGE_LOG_FD |
| 763 | fi |
| 764 | rm -rf conftest* |
| 765 | ]) |
| 766 | sys_symbol_underscore=$lt_cv_sys_symbol_underscore |
| 767 | AC_SUBST([sys_symbol_underscore]) |
| 768 | ])# LT_SYS_SYMBOL_USCORE |
| 769 | |
| 770 | # Old name: |
| 771 | AU_ALIAS([AC_LTDL_SYMBOL_USCORE], [LT_SYS_SYMBOL_USCORE]) |
| 772 | dnl aclocal-1.4 backwards compatibility: |
| 773 | dnl AC_DEFUN([AC_LTDL_SYMBOL_USCORE], []) |
| 774 | |
| 775 | |
| 776 | # LT_FUNC_DLSYM_USCORE |
| 777 | # -------------------- |
| 778 | AC_DEFUN([LT_FUNC_DLSYM_USCORE], |
| 779 | [AC_REQUIRE([LT_SYS_SYMBOL_USCORE])dnl |
| 780 | if test x"$lt_cv_sys_symbol_underscore" = xyes; then |
| 781 | if test x"$libltdl_cv_func_dlopen" = xyes || |
| 782 | test x"$libltdl_cv_lib_dl_dlopen" = xyes ; then |
| 783 | AC_CACHE_CHECK([whether we have to add an underscore for dlsym], |
| 784 | [libltdl_cv_need_uscore], |
| 785 | [libltdl_cv_need_uscore=unknown |
| 786 | save_LIBS="$LIBS" |
| 787 | LIBS="$LIBS $LIBADD_DLOPEN" |
| 788 | _LT_TRY_DLOPEN_SELF( |
| 789 | [libltdl_cv_need_uscore=no], [libltdl_cv_need_uscore=yes], |
| 790 | [], [libltdl_cv_need_uscore=cross]) |
| 791 | LIBS="$save_LIBS" |
| 792 | ]) |
| 793 | fi |
| 794 | fi |
| 795 | |
| 796 | if test x"$libltdl_cv_need_uscore" = xyes; then |
| 797 | AC_DEFINE([NEED_USCORE], [1], |
| 798 | [Define if dlsym() requires a leading underscore in symbol names.]) |
| 799 | fi |
| 800 | ])# LT_FUNC_DLSYM_USCORE |
| 801 | |
| 802 | # Old name: |
| 803 | AU_ALIAS([AC_LTDL_DLSYM_USCORE], [LT_FUNC_DLSYM_USCORE]) |
| 804 | dnl aclocal-1.4 backwards compatibility: |
| 805 | dnl AC_DEFUN([AC_LTDL_DLSYM_USCORE], []) |
| 806 | |
notaz.gp2x.de / sdl_omap.git / blame