libpcsxcore/new_dynarec/linkage_arm.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas                     *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "linkage_offsets.h"
  25
  26
  27 #ifdef __MACH__
  28 #define dynarec_local           ESYM(dynarec_local)
  29 #define ndrc_add_jump_out       ESYM(ndrc_add_jump_out)
  30 #define ndrc_try_restore_block  ESYM(ndrc_try_restore_block)
  31 #define ndrc_get_addr_ht        ESYM(ndrc_get_addr_ht)
  32 #define ndrc_get_addr_ht_param  ESYM(ndrc_get_addr_ht_param)
  33 #define ndrc_write_invalidate_one ESYM(ndrc_write_invalidate_one)
  34 #define gen_interupt            ESYM(gen_interupt)
  35 #define gteCheckStallRaw        ESYM(gteCheckStallRaw)
  36 #define psxException            ESYM(psxException)
  37 #endif
  38
  39         .bss
  40         .align  4
  41         .global dynarec_local
  42         .type   dynarec_local, %object
  43         .size   dynarec_local, LO_dynarec_local_size
  44 dynarec_local:
  45         .space  LO_dynarec_local_size
  46
  47 #define DRC_VAR_(name, vname, size_) \
  48         vname = dynarec_local + LO_##name; \
  49         .global vname; \
  50         .type   vname, %object; \
  51         .size   vname, size_
  52
  53 #define DRC_VAR(name, size_) \
  54         DRC_VAR_(name, ESYM(name), size_)
  55
  56 DRC_VAR(next_interupt, 4)
  57 DRC_VAR(cycle_count, 4)
  58 DRC_VAR(last_count, 4)
  59 DRC_VAR(pending_exception, 4)
  60 DRC_VAR(stop, 4)
  61 DRC_VAR(branch_target, 4)
  62 DRC_VAR(address, 4)
  63 DRC_VAR(hack_addr, 4)
  64 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  65
  66 /* psxRegs */
  67 @DRC_VAR(reg, 128)
  68 DRC_VAR(lo, 4)
  69 DRC_VAR(hi, 4)
  70 DRC_VAR(reg_cop0, 128)
  71 DRC_VAR(reg_cop2d, 128)
  72 DRC_VAR(reg_cop2c, 128)
  73 DRC_VAR(pcaddr, 4)
  74 @DRC_VAR(code, 4)
  75 @DRC_VAR(cycle, 4)
  76 @DRC_VAR(interrupt, 4)
  77 @DRC_VAR(intCycle, 256)
  78
  79 DRC_VAR(rcnts, 7*4*4)
  80 DRC_VAR(inv_code_start, 4)
  81 DRC_VAR(inv_code_end, 4)
  82 DRC_VAR(mem_rtab, 4)
  83 DRC_VAR(mem_wtab, 4)
  84 DRC_VAR(psxH_ptr, 4)
  85 DRC_VAR(zeromem_ptr, 4)
  86 DRC_VAR(invc_ptr, 4)
  87 DRC_VAR(scratch_buf_ptr, 4)
  88 DRC_VAR(ram_offset, 4)
  89 DRC_VAR(mini_ht, 256)
  90
  91
  92         .syntax unified
  93         .text
  94         .align  2
  95
  96 #ifndef HAVE_ARMV5
  97 .macro blx rd
  98         mov     lr, pc
  99         bx      \rd
 100 .endm
 101 #endif
 102
 103 .macro load_varadr reg var
 104 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 105         movw    \reg, #:lower16:(\var-(1678f+8))
 106         movt    \reg, #:upper16:(\var-(1678f+8))
 107 1678:
 108         add     \reg, pc
 109 #elif defined(HAVE_ARMV7) && !defined(__PIC__)
 110         movw    \reg, #:lower16:\var
 111         movt    \reg, #:upper16:\var
 112 #else
 113         ldr     \reg, =\var
 114 #endif
 115 .endm
 116
 117 .macro load_varadr_ext reg var
 118 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 119         movw    \reg, #:lower16:(ptr_\var-(1678f+8))
 120         movt    \reg, #:upper16:(ptr_\var-(1678f+8))
 121 1678:
 122         ldr     \reg, [pc, \reg]
 123 #else
 124         load_varadr \reg \var
 125 #endif
 126 .endm
 127
 128 .macro mov_16 reg imm
 129 #ifdef HAVE_ARMV7
 130         movw    \reg, #\imm
 131 #else
 132         mov     \reg, #(\imm & 0x00ff)
 133         orr     \reg, #(\imm & 0xff00)
 134 #endif
 135 .endm
 136
 137 .macro mov_24 reg imm
 138 #ifdef HAVE_ARMV7
 139         movw    \reg, #(\imm & 0xffff)
 140         movt    \reg, #(\imm >> 16)
 141 #else
 142         mov     \reg, #(\imm & 0x0000ff)
 143         orr     \reg, #(\imm & 0x00ff00)
 144         orr     \reg, #(\imm & 0xff0000)
 145 #endif
 146 .endm
 147
 148 FUNCTION(dyna_linker):
 149         /* r0 = virtual target address */
 150         /* r1 = pointer to an instruction to patch */
 151 #ifndef NO_WRITE_EXEC
 152         ldr     r7, [r1]
 153         mov     r4, r0
 154         add     r6, r7, #2
 155         mov     r5, r1
 156         lsl     r6, r6, #8
 157         /* must not compile - that might expire the caller block */
 158         mov     r1, #0
 159         bl      ndrc_get_addr_ht_param
 160
 161         movs    r8, r0
 162         beq     0f
 163         add     r6, r5, r6, asr #6  /* old target */
 164         teq     r0, r6
 165         moveq   pc, r0 /* Stale i-cache */
 166         mov     r0, r4
 167         mov     r1, r6
 168         bl      ndrc_add_jump_out
 169
 170         sub     r2, r8, r5
 171         and     r1, r7, #0xff000000
 172         lsl     r2, r2, #6
 173         sub     r1, r1, #2
 174         add     r1, r1, r2, lsr #8
 175         str     r1, [r5]
 176         mov     pc, r8
 177 0:
 178         mov     r0, r4
 179 #else
 180         /* XXX: should be able to do better than this... */
 181 #endif
 182         bl      ndrc_get_addr_ht
 183         mov     pc, r0
 184         .size   dyna_linker, .-dyna_linker
 185
 186         .align  2
 187 FUNCTION(jump_vaddr_r1):
 188         mov     r0, r1
 189         b       jump_vaddr_r0
 190         .size   jump_vaddr_r1, .-jump_vaddr_r1
 191 FUNCTION(jump_vaddr_r2):
 192         mov     r0, r2
 193         b       jump_vaddr_r0
 194         .size   jump_vaddr_r2, .-jump_vaddr_r2
 195 FUNCTION(jump_vaddr_r3):
 196         mov     r0, r3
 197         b       jump_vaddr_r0
 198         .size   jump_vaddr_r3, .-jump_vaddr_r3
 199 FUNCTION(jump_vaddr_r4):
 200         mov     r0, r4
 201         b       jump_vaddr_r0
 202         .size   jump_vaddr_r4, .-jump_vaddr_r4
 203 FUNCTION(jump_vaddr_r5):
 204         mov     r0, r5
 205         b       jump_vaddr_r0
 206         .size   jump_vaddr_r5, .-jump_vaddr_r5
 207 FUNCTION(jump_vaddr_r6):
 208         mov     r0, r6
 209         b       jump_vaddr_r0
 210         .size   jump_vaddr_r6, .-jump_vaddr_r6
 211 FUNCTION(jump_vaddr_r8):
 212         mov     r0, r8
 213         b       jump_vaddr_r0
 214         .size   jump_vaddr_r8, .-jump_vaddr_r8
 215 FUNCTION(jump_vaddr_r9):
 216         mov     r0, r9
 217         b       jump_vaddr_r0
 218         .size   jump_vaddr_r9, .-jump_vaddr_r9
 219 FUNCTION(jump_vaddr_r10):
 220         mov     r0, r10
 221         b       jump_vaddr_r0
 222         .size   jump_vaddr_r10, .-jump_vaddr_r10
 223 FUNCTION(jump_vaddr_r12):
 224         mov     r0, r12
 225         b       jump_vaddr_r0
 226         .size   jump_vaddr_r12, .-jump_vaddr_r12
 227 FUNCTION(jump_vaddr_r7):
 228         add     r0, r7, #0
 229         .size   jump_vaddr_r7, .-jump_vaddr_r7
 230 FUNCTION(jump_vaddr_r0):
 231         bl      ndrc_get_addr_ht
 232         mov     pc, r0
 233         .size   jump_vaddr_r0, .-jump_vaddr_r0
 234
 235         .align  2
 236 FUNCTION(cc_interrupt):
 237         ldr     r0, [fp, #LO_last_count]
 238         mov     r1, #0
 239         add     r10, r0, r10
 240         str     r1, [fp, #LO_pending_exception]
 241         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 242 @@      str     r10, [fp, #LO_reg_cop0+36]      /* Count - not on PSX */
 243         mov     r10, lr
 244
 245         add     r0, fp, #(LO_psxRegs + 34*4)    /* CP0 */
 246         bl      gen_interupt
 247         mov     lr, r10
 248         ldr     r10, [fp, #LO_cycle]
 249         ldr     r0, [fp, #LO_next_interupt]
 250         ldr     r1, [fp, #LO_pending_exception]
 251         ldr     r2, [fp, #LO_stop]
 252         str     r0, [fp, #LO_last_count]
 253         sub     r10, r10, r0
 254         tst     r2, r2
 255         ldmfdne sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 256         tst     r1, r1
 257         moveq   pc, lr
 258         ldr     r0, [fp, #LO_pcaddr]
 259         bl      ndrc_get_addr_ht
 260         mov     pc, r0
 261         .size   cc_interrupt, .-cc_interrupt
 262
 263         .align  2
 264 FUNCTION(fp_exception):
 265         mov     r2, #0x10000000
 266 .E7:
 267         ldr     r1, [fp, #LO_reg_cop0+48] /* Status */
 268         mov     r3, #0x80000000
 269         str     r0, [fp, #LO_reg_cop0+56] /* EPC */
 270         orr     r1, #2
 271         add     r2, r2, #0x2c
 272         str     r1, [fp, #LO_reg_cop0+48] /* Status */
 273         str     r2, [fp, #LO_reg_cop0+52] /* Cause */
 274         add     r0, r3, #0x80
 275         bl      ndrc_get_addr_ht
 276         mov     pc, r0
 277         .size   fp_exception, .-fp_exception
 278         .align  2
 279 FUNCTION(fp_exception_ds):
 280         mov     r2, #0x90000000 /* Set high bit if delay slot */
 281         b       .E7
 282         .size   fp_exception_ds, .-fp_exception_ds
 283
 284         .align  2
 285 FUNCTION(jump_break_ds):
 286         mov     r0, #0x24
 287         mov     r1, #1
 288         b       call_psxException
 289 FUNCTION(jump_break):
 290         mov     r0, #0x24
 291         mov     r1, #0
 292         b       call_psxException
 293 FUNCTION(jump_syscall_ds):
 294         mov     r0, #0x20
 295         mov     r1, #2
 296         b       call_psxException
 297 FUNCTION(jump_syscall):
 298         mov     r0, #0x20
 299         mov     r1, #0
 300
 301 call_psxException:
 302         ldr     r3, [fp, #LO_last_count]
 303         str     r2, [fp, #LO_pcaddr]
 304         add     r10, r3, r10
 305         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 306         add     r2, fp, #(LO_psxRegs + 34*4)    /* CP0 */
 307         bl      psxException
 308
 309         /* note: psxException might do recursive recompiler call from it's HLE code,
 310          * so be ready for this */
 311 FUNCTION(jump_to_new_pc):
 312         ldr     r1, [fp, #LO_next_interupt]
 313         ldr     r10, [fp, #LO_cycle]
 314         ldr     r0, [fp, #LO_pcaddr]
 315         sub     r10, r10, r1
 316         str     r1, [fp, #LO_last_count]
 317         bl      ndrc_get_addr_ht
 318         mov     pc, r0
 319         .size   jump_to_new_pc, .-jump_to_new_pc
 320
 321         .align  2
 322 FUNCTION(new_dyna_leave):
 323         ldr     r0, [fp, #LO_last_count]
 324         add     r12, fp, #28
 325         add     r10, r0, r10
 326         str     r10, [fp, #LO_cycle]
 327         ldmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 328         .size   new_dyna_leave, .-new_dyna_leave
 329
 330         .align  2
 331 FUNCTION(invalidate_addr_r0):
 332         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 333         b       invalidate_addr_call
 334         .size   invalidate_addr_r0, .-invalidate_addr_r0
 335         .align  2
 336 FUNCTION(invalidate_addr_r1):
 337         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 338         mov     r0, r1
 339         b       invalidate_addr_call
 340         .size   invalidate_addr_r1, .-invalidate_addr_r1
 341         .align  2
 342 FUNCTION(invalidate_addr_r2):
 343         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 344         mov     r0, r2
 345         b       invalidate_addr_call
 346         .size   invalidate_addr_r2, .-invalidate_addr_r2
 347         .align  2
 348 FUNCTION(invalidate_addr_r3):
 349         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 350         mov     r0, r3
 351         b       invalidate_addr_call
 352         .size   invalidate_addr_r3, .-invalidate_addr_r3
 353         .align  2
 354 FUNCTION(invalidate_addr_r4):
 355         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 356         mov     r0, r4
 357         b       invalidate_addr_call
 358         .size   invalidate_addr_r4, .-invalidate_addr_r4
 359         .align  2
 360 FUNCTION(invalidate_addr_r5):
 361         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 362         mov     r0, r5
 363         b       invalidate_addr_call
 364         .size   invalidate_addr_r5, .-invalidate_addr_r5
 365         .align  2
 366 FUNCTION(invalidate_addr_r6):
 367         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 368         mov     r0, r6
 369         b       invalidate_addr_call
 370         .size   invalidate_addr_r6, .-invalidate_addr_r6
 371         .align  2
 372 FUNCTION(invalidate_addr_r7):
 373         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 374         mov     r0, r7
 375         b       invalidate_addr_call
 376         .size   invalidate_addr_r7, .-invalidate_addr_r7
 377         .align  2
 378 FUNCTION(invalidate_addr_r8):
 379         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 380         mov     r0, r8
 381         b       invalidate_addr_call
 382         .size   invalidate_addr_r8, .-invalidate_addr_r8
 383         .align  2
 384 FUNCTION(invalidate_addr_r9):
 385         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 386         mov     r0, r9
 387         b       invalidate_addr_call
 388         .size   invalidate_addr_r9, .-invalidate_addr_r9
 389         .align  2
 390 FUNCTION(invalidate_addr_r10):
 391         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 392         mov     r0, r10
 393         b       invalidate_addr_call
 394         .size   invalidate_addr_r10, .-invalidate_addr_r10
 395         .align  2
 396 FUNCTION(invalidate_addr_r12):
 397         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 398         mov     r0, r12
 399         .size   invalidate_addr_r12, .-invalidate_addr_r12
 400         .align  2
 401 invalidate_addr_call:
 402         ldr     r12, [fp, #LO_inv_code_start]
 403         ldr     lr, [fp, #LO_inv_code_end]
 404         cmp     r0, r12
 405         cmpcs   lr, r0
 406         blcc    ndrc_write_invalidate_one
 407         ldmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
 408         .size   invalidate_addr_call, .-invalidate_addr_call
 409
 410         .align  2
 411 FUNCTION(new_dyna_start):
 412         /* ip is stored to conform EABI alignment */
 413         stmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
 414         mov     fp, r0 /* dynarec_local */
 415         ldr     r0, [fp, #LO_pcaddr]
 416         bl      ndrc_get_addr_ht
 417         ldr     r1, [fp, #LO_next_interupt]
 418         ldr     r10, [fp, #LO_cycle]
 419         str     r1, [fp, #LO_last_count]
 420         sub     r10, r10, r1
 421         mov     pc, r0
 422         .size   new_dyna_start, .-new_dyna_start
 423
 424 /* --------------------------------------- */
 425
 426 .align  2
 427
 428 .macro pcsx_read_mem readop tab_shift
 429         /* r0 = address, r1 = handler_tab, r2 = cycles */
 430         lsl     r3, r0, #20
 431         lsr     r3, #(20+\tab_shift)
 432         ldr     r12, [fp, #LO_last_count]
 433         ldr     r1, [r1, r3, lsl #2]
 434         add     r2, r2, r12
 435         lsls    r1, #1
 436 .if \tab_shift == 1
 437         lsl     r3, #1
 438         \readop r0, [r1, r3]
 439 .else
 440         \readop r0, [r1, r3, lsl #\tab_shift]
 441 .endif
 442         movcc   pc, lr
 443         str     r2, [fp, #LO_cycle]
 444         bx      r1
 445 .endm
 446
 447 FUNCTION(jump_handler_read8):
 448         add     r1, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 449         pcsx_read_mem ldrbcc, 0
 450
 451 FUNCTION(jump_handler_read16):
 452         add     r1, #0x1000/4*4              @ shift to r16 part
 453         pcsx_read_mem ldrhcc, 1
 454
 455 FUNCTION(jump_handler_read32):
 456         pcsx_read_mem ldrcc, 2
 457
 458
 459 .macro memhandler_post
 460         ldr     r0, [fp, #LO_next_interupt]
 461         ldr     r2, [fp, #LO_cycle]        @ memhandlers can modify cc, like dma
 462         str     r0, [fp, #LO_last_count]
 463         sub     r0, r2, r0
 464 .endm
 465
 466 .macro pcsx_write_mem wrtop tab_shift
 467         /* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
 468         lsl     r12,r0, #20
 469         lsr     r12, #(20+\tab_shift)
 470         ldr     r3, [r3, r12, lsl #2]
 471         str     r0, [fp, #LO_address]      @ some handlers still need it..
 472         lsls    r3, #1
 473         mov     r0, r2                     @ cycle return in case of direct store
 474 .if \tab_shift == 1
 475         lsl     r12, #1
 476         \wrtop  r1, [r3, r12]
 477 .else
 478         \wrtop  r1, [r3, r12, lsl #\tab_shift]
 479 .endif
 480         movcc   pc, lr
 481         ldr     r12, [fp, #LO_last_count]
 482         mov     r0, r1
 483         add     r2, r2, r12
 484         str     r2, [fp, #LO_cycle]
 485
 486         str     lr, [fp, #LO_saved_lr]
 487         blx     r3
 488         ldr     lr, [fp, #LO_saved_lr]
 489
 490         memhandler_post
 491         bx      lr
 492 .endm
 493
 494 FUNCTION(jump_handler_write8):
 495         add     r3, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 496         pcsx_write_mem strbcc, 0
 497
 498 FUNCTION(jump_handler_write16):
 499         add     r3, #0x1000/4*4              @ shift to r16 part
 500         pcsx_write_mem strhcc, 1
 501
 502 FUNCTION(jump_handler_write32):
 503         pcsx_write_mem strcc, 2
 504
 505 FUNCTION(jump_handler_write_h):
 506         /* r0 = address, r1 = data, r2 = cycles, r3 = handler */
 507         ldr     r12, [fp, #LO_last_count]
 508         str     r0, [fp, #LO_address]      @ some handlers still need it..
 509         add     r2, r2, r12
 510         mov     r0, r1
 511         str     r2, [fp, #LO_cycle]
 512
 513         str     lr, [fp, #LO_saved_lr]
 514         blx     r3
 515         ldr     lr, [fp, #LO_saved_lr]
 516
 517         memhandler_post
 518         bx      lr
 519
 520 FUNCTION(jump_handle_swl):
 521         /* r0 = address, r1 = data, r2 = cycles */
 522         ldr     r3, [fp, #LO_mem_wtab]
 523         mov     r12,r0,lsr #12
 524         ldr     r3, [r3, r12, lsl #2]
 525         lsls    r3, #1
 526         bcs     4f
 527         add     r3, r0, r3
 528         mov     r0, r2
 529         tst     r3, #2
 530         beq     101f
 531         tst     r3, #1
 532         beq     2f
 533 3:
 534         str     r1, [r3, #-3]
 535         bx      lr
 536 2:
 537         lsr     r2, r1, #8
 538         lsr     r1, #24
 539         strh    r2, [r3, #-2]
 540         strb    r1, [r3]
 541         bx      lr
 542 101:
 543         tst     r3, #1
 544         lsrne   r1, #16         @ 1
 545         lsreq   r12, r1, #24    @ 0
 546         strhne  r1, [r3, #-1]
 547         strbeq  r12, [r3]
 548         bx      lr
 549 4:
 550         mov     r0, r2
 551 @       b       abort
 552         bx      lr              @ TODO?
 553
 554
 555 FUNCTION(jump_handle_swr):
 556         /* r0 = address, r1 = data, r2 = cycles */
 557         ldr     r3, [fp, #LO_mem_wtab]
 558         mov     r12,r0,lsr #12
 559         ldr     r3, [r3, r12, lsl #2]
 560         lsls    r3, #1
 561         bcs     4f
 562         add     r3, r0, r3
 563         and     r12,r3, #3
 564         mov     r0, r2
 565         cmp     r12,#2
 566         strbgt  r1, [r3]        @ 3
 567         strheq  r1, [r3]        @ 2
 568         cmp     r12,#1
 569         strlt   r1, [r3]        @ 0
 570         bxne    lr
 571         lsr     r2, r1, #8      @ 1
 572         strb    r1, [r3]
 573         strh    r2, [r3, #1]
 574         bx      lr
 575 4:
 576         mov     r0, r2
 577 @       b       abort
 578         bx      lr              @ TODO?
 579
 580
 581 .macro rcntx_read_mode0 num
 582         /* r0 = address, r2 = cycles */
 583         ldr     r3, [fp, #LO_rcnts+6*4+7*4*\num] @ cycleStart
 584         mov     r0, r2, lsl #16
 585         sub     r0, r0, r3, lsl #16
 586         lsr     r0, #16
 587         bx      lr
 588 .endm
 589
 590 FUNCTION(rcnt0_read_count_m0):
 591         rcntx_read_mode0 0
 592
 593 FUNCTION(rcnt1_read_count_m0):
 594         rcntx_read_mode0 1
 595
 596 FUNCTION(rcnt2_read_count_m0):
 597         rcntx_read_mode0 2
 598
 599 FUNCTION(rcnt0_read_count_m1):
 600         /* r0 = address, r2 = cycles */
 601         ldr     r3, [fp, #LO_rcnts+6*4+7*4*0] @ cycleStart
 602         mov_16  r1, 0x3334
 603         sub     r2, r2, r3
 604         mul     r0, r1, r2              @ /= 5
 605         lsr     r0, #16
 606         bx      lr
 607
 608 FUNCTION(rcnt1_read_count_m1):
 609         /* r0 = address, r2 = cycles */
 610         ldr     r3, [fp, #LO_rcnts+6*4+7*4*1]
 611         mov_24  r1, 0x1e6cde
 612         sub     r2, r2, r3
 613         umull   r3, r0, r1, r2          @ ~ /= hsync_cycles, max ~0x1e6cdd
 614         bx      lr
 615
 616 FUNCTION(rcnt2_read_count_m1):
 617         /* r0 = address, r2 = cycles */
 618         ldr     r3, [fp, #LO_rcnts+6*4+7*4*2]
 619         mov     r0, r2, lsl #16-3
 620         sub     r0, r0, r3, lsl #16-3
 621         lsr     r0, #16                 @ /= 8
 622         bx      lr
 623
 624 FUNCTION(call_gteStall):
 625         /* r0 = op_cycles, r1 = cycles */
 626         ldr     r2, [fp, #LO_last_count]
 627         str     lr, [fp, #LO_saved_lr]
 628         add     r1, r1, r2
 629         str     r1, [fp, #LO_cycle]
 630         add     r1, fp, #LO_psxRegs
 631         bl      gteCheckStallRaw
 632         ldr     lr, [fp, #LO_saved_lr]
 633         add     r10, r10, r0
 634         bx      lr
 635
 636 #ifdef HAVE_ARMV6
 637
 638 FUNCTION(get_reg):
 639         ldr     r12, [r0]
 640         and     r1, r1, #0xff
 641         ldr     r2, [r0, #4]
 642         orr     r1, r1, r1, lsl #8
 643         ldr     r3, [r0, #8]
 644         orr     r1, r1, r1, lsl #16   @ searched char in every byte
 645         ldrb    r0, [r0, #12]         @ last byte
 646         eor     r12, r12, r1
 647         eor     r2, r2, r1
 648         eor     r3, r3, r1
 649         cmp     r0, r1, lsr #24
 650         mov     r0, #12
 651         mvn     r1, #0                @ r1=~0
 652         bxeq    lr
 653         orr     r3, r3, #0xff000000   @ EXCLUDE_REG
 654         uadd8   r0, r12, r1           @ add and set GE bits when not 0 (match)
 655         mov     r12, #0
 656         sel     r0, r12, r1           @ 0 if no match, else ff in some byte
 657         uadd8   r2, r2, r1
 658         sel     r2, r12, r1
 659         uadd8   r3, r3, r1
 660         sel     r3, r12, r1
 661         mov     r12, #3
 662         clz     r0, r0                @ 0, 8, 16, 24 or 32
 663         clz     r2, r2
 664         clz     r3, r3
 665         sub     r0, r12, r0, lsr #3   @ 3, 2, 1, 0 or -1
 666         sub     r2, r12, r2, lsr #3
 667         sub     r3, r12, r3, lsr #3
 668         orr     r2, r2, #4
 669         orr     r3, r3, #8
 670         and     r0, r0, r2
 671         and     r0, r0, r3
 672         bx      lr
 673
 674 #endif /* HAVE_ARMV6 */
 675
 676 @ vim:filetype=armasm