plugins/gpulib/cspace_neon.s

   1 /*
   2  * (C) Gražvydas "notaz" Ignotas, 2010
   3  *
   4  * This work is licensed under the terms of any of these licenses
   5  * (at your option):
   6  *  - GNU GPL, version 2 or later.
   7  *  - GNU LGPL, version 2.1 or later.
   8  * See the COPYING file in the top-level directory.
   9  */
  10
  11 .text
  12 .align 2
  13
  14 .global bgr555_to_rgb565
  15 bgr555_to_rgb565:
  16     pld         [r1]
  17     mov         r3, #0x07c0
  18     vdup.16     q15, r3
  19     subs        r2, r2, #64
  20     blt         btr16_end64
  21 0:
  22     pld         [r1, #64*2]
  23     vldmia      r1!, {q0-q3}
  24     vshl.u16    q4, q0, #11
  25     vshl.u16    q5, q1, #11
  26     vshl.u16    q6, q2, #11
  27     vshl.u16    q7, q3, #11
  28     vsri.u16    q4, q0, #10
  29     vsri.u16    q5, q1, #10
  30     vsri.u16    q6, q2, #10
  31     vsri.u16    q7, q3, #10
  32     vshl.u16    q0, q0, #1
  33     vshl.u16    q1, q1, #1
  34     vshl.u16    q2, q2, #1
  35     vshl.u16    q3, q3, #1
  36     vbit        q4, q0, q15
  37     vbit        q5, q1, q15
  38     vbit        q6, q2, q15
  39     vbit        q7, q3, q15
  40     vstmia      r0!, {q4-q7}
  41     subs        r2, r2, #64
  42     bge         0b
  43
  44 btr16_end64:
  45     adds        r2, r2, #64
  46     bxeq        lr
  47     subs        r2, r2, #16
  48     blt         btr16_end16
  49
  50     @ handle the remainder (reasonably rare)
  51 0:
  52     vld1.16     {q0}, [r1]!
  53     vshl.u16    q1, q0, #11
  54     vshl.u16    q2, q0, #1
  55     vsri.u16    q1, q0, #10
  56     vbit        q1, q2, q15
  57     subs        r2, r2, #16
  58     vst1.16     {q1}, [r0]!
  59     bge         0b
  60
  61 btr16_end16:
  62     adds        r2, r2, #16
  63     bxeq        lr
  64     subs        r2, r2, #8
  65     bxlt        lr
  66
  67     @ very rare
  68     vld1.16     d0, [r1]!
  69     vshl.u16    d1, d0, #11
  70     vshl.u16    d2, d0, #1
  71     vsri.u16    d1, d0, #10
  72     vbit        d1, d2, d30
  73     vst1.16     d1, [r0]!
  74     bx          lr
  75
  76
  77 .global bgr888_to_rgb888
  78 bgr888_to_rgb888:
  79     pld         [r1]
  80     @ r2 /= 48
  81     mov         r2, r2, lsr #4
  82     movw        r3, #0x5556
  83     movt        r3, #0x5555
  84     umull       r12,r2, r3, r2
  85 0:
  86     pld         [r1, #48*3]
  87     vld3.8      {d0-d2}, [r1, :64]!
  88     vld3.8      {d3-d5}, [r1, :64]!
  89     vswp        d0, d2
  90     vswp        d3, d5
  91     vst3.8      {d0-d2}, [r0, :64]!
  92     vst3.8      {d3-d5}, [r0, :64]!
  93     subs        r2, r2, #1
  94     bne         0b
  95
  96     bx          lr
  97
  98
  99 .global bgr888_to_rgb565
 100 bgr888_to_rgb565:
 101     pld         [r1]
 102     @ r2 /= 48
 103     mov         r2, r2, lsr #4
 104     movw        r3, #0x5556
 105     movt        r3, #0x5555
 106     umull       r12,r2, r3, r2
 107
 108     mov         r3, #0x07e0
 109     vdup.16     q15, r3
 110 0:
 111     pld         [r1, #48*3]
 112     vld3.8      {d1-d3}, [r1, :64]!
 113     vld3.8      {d5-d7}, [r1, :64]!
 114
 115     vshll.u8    q8, d2, #3      @ g
 116     vshll.u8    q9, d6, #3
 117     vshr.u8     d0, d3, #3      @ b
 118     vshr.u8     d4, d7, #3
 119     vzip.8      d0, d1          @ rb
 120     vzip.8      d4, d5
 121     vbit        q0, q8, q15
 122     vbit        q2, q9, q15
 123
 124     vstmia      r0!, {d0,d1}
 125     vstmia      r0!, {d4,d5}
 126     subs        r2, r2, #1
 127     bne         0b
 128
 129     bx          lr
 130
 131
 132 @ vim:filetype=armasm