libpcsxcore/new_dynarec/linkage_arm64.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2021 notaz                                              *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "assem_arm64.h"
  25 #include "linkage_offsets.h"
  26
  27 #if (LO_mem_wtab & 7)
  28 #error misligned pointers
  29 #endif
  30
  31 .bss
  32         .align  4
  33         .global dynarec_local
  34         .type   dynarec_local, %object
  35         .size   dynarec_local, LO_dynarec_local_size
  36 dynarec_local:
  37         .space  LO_dynarec_local_size
  38
  39 #define DRC_VAR_(name, vname, size_) \
  40         vname = dynarec_local + LO_##name; \
  41         .global vname; \
  42         .type   vname, %object; \
  43         .size   vname, size_
  44
  45 #define DRC_VAR(name, size_) \
  46         DRC_VAR_(name, ESYM(name), size_)
  47
  48 DRC_VAR(next_interupt, 4)
  49 DRC_VAR(cycle_count, 4)
  50 DRC_VAR(last_count, 4)
  51 DRC_VAR(pending_exception, 4)
  52 DRC_VAR(stop, 4)
  53 DRC_VAR(branch_target, 4)
  54 DRC_VAR(address, 4)
  55 DRC_VAR(hack_addr, 4)
  56 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  57
  58 /* psxRegs */
  59 #DRC_VAR(reg, 128)
  60 DRC_VAR(lo, 4)
  61 DRC_VAR(hi, 4)
  62 DRC_VAR(reg_cop0, 128)
  63 DRC_VAR(reg_cop2d, 128)
  64 DRC_VAR(reg_cop2c, 128)
  65 DRC_VAR(pcaddr, 4)
  66 #DRC_VAR(code, 4)
  67 #DRC_VAR(cycle, 4)
  68 #DRC_VAR(interrupt, 4)
  69 #DRC_VAR(intCycle, 256)
  70
  71 DRC_VAR(rcnts, 7*4*4)
  72 DRC_VAR(inv_code_start, 4)
  73 DRC_VAR(inv_code_end, 4)
  74 DRC_VAR(mem_rtab, 8)
  75 DRC_VAR(mem_wtab, 8)
  76 DRC_VAR(psxH_ptr, 8)
  77 DRC_VAR(invc_ptr, 8)
  78 DRC_VAR(zeromem_ptr, 8)
  79 DRC_VAR(scratch_buf_ptr, 8)
  80 DRC_VAR(ram_offset, 8)
  81 DRC_VAR(mini_ht, 256)
  82
  83
  84         .text
  85         .align  2
  86
  87 FUNCTION(dyna_linker):
  88         /* r0 = virtual target address */
  89         /* r1 = instruction to patch */
  90         bl      ndrc_get_addr_ht
  91         br      x0
  92         .size   dyna_linker, .-dyna_linker
  93
  94         .align  2
  95 FUNCTION(cc_interrupt):
  96         ldr     w0, [rFP, #LO_last_count]
  97         add     rCC, w0, rCC
  98         str     wzr, [rFP, #LO_pending_exception]
  99         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 100         mov     x21, lr
 101 1:
 102         add     x0, rFP, #LO_reg_cop0           /* CP0 */
 103         bl      gen_interupt
 104         mov     lr, x21
 105         ldr     rCC, [rFP, #LO_cycle]
 106         ldr     w0, [rFP, #LO_next_interupt]
 107         ldr     w1, [rFP, #LO_pending_exception]
 108         ldr     w2, [rFP, #LO_stop]
 109         str     w0, [rFP, #LO_last_count]
 110         sub     rCC, rCC, w0
 111         cbnz    w2, new_dyna_leave
 112         cbnz    w1, 2f
 113         ret
 114 2:
 115         ldr     w0, [rFP, #LO_pcaddr]
 116         bl      ndrc_get_addr_ht
 117         br      x0
 118         .size   cc_interrupt, .-cc_interrupt
 119
 120         .align  2
 121 FUNCTION(jump_addrerror_ds): /* R3000E_AdEL / R3000E_AdES in w0 */
 122         str     w1, [rFP, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
 123         mov     w1, #1
 124         b       call_psxException
 125 FUNCTION(jump_addrerror):
 126         str     w1, [rFP, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
 127         mov     w1, #0
 128         b       call_psxException
 129 FUNCTION(jump_overflow_ds):
 130         mov     w0, #(12<<2)  /* R3000E_Ov */
 131         mov     w1, #1
 132         b       call_psxException
 133 FUNCTION(jump_overflow):
 134         mov     w0, #(12<<2)
 135         mov     w1, #0
 136         b       call_psxException
 137 FUNCTION(jump_break_ds):
 138         mov     w0, #(9<<2)  /* R3000E_Bp */
 139         mov     w1, #1
 140         b       call_psxException
 141 FUNCTION(jump_break):
 142         mov     w0, #(9<<2)
 143         mov     w1, #0
 144         b       call_psxException
 145 FUNCTION(jump_syscall_ds):
 146         mov     w0, #(8<<2)  /* R3000E_Syscall */
 147         mov     w1, #2
 148         b       call_psxException
 149 FUNCTION(jump_syscall):
 150         mov     w0, #(8<<2)
 151         mov     w1, #0
 152
 153 call_psxException:
 154         ldr     w3, [rFP, #LO_last_count]
 155         str     w2, [rFP, #LO_pcaddr]
 156         add     rCC, w3, rCC
 157         str     rCC, [rFP, #LO_cycle]           /* PCSX cycles */
 158         add     x2, rFP, #LO_reg_cop0           /* CP0 */
 159         bl      psxException
 160
 161         /* note: psxException might do recursive recompiler call from it's HLE code,
 162          * so be ready for this */
 163 FUNCTION(jump_to_new_pc):
 164         ldr     w1, [rFP, #LO_next_interupt]
 165         ldr     rCC, [rFP, #LO_cycle]
 166         ldr     w0, [rFP, #LO_pcaddr]
 167         sub     rCC, rCC, w1
 168         str     w1, [rFP, #LO_last_count]
 169         bl      ndrc_get_addr_ht
 170         br      x0
 171         .size   jump_to_new_pc, .-jump_to_new_pc
 172
 173         /* stack must be aligned by 16, and include space for save_regs() use */
 174         .align  2
 175 FUNCTION(new_dyna_start):
 176         stp     x29, x30, [sp, #-SSP_ALL]!
 177         ldr     w1,  [x0, #LO_next_interupt]
 178         ldr     w2,  [x0, #LO_cycle]
 179         stp     x19, x20, [sp, #16*1]
 180         stp     x21, x22, [sp, #16*2]
 181         stp     x23, x24, [sp, #16*3]
 182         stp     x25, x26, [sp, #16*4]
 183         stp     x27, x28, [sp, #16*5]
 184         mov     rFP, x0
 185         ldr     w0,  [rFP, #LO_pcaddr]
 186         str     w1,  [rFP, #LO_last_count]
 187         sub     rCC, w2, w1
 188         bl      ndrc_get_addr_ht
 189         br      x0
 190         .size   new_dyna_start, .-new_dyna_start
 191
 192         .align  2
 193 FUNCTION(new_dyna_leave):
 194         ldr     w0,  [rFP, #LO_last_count]
 195         add     rCC, rCC, w0
 196         str     rCC, [rFP, #LO_cycle]
 197         ldp     x19, x20, [sp, #16*1]
 198         ldp     x21, x22, [sp, #16*2]
 199         ldp     x23, x24, [sp, #16*3]
 200         ldp     x25, x26, [sp, #16*4]
 201         ldp     x27, x28, [sp, #16*5]
 202         ldp     x29, x30, [sp], #SSP_ALL
 203         ret
 204         .size   new_dyna_leave, .-new_dyna_leave
 205
 206 /* --------------------------------------- */
 207
 208 .align  2
 209
 210 .macro memhandler_pre
 211         /* w0 = adddr/data, x1 = rhandler, w2 = cycles, x3 = whandler */
 212         ldr     w4, [rFP, #LO_last_count]
 213         add     w4, w4, w2
 214         str     w4, [rFP, #LO_cycle]
 215 .endm
 216
 217 .macro memhandler_post
 218         ldr     w0, [rFP, #LO_next_interupt]
 219         ldr     w2, [rFP, #LO_cycle]        // memhandlers can modify cc, like dma
 220         str     w0, [rFP, #LO_last_count]
 221         sub     w0, w2, w0
 222 .endm
 223
 224 FUNCTION(do_memhandler_pre):
 225         memhandler_pre
 226         ret
 227
 228 FUNCTION(do_memhandler_post):
 229         memhandler_post
 230         ret
 231
 232 .macro pcsx_read_mem readop tab_shift
 233         /* w0 = address, x1 = handler_tab, w2 = cycles */
 234         ubfm    w4, w0, #\tab_shift, #11
 235         ldr     x3, [x1, w4, uxtw #3]
 236         adds    x3, x3, x3
 237         bcs     0f
 238         \readop w0, [x3, w4, uxtw #\tab_shift]
 239         ret
 240 0:
 241         stp     xzr, x30, [sp, #-16]!
 242         memhandler_pre
 243         blr     x3
 244 .endm
 245
 246 FUNCTION(jump_handler_read8):
 247         add     x1, x1, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 248         pcsx_read_mem ldrb, 0
 249         b       handler_read_end
 250
 251 FUNCTION(jump_handler_read16):
 252         add     x1, x1, #0x1000/4*8               /* shift to r16 part */
 253         pcsx_read_mem ldrh, 1
 254         b       handler_read_end
 255
 256 FUNCTION(jump_handler_read32):
 257         pcsx_read_mem ldr, 2
 258
 259 handler_read_end:
 260         ldp     xzr, x30, [sp], #16
 261         ret
 262
 263 .macro pcsx_write_mem wrtop movop tab_shift
 264         /* w0 = address, w1 = data, w2 = cycles, x3 = handler_tab */
 265         ubfm    w4, w0, #\tab_shift, #11
 266         ldr     x3, [x3, w4, uxtw #3]
 267         adds    x3, x3, x3
 268         bcs     0f
 269         mov     w0, w2                    /* cycle return */
 270         \wrtop  w1, [x3, w4, uxtw #\tab_shift]
 271         ret
 272 0:
 273         stp     xzr, x30, [sp, #-16]!
 274         str     w0, [rFP, #LO_address]    /* some handlers still need it... */
 275         \movop  w0, w1
 276         memhandler_pre
 277         blr     x3
 278 .endm
 279
 280 FUNCTION(jump_handler_write8):
 281         add     x3, x3, #0x1000/4*8 + 0x1000/2*8  /* shift to r8 part */
 282         pcsx_write_mem strb uxtb 0
 283         b       handler_write_end
 284
 285 FUNCTION(jump_handler_write16):
 286         add     x3, x3, #0x1000/4*8               /* shift to r16 part */
 287         pcsx_write_mem strh uxth 1
 288         b       handler_write_end
 289
 290 FUNCTION(jump_handler_write32):
 291         pcsx_write_mem str mov 2
 292
 293 handler_write_end:
 294         memhandler_post
 295         ldp     xzr, x30, [sp], #16
 296         ret
 297
 298 FUNCTION(jump_handle_swl):
 299         /* w0 = address, w1 = data, w2 = cycles */
 300         ldr     x3, [rFP, #LO_mem_wtab]
 301         orr     w4, wzr, w0, lsr #12
 302         ldr     x3, [x3, w4, uxtw #3]
 303         adds    x3, x3, x3
 304         bcs     jump_handle_swx_interp
 305         add     x3, x0, x3
 306         mov     w0, w2
 307         tbz     x3, #1, 10f     // & 2
 308         tbz     x3, #0, 2f      // & 1
 309 3:
 310         stur    w1, [x3, #-3]
 311         ret
 312 2:
 313         lsr     w2, w1, #8
 314         lsr     w1, w1, #24
 315         sturh   w2, [x3, #-2]
 316         strb    w1, [x3]
 317         ret
 318 10:
 319         tbz     x3, #0, 0f      // & 1
 320 1:
 321         lsr     w1, w1, #16
 322         sturh   w1, [x3, #-1]
 323         ret
 324 0:
 325         lsr     w2, w1, #24
 326         strb    w2, [x3]
 327         ret
 328
 329 FUNCTION(jump_handle_swr):
 330         /* w0 = address, w1 = data, w2 = cycles */
 331         ldr     x3, [rFP, #LO_mem_wtab]
 332         orr     w4, wzr, w0, lsr #12
 333         ldr     x3, [x3, w4, uxtw #3]
 334         adds    x3, x3, x3
 335         bcs     jump_handle_swx_interp
 336         add     x3, x0, x3
 337         mov     w0, w2
 338         tbz     x3, #1, 10f     // & 2
 339         tbz     x3, #0, 2f      // & 1
 340 3:
 341         strb    w1, [x3]
 342         ret
 343 2:
 344         strh    w1, [x3]
 345         ret
 346 10:
 347         tbz     x3, #0, 0f      // & 1
 348 1:
 349         lsr     w2, w1, #8
 350         strb    w1, [x3]
 351         sturh   w2, [x3, #1]
 352         ret
 353 0:
 354         str     w1, [x3]
 355         ret
 356
 357 jump_handle_swx_interp: /* almost never happens */
 358         ldr     w3, [rFP, #LO_last_count]
 359         add     x0, rFP, #LO_psxRegs
 360         add     w2, w3, w2
 361         str     w2, [rFP, #LO_cycle]           /* PCSX cycles */
 362         bl      execI
 363         b       jump_to_new_pc
 364
 365 FUNCTION(call_gteStall):
 366         /* w0 = op_cycles, w1 = cycles */
 367         ldr     w2, [rFP, #LO_last_count]
 368         str     lr, [rFP, #LO_saved_lr]
 369         add     w1, w1, w2
 370         str     w1, [rFP, #LO_cycle]
 371         add     x1, rFP, #LO_psxRegs
 372         bl      gteCheckStallRaw
 373         ldr     lr, [rFP, #LO_saved_lr]
 374         add     rCC, rCC, w0
 375         ret
 376