libpcsxcore/new_dynarec/linkage_arm.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas                     *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "linkage_offsets.h"
  25
  26
  27 #ifdef __MACH__
  28 #define dynarec_local           ESYM(dynarec_local)
  29 #define ndrc_add_jump_out       ESYM(ndrc_add_jump_out)
  30 #define ndrc_try_restore_block  ESYM(ndrc_try_restore_block)
  31 #define ndrc_get_addr_ht        ESYM(ndrc_get_addr_ht)
  32 #define ndrc_get_addr_ht_param  ESYM(ndrc_get_addr_ht_param)
  33 #define ndrc_write_invalidate_one ESYM(ndrc_write_invalidate_one)
  34 #define gen_interupt            ESYM(gen_interupt)
  35 #define gteCheckStallRaw        ESYM(gteCheckStallRaw)
  36 #define psxException            ESYM(psxException)
  37 #endif
  38
  39         .bss
  40         .align  4
  41         .global dynarec_local
  42         .type   dynarec_local, %object
  43         .size   dynarec_local, LO_dynarec_local_size
  44 dynarec_local:
  45         .space  LO_dynarec_local_size
  46
  47 #define DRC_VAR_(name, vname, size_) \
  48         vname = dynarec_local + LO_##name; \
  49         .global vname; \
  50         .type   vname, %object; \
  51         .size   vname, size_
  52
  53 #define DRC_VAR(name, size_) \
  54         DRC_VAR_(name, ESYM(name), size_)
  55
  56 DRC_VAR(next_interupt, 4)
  57 DRC_VAR(cycle_count, 4)
  58 DRC_VAR(last_count, 4)
  59 DRC_VAR(pending_exception, 4)
  60 DRC_VAR(stop, 4)
  61 DRC_VAR(branch_target, 4)
  62 DRC_VAR(address, 4)
  63 DRC_VAR(hack_addr, 4)
  64 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  65
  66 /* psxRegs */
  67 @DRC_VAR(reg, 128)
  68 DRC_VAR(lo, 4)
  69 DRC_VAR(hi, 4)
  70 DRC_VAR(reg_cop0, 128)
  71 DRC_VAR(reg_cop2d, 128)
  72 DRC_VAR(reg_cop2c, 128)
  73 DRC_VAR(pcaddr, 4)
  74 @DRC_VAR(code, 4)
  75 @DRC_VAR(cycle, 4)
  76 @DRC_VAR(interrupt, 4)
  77 @DRC_VAR(intCycle, 256)
  78
  79 DRC_VAR(rcnts, 7*4*4)
  80 DRC_VAR(inv_code_start, 4)
  81 DRC_VAR(inv_code_end, 4)
  82 DRC_VAR(mem_rtab, 4)
  83 DRC_VAR(mem_wtab, 4)
  84 DRC_VAR(psxH_ptr, 4)
  85 DRC_VAR(zeromem_ptr, 4)
  86 DRC_VAR(invc_ptr, 4)
  87 DRC_VAR(scratch_buf_ptr, 4)
  88 DRC_VAR(ram_offset, 4)
  89 DRC_VAR(mini_ht, 256)
  90
  91
  92         .syntax unified
  93         .text
  94         .align  2
  95
  96 #ifndef HAVE_ARMV5
  97 .macro blx rd
  98         mov     lr, pc
  99         bx      \rd
 100 .endm
 101 #endif
 102
 103 .macro load_varadr reg var
 104 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 105         movw    \reg, #:lower16:(\var-(1678f+8))
 106         movt    \reg, #:upper16:(\var-(1678f+8))
 107 1678:
 108         add     \reg, pc
 109 #elif defined(HAVE_ARMV7) && !defined(__PIC__)
 110         movw    \reg, #:lower16:\var
 111         movt    \reg, #:upper16:\var
 112 #else
 113         ldr     \reg, =\var
 114 #endif
 115 .endm
 116
 117 .macro load_varadr_ext reg var
 118 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 119         movw    \reg, #:lower16:(ptr_\var-(1678f+8))
 120         movt    \reg, #:upper16:(ptr_\var-(1678f+8))
 121 1678:
 122         ldr     \reg, [pc, \reg]
 123 #else
 124         load_varadr \reg \var
 125 #endif
 126 .endm
 127
 128 .macro mov_16 reg imm
 129 #ifdef HAVE_ARMV7
 130         movw    \reg, #\imm
 131 #else
 132         mov     \reg, #(\imm & 0x00ff)
 133         orr     \reg, #(\imm & 0xff00)
 134 #endif
 135 .endm
 136
 137 .macro mov_24 reg imm
 138 #ifdef HAVE_ARMV7
 139         movw    \reg, #(\imm & 0xffff)
 140         movt    \reg, #(\imm >> 16)
 141 #else
 142         mov     \reg, #(\imm & 0x0000ff)
 143         orr     \reg, #(\imm & 0x00ff00)
 144         orr     \reg, #(\imm & 0xff0000)
 145 #endif
 146 .endm
 147
 148 FUNCTION(dyna_linker):
 149         /* r0 = virtual target address */
 150         /* r1 = pointer to an instruction to patch */
 151 #ifndef NO_WRITE_EXEC
 152         ldr     r7, [r1]
 153         mov     r4, r0
 154         add     r6, r7, #2
 155         mov     r5, r1
 156         lsl     r6, r6, #8
 157         /* must not compile - that might expire the caller block */
 158         mov     r1, #0
 159         bl      ndrc_get_addr_ht_param
 160
 161         movs    r8, r0
 162         beq     0f
 163         add     r6, r5, r6, asr #6  /* old target */
 164         teq     r0, r6
 165         moveq   pc, r0 /* Stale i-cache */
 166         mov     r0, r4
 167         mov     r1, r6
 168         bl      ndrc_add_jump_out
 169
 170         sub     r2, r8, r5
 171         and     r1, r7, #0xff000000
 172         lsl     r2, r2, #6
 173         sub     r1, r1, #2
 174         add     r1, r1, r2, lsr #8
 175         str     r1, [r5]
 176         mov     pc, r8
 177 0:
 178         mov     r0, r4
 179 #else
 180         /* XXX: should be able to do better than this... */
 181 #endif
 182         bl      ndrc_get_addr_ht
 183         mov     pc, r0
 184         .size   dyna_linker, .-dyna_linker
 185
 186         .align  2
 187 FUNCTION(jump_vaddr_r1):
 188         mov     r0, r1
 189         b       jump_vaddr_r0
 190         .size   jump_vaddr_r1, .-jump_vaddr_r1
 191 FUNCTION(jump_vaddr_r2):
 192         mov     r0, r2
 193         b       jump_vaddr_r0
 194         .size   jump_vaddr_r2, .-jump_vaddr_r2
 195 FUNCTION(jump_vaddr_r3):
 196         mov     r0, r3
 197         b       jump_vaddr_r0
 198         .size   jump_vaddr_r3, .-jump_vaddr_r3
 199 FUNCTION(jump_vaddr_r4):
 200         mov     r0, r4
 201         b       jump_vaddr_r0
 202         .size   jump_vaddr_r4, .-jump_vaddr_r4
 203 FUNCTION(jump_vaddr_r5):
 204         mov     r0, r5
 205         b       jump_vaddr_r0
 206         .size   jump_vaddr_r5, .-jump_vaddr_r5
 207 FUNCTION(jump_vaddr_r6):
 208         mov     r0, r6
 209         b       jump_vaddr_r0
 210         .size   jump_vaddr_r6, .-jump_vaddr_r6
 211 FUNCTION(jump_vaddr_r8):
 212         mov     r0, r8
 213         b       jump_vaddr_r0
 214         .size   jump_vaddr_r8, .-jump_vaddr_r8
 215 FUNCTION(jump_vaddr_r9):
 216         mov     r0, r9
 217         b       jump_vaddr_r0
 218         .size   jump_vaddr_r9, .-jump_vaddr_r9
 219 FUNCTION(jump_vaddr_r10):
 220         mov     r0, r10
 221         b       jump_vaddr_r0
 222         .size   jump_vaddr_r10, .-jump_vaddr_r10
 223 FUNCTION(jump_vaddr_r12):
 224         mov     r0, r12
 225         b       jump_vaddr_r0
 226         .size   jump_vaddr_r12, .-jump_vaddr_r12
 227 FUNCTION(jump_vaddr_r7):
 228         add     r0, r7, #0
 229         .size   jump_vaddr_r7, .-jump_vaddr_r7
 230 FUNCTION(jump_vaddr_r0):
 231         bl      ndrc_get_addr_ht
 232         mov     pc, r0
 233         .size   jump_vaddr_r0, .-jump_vaddr_r0
 234
 235         .align  2
 236 FUNCTION(cc_interrupt):
 237         ldr     r0, [fp, #LO_last_count]
 238         mov     r1, #0
 239         add     r10, r0, r10
 240         str     r1, [fp, #LO_pending_exception]
 241         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 242 @@      str     r10, [fp, #LO_reg_cop0+36]      /* Count - not on PSX */
 243         mov     r10, lr
 244
 245         bl      gen_interupt
 246         mov     lr, r10
 247         ldr     r10, [fp, #LO_cycle]
 248         ldr     r0, [fp, #LO_next_interupt]
 249         ldr     r1, [fp, #LO_pending_exception]
 250         ldr     r2, [fp, #LO_stop]
 251         str     r0, [fp, #LO_last_count]
 252         sub     r10, r10, r0
 253         tst     r2, r2
 254         ldmfdne sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 255         tst     r1, r1
 256         moveq   pc, lr
 257         ldr     r0, [fp, #LO_pcaddr]
 258         bl      ndrc_get_addr_ht
 259         mov     pc, r0
 260         .size   cc_interrupt, .-cc_interrupt
 261
 262         .align  2
 263 FUNCTION(fp_exception):
 264         mov     r2, #0x10000000
 265 .E7:
 266         ldr     r1, [fp, #LO_reg_cop0+48] /* Status */
 267         mov     r3, #0x80000000
 268         str     r0, [fp, #LO_reg_cop0+56] /* EPC */
 269         orr     r1, #2
 270         add     r2, r2, #0x2c
 271         str     r1, [fp, #LO_reg_cop0+48] /* Status */
 272         str     r2, [fp, #LO_reg_cop0+52] /* Cause */
 273         add     r0, r3, #0x80
 274         bl      ndrc_get_addr_ht
 275         mov     pc, r0
 276         .size   fp_exception, .-fp_exception
 277         .align  2
 278 FUNCTION(fp_exception_ds):
 279         mov     r2, #0x90000000 /* Set high bit if delay slot */
 280         b       .E7
 281         .size   fp_exception_ds, .-fp_exception_ds
 282
 283         .align  2
 284 FUNCTION(jump_break_ds):
 285         mov     r0, #0x24
 286         mov     r1, #1
 287         b       call_psxException
 288 FUNCTION(jump_break):
 289         mov     r0, #0x24
 290         mov     r1, #0
 291         b       call_psxException
 292 FUNCTION(jump_syscall_ds):
 293         mov     r0, #0x20
 294         mov     r1, #1
 295         b       call_psxException
 296 FUNCTION(jump_syscall):
 297         mov     r0, #0x20
 298         mov     r1, #0
 299
 300 call_psxException:
 301         ldr     r3, [fp, #LO_last_count]
 302         str     r2, [fp, #LO_pcaddr]
 303         add     r10, r3, r10
 304         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 305         bl      psxException
 306
 307         /* note: psxException might do recursive recompiler call from it's HLE code,
 308          * so be ready for this */
 309 FUNCTION(jump_to_new_pc):
 310         ldr     r1, [fp, #LO_next_interupt]
 311         ldr     r10, [fp, #LO_cycle]
 312         ldr     r0, [fp, #LO_pcaddr]
 313         sub     r10, r10, r1
 314         str     r1, [fp, #LO_last_count]
 315         bl      ndrc_get_addr_ht
 316         mov     pc, r0
 317         .size   jump_to_new_pc, .-jump_to_new_pc
 318
 319         .align  2
 320 FUNCTION(new_dyna_leave):
 321         ldr     r0, [fp, #LO_last_count]
 322         add     r12, fp, #28
 323         add     r10, r0, r10
 324         str     r10, [fp, #LO_cycle]
 325         ldmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 326         .size   new_dyna_leave, .-new_dyna_leave
 327
 328         .align  2
 329 FUNCTION(invalidate_addr_r0):
 330         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 331         b       invalidate_addr_call
 332         .size   invalidate_addr_r0, .-invalidate_addr_r0
 333         .align  2
 334 FUNCTION(invalidate_addr_r1):
 335         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 336         mov     r0, r1
 337         b       invalidate_addr_call
 338         .size   invalidate_addr_r1, .-invalidate_addr_r1
 339         .align  2
 340 FUNCTION(invalidate_addr_r2):
 341         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 342         mov     r0, r2
 343         b       invalidate_addr_call
 344         .size   invalidate_addr_r2, .-invalidate_addr_r2
 345         .align  2
 346 FUNCTION(invalidate_addr_r3):
 347         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 348         mov     r0, r3
 349         b       invalidate_addr_call
 350         .size   invalidate_addr_r3, .-invalidate_addr_r3
 351         .align  2
 352 FUNCTION(invalidate_addr_r4):
 353         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 354         mov     r0, r4
 355         b       invalidate_addr_call
 356         .size   invalidate_addr_r4, .-invalidate_addr_r4
 357         .align  2
 358 FUNCTION(invalidate_addr_r5):
 359         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 360         mov     r0, r5
 361         b       invalidate_addr_call
 362         .size   invalidate_addr_r5, .-invalidate_addr_r5
 363         .align  2
 364 FUNCTION(invalidate_addr_r6):
 365         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 366         mov     r0, r6
 367         b       invalidate_addr_call
 368         .size   invalidate_addr_r6, .-invalidate_addr_r6
 369         .align  2
 370 FUNCTION(invalidate_addr_r7):
 371         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 372         mov     r0, r7
 373         b       invalidate_addr_call
 374         .size   invalidate_addr_r7, .-invalidate_addr_r7
 375         .align  2
 376 FUNCTION(invalidate_addr_r8):
 377         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 378         mov     r0, r8
 379         b       invalidate_addr_call
 380         .size   invalidate_addr_r8, .-invalidate_addr_r8
 381         .align  2
 382 FUNCTION(invalidate_addr_r9):
 383         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 384         mov     r0, r9
 385         b       invalidate_addr_call
 386         .size   invalidate_addr_r9, .-invalidate_addr_r9
 387         .align  2
 388 FUNCTION(invalidate_addr_r10):
 389         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 390         mov     r0, r10
 391         b       invalidate_addr_call
 392         .size   invalidate_addr_r10, .-invalidate_addr_r10
 393         .align  2
 394 FUNCTION(invalidate_addr_r12):
 395         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 396         mov     r0, r12
 397         .size   invalidate_addr_r12, .-invalidate_addr_r12
 398         .align  2
 399 invalidate_addr_call:
 400         ldr     r12, [fp, #LO_inv_code_start]
 401         ldr     lr, [fp, #LO_inv_code_end]
 402         cmp     r0, r12
 403         cmpcs   lr, r0
 404         blcc    ndrc_write_invalidate_one
 405         ldmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
 406         .size   invalidate_addr_call, .-invalidate_addr_call
 407
 408         .align  2
 409 FUNCTION(new_dyna_start):
 410         /* ip is stored to conform EABI alignment */
 411         stmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
 412         mov     fp, r0 /* dynarec_local */
 413         ldr     r0, [fp, #LO_pcaddr]
 414         bl      ndrc_get_addr_ht
 415         ldr     r1, [fp, #LO_next_interupt]
 416         ldr     r10, [fp, #LO_cycle]
 417         str     r1, [fp, #LO_last_count]
 418         sub     r10, r10, r1
 419         mov     pc, r0
 420         .size   new_dyna_start, .-new_dyna_start
 421
 422 /* --------------------------------------- */
 423
 424 .align  2
 425
 426 .macro pcsx_read_mem readop tab_shift
 427         /* r0 = address, r1 = handler_tab, r2 = cycles */
 428         lsl     r3, r0, #20
 429         lsr     r3, #(20+\tab_shift)
 430         ldr     r12, [fp, #LO_last_count]
 431         ldr     r1, [r1, r3, lsl #2]
 432         add     r2, r2, r12
 433         lsls    r1, #1
 434 .if \tab_shift == 1
 435         lsl     r3, #1
 436         \readop r0, [r1, r3]
 437 .else
 438         \readop r0, [r1, r3, lsl #\tab_shift]
 439 .endif
 440         movcc   pc, lr
 441         str     r2, [fp, #LO_cycle]
 442         bx      r1
 443 .endm
 444
 445 FUNCTION(jump_handler_read8):
 446         add     r1, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 447         pcsx_read_mem ldrbcc, 0
 448
 449 FUNCTION(jump_handler_read16):
 450         add     r1, #0x1000/4*4              @ shift to r16 part
 451         pcsx_read_mem ldrhcc, 1
 452
 453 FUNCTION(jump_handler_read32):
 454         pcsx_read_mem ldrcc, 2
 455
 456
 457 .macro memhandler_post
 458         ldr     r0, [fp, #LO_next_interupt]
 459         ldr     r2, [fp, #LO_cycle]        @ memhandlers can modify cc, like dma
 460         str     r0, [fp, #LO_last_count]
 461         sub     r0, r2, r0
 462 .endm
 463
 464 .macro pcsx_write_mem wrtop tab_shift
 465         /* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
 466         lsl     r12,r0, #20
 467         lsr     r12, #(20+\tab_shift)
 468         ldr     r3, [r3, r12, lsl #2]
 469         str     r0, [fp, #LO_address]      @ some handlers still need it..
 470         lsls    r3, #1
 471         mov     r0, r2                     @ cycle return in case of direct store
 472 .if \tab_shift == 1
 473         lsl     r12, #1
 474         \wrtop  r1, [r3, r12]
 475 .else
 476         \wrtop  r1, [r3, r12, lsl #\tab_shift]
 477 .endif
 478         movcc   pc, lr
 479         ldr     r12, [fp, #LO_last_count]
 480         mov     r0, r1
 481         add     r2, r2, r12
 482         str     r2, [fp, #LO_cycle]
 483
 484         str     lr, [fp, #LO_saved_lr]
 485         blx     r3
 486         ldr     lr, [fp, #LO_saved_lr]
 487
 488         memhandler_post
 489         bx      lr
 490 .endm
 491
 492 FUNCTION(jump_handler_write8):
 493         add     r3, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 494         pcsx_write_mem strbcc, 0
 495
 496 FUNCTION(jump_handler_write16):
 497         add     r3, #0x1000/4*4              @ shift to r16 part
 498         pcsx_write_mem strhcc, 1
 499
 500 FUNCTION(jump_handler_write32):
 501         pcsx_write_mem strcc, 2
 502
 503 FUNCTION(jump_handler_write_h):
 504         /* r0 = address, r1 = data, r2 = cycles, r3 = handler */
 505         ldr     r12, [fp, #LO_last_count]
 506         str     r0, [fp, #LO_address]      @ some handlers still need it..
 507         add     r2, r2, r12
 508         mov     r0, r1
 509         str     r2, [fp, #LO_cycle]
 510
 511         str     lr, [fp, #LO_saved_lr]
 512         blx     r3
 513         ldr     lr, [fp, #LO_saved_lr]
 514
 515         memhandler_post
 516         bx      lr
 517
 518 FUNCTION(jump_handle_swl):
 519         /* r0 = address, r1 = data, r2 = cycles */
 520         ldr     r3, [fp, #LO_mem_wtab]
 521         mov     r12,r0,lsr #12
 522         ldr     r3, [r3, r12, lsl #2]
 523         lsls    r3, #1
 524         bcs     4f
 525         add     r3, r0, r3
 526         mov     r0, r2
 527         tst     r3, #2
 528         beq     101f
 529         tst     r3, #1
 530         beq     2f
 531 3:
 532         str     r1, [r3, #-3]
 533         bx      lr
 534 2:
 535         lsr     r2, r1, #8
 536         lsr     r1, #24
 537         strh    r2, [r3, #-2]
 538         strb    r1, [r3]
 539         bx      lr
 540 101:
 541         tst     r3, #1
 542         lsrne   r1, #16         @ 1
 543         lsreq   r12, r1, #24    @ 0
 544         strhne  r1, [r3, #-1]
 545         strbeq  r12, [r3]
 546         bx      lr
 547 4:
 548         mov     r0, r2
 549 @       b       abort
 550         bx      lr              @ TODO?
 551
 552
 553 FUNCTION(jump_handle_swr):
 554         /* r0 = address, r1 = data, r2 = cycles */
 555         ldr     r3, [fp, #LO_mem_wtab]
 556         mov     r12,r0,lsr #12
 557         ldr     r3, [r3, r12, lsl #2]
 558         lsls    r3, #1
 559         bcs     4f
 560         add     r3, r0, r3
 561         and     r12,r3, #3
 562         mov     r0, r2
 563         cmp     r12,#2
 564         strbgt  r1, [r3]        @ 3
 565         strheq  r1, [r3]        @ 2
 566         cmp     r12,#1
 567         strlt   r1, [r3]        @ 0
 568         bxne    lr
 569         lsr     r2, r1, #8      @ 1
 570         strb    r1, [r3]
 571         strh    r2, [r3, #1]
 572         bx      lr
 573 4:
 574         mov     r0, r2
 575 @       b       abort
 576         bx      lr              @ TODO?
 577
 578
 579 .macro rcntx_read_mode0 num
 580         /* r0 = address, r2 = cycles */
 581         ldr     r3, [fp, #LO_rcnts+6*4+7*4*\num] @ cycleStart
 582         mov     r0, r2, lsl #16
 583         sub     r0, r0, r3, lsl #16
 584         lsr     r0, #16
 585         bx      lr
 586 .endm
 587
 588 FUNCTION(rcnt0_read_count_m0):
 589         rcntx_read_mode0 0
 590
 591 FUNCTION(rcnt1_read_count_m0):
 592         rcntx_read_mode0 1
 593
 594 FUNCTION(rcnt2_read_count_m0):
 595         rcntx_read_mode0 2
 596
 597 FUNCTION(rcnt0_read_count_m1):
 598         /* r0 = address, r2 = cycles */
 599         ldr     r3, [fp, #LO_rcnts+6*4+7*4*0] @ cycleStart
 600         mov_16  r1, 0x3334
 601         sub     r2, r2, r3
 602         mul     r0, r1, r2              @ /= 5
 603         lsr     r0, #16
 604         bx      lr
 605
 606 FUNCTION(rcnt1_read_count_m1):
 607         /* r0 = address, r2 = cycles */
 608         ldr     r3, [fp, #LO_rcnts+6*4+7*4*1]
 609         mov_24  r1, 0x1e6cde
 610         sub     r2, r2, r3
 611         umull   r3, r0, r1, r2          @ ~ /= hsync_cycles, max ~0x1e6cdd
 612         bx      lr
 613
 614 FUNCTION(rcnt2_read_count_m1):
 615         /* r0 = address, r2 = cycles */
 616         ldr     r3, [fp, #LO_rcnts+6*4+7*4*2]
 617         mov     r0, r2, lsl #16-3
 618         sub     r0, r0, r3, lsl #16-3
 619         lsr     r0, #16                 @ /= 8
 620         bx      lr
 621
 622 FUNCTION(call_gteStall):
 623         /* r0 = op_cycles, r1 = cycles */
 624         ldr     r2, [fp, #LO_last_count]
 625         str     lr, [fp, #LO_saved_lr]
 626         add     r1, r1, r2
 627         str     r1, [fp, #LO_cycle]
 628         add     r1, fp, #LO_psxRegs
 629         bl      gteCheckStallRaw
 630         ldr     lr, [fp, #LO_saved_lr]
 631         add     r10, r10, r0
 632         bx      lr
 633
 634 #ifdef HAVE_ARMV6
 635
 636 FUNCTION(get_reg):
 637         ldr     r12, [r0]
 638         and     r1, r1, #0xff
 639         ldr     r2, [r0, #4]
 640         orr     r1, r1, r1, lsl #8
 641         ldr     r3, [r0, #8]
 642         orr     r1, r1, r1, lsl #16   @ searched char in every byte
 643         ldrb    r0, [r0, #12]         @ last byte
 644         eor     r12, r12, r1
 645         eor     r2, r2, r1
 646         eor     r3, r3, r1
 647         cmp     r0, r1, lsr #24
 648         mov     r0, #12
 649         mvn     r1, #0                @ r1=~0
 650         bxeq    lr
 651         orr     r3, r3, #0xff000000   @ EXCLUDE_REG
 652         uadd8   r0, r12, r1           @ add and set GE bits when not 0 (match)
 653         mov     r12, #0
 654         sel     r0, r12, r1           @ 0 if no match, else ff in some byte
 655         uadd8   r2, r2, r1
 656         sel     r2, r12, r1
 657         uadd8   r3, r3, r1
 658         sel     r3, r12, r1
 659         mov     r12, #3
 660         clz     r0, r0                @ 0, 8, 16, 24 or 32
 661         clz     r2, r2
 662         clz     r3, r3
 663         sub     r0, r12, r0, lsr #3   @ 3, 2, 1, 0 or -1
 664         sub     r2, r12, r2, lsr #3
 665         sub     r3, r12, r3, lsr #3
 666         orr     r2, r2, #4
 667         orr     r3, r3, #8
 668         and     r0, r0, r2
 669         and     r0, r0, r3
 670         bx      lr
 671
 672 #endif /* HAVE_ARMV6 */
 673
 674 @ vim:filetype=armasm