Pico/Memory_amips.s

   1 # vim:filetype=mips
   2
   3 # memory handlers with banking support for SSF II - The New Challengers
   4 # mostly based on Gens code
   5
   6 # (c) Copyright 2007, Grazvydas "notaz" Ignotas
   7 # All Rights Reserved
   8
   9
  10 .set noreorder
  11 .set noat
  12
  13 .text
  14 .align 4
  15
  16 # default jump tables
  17
  18 m_read8_def_table:
  19     .long   m_read8_rom0    # 0x000000 - 0x07FFFF
  20     .long   m_read8_rom1    # 0x080000 - 0x0FFFFF
  21     .long   m_read8_rom2    # 0x100000 - 0x17FFFF
  22     .long   m_read8_rom3    # 0x180000 - 0x1FFFFF
  23     .long   m_read8_rom4    # 0x200000 - 0x27FFFF
  24     .long   m_read8_rom5    # 0x280000 - 0x2FFFFF
  25     .long   m_read8_rom6    # 0x300000 - 0x37FFFF
  26     .long   m_read8_rom7    # 0x380000 - 0x3FFFFF
  27     .long   m_read8_rom8    # 0x400000 - 0x47FFFF - for all those large ROM hacks
  28     .long   m_read8_rom9    # 0x480000 - 0x4FFFFF
  29     .long   m_read8_romA    # 0x500000 - 0x57FFFF
  30     .long   m_read8_romB    # 0x580000 - 0x5FFFFF
  31     .long   m_read8_romC    # 0x600000 - 0x67FFFF
  32     .long   m_read8_romD    # 0x680000 - 0x6FFFFF
  33     .long   m_read8_romE    # 0x700000 - 0x77FFFF
  34     .long   m_read8_romF    # 0x780000 - 0x7FFFFF
  35     .long   m_read8_rom10   # 0x800000 - 0x87FFFF
  36     .long   m_read8_rom11   # 0x880000 - 0x8FFFFF
  37     .long   m_read8_rom12   # 0x900000 - 0x97FFFF
  38     .long   m_read8_rom13   # 0x980000 - 0x9FFFFF
  39     .long   m_read8_misc    # 0xA00000 - 0xA7FFFF
  40     .long   m_read_null     # 0xA80000 - 0xAFFFFF
  41     .long   m_read_null     # 0xB00000 - 0xB7FFFF
  42     .long   m_read_null     # 0xB80000 - 0xBFFFFF
  43     .long   m_read8_vdp     # 0xC00000 - 0xC7FFFF
  44     .long   m_read8_vdp     # 0xC80000 - 0xCFFFFF
  45     .long   m_read8_vdp     # 0xD00000 - 0xD7FFFF
  46     .long   m_read8_vdp     # 0xD80000 - 0xDFFFFF
  47     .long   m_read8_ram     # 0xE00000 - 0xE7FFFF
  48     .long   m_read8_ram     # 0xE80000 - 0xEFFFFF
  49     .long   m_read8_ram     # 0xF00000 - 0xF7FFFF
  50     .long   m_read8_ram     # 0xF80000 - 0xFFFFFF
  51
  52 m_read16_def_table:
  53     .long   m_read16_rom0    # 0x000000 - 0x07FFFF
  54     .long   m_read16_rom1    # 0x080000 - 0x0FFFFF
  55     .long   m_read16_rom2    # 0x100000 - 0x17FFFF
  56     .long   m_read16_rom3    # 0x180000 - 0x1FFFFF
  57     .long   m_read16_rom4    # 0x200000 - 0x27FFFF
  58     .long   m_read16_rom5    # 0x280000 - 0x2FFFFF
  59     .long   m_read16_rom6    # 0x300000 - 0x37FFFF
  60     .long   m_read16_rom7    # 0x380000 - 0x3FFFFF
  61     .long   m_read16_rom8    # 0x400000 - 0x47FFFF
  62     .long   m_read16_rom9    # 0x480000 - 0x4FFFFF
  63     .long   m_read16_romA    # 0x500000 - 0x57FFFF
  64     .long   m_read16_romB    # 0x580000 - 0x5FFFFF
  65     .long   m_read16_romC    # 0x600000 - 0x67FFFF
  66     .long   m_read16_romD    # 0x680000 - 0x6FFFFF
  67     .long   m_read16_romE    # 0x700000 - 0x77FFFF
  68     .long   m_read16_romF    # 0x780000 - 0x7FFFFF
  69     .long   m_read16_rom10   # 0x800000 - 0x87FFFF
  70     .long   m_read16_rom11   # 0x880000 - 0x8FFFFF
  71     .long   m_read16_rom12   # 0x900000 - 0x97FFFF
  72     .long   m_read16_rom13   # 0x980000 - 0x9FFFFF
  73     .long   m_read16_misc    # 0xA00000 - 0xA7FFFF
  74     .long   m_read_null      # 0xA80000 - 0xAFFFFF
  75     .long   m_read_null      # 0xB00000 - 0xB7FFFF
  76     .long   m_read_null      # 0xB80000 - 0xBFFFFF
  77     .long   m_read16_vdp     # 0xC00000 - 0xC7FFFF
  78     .long   m_read16_vdp     # 0xC80000 - 0xCFFFFF
  79     .long   m_read16_vdp     # 0xD00000 - 0xD7FFFF
  80     .long   m_read16_vdp     # 0xD80000 - 0xDFFFFF
  81     .long   m_read16_ram     # 0xE00000 - 0xE7FFFF
  82     .long   m_read16_ram     # 0xE80000 - 0xEFFFFF
  83     .long   m_read16_ram     # 0xF00000 - 0xF7FFFF
  84     .long   m_read16_ram     # 0xF80000 - 0xFFFFFF
  85
  86 m_read32_def_table:
  87     .long   m_read32_rom0    # 0x000000 - 0x07FFFF
  88     .long   m_read32_rom1    # 0x080000 - 0x0FFFFF
  89     .long   m_read32_rom2    # 0x100000 - 0x17FFFF
  90     .long   m_read32_rom3    # 0x180000 - 0x1FFFFF
  91     .long   m_read32_rom4    # 0x200000 - 0x27FFFF
  92     .long   m_read32_rom5    # 0x280000 - 0x2FFFFF
  93     .long   m_read32_rom6    # 0x300000 - 0x37FFFF
  94     .long   m_read32_rom7    # 0x380000 - 0x3FFFFF
  95     .long   m_read32_rom8    # 0x400000 - 0x47FFFF
  96     .long   m_read32_rom9    # 0x480000 - 0x4FFFFF
  97     .long   m_read32_romA    # 0x500000 - 0x57FFFF
  98     .long   m_read32_romB    # 0x580000 - 0x5FFFFF
  99     .long   m_read32_romC    # 0x600000 - 0x67FFFF
 100     .long   m_read32_romD    # 0x680000 - 0x6FFFFF
 101     .long   m_read32_romE    # 0x700000 - 0x77FFFF
 102     .long   m_read32_romF    # 0x780000 - 0x7FFFFF
 103     .long   m_read32_rom10   # 0x800000 - 0x87FFFF
 104     .long   m_read32_rom11   # 0x880000 - 0x8FFFFF
 105     .long   m_read32_rom12   # 0x900000 - 0x97FFFF
 106     .long   m_read32_rom13   # 0x980000 - 0x9FFFFF
 107     .long   m_read32_misc    # 0xA00000 - 0xA7FFFF
 108     .long   m_read_null      # 0xA80000 - 0xAFFFFF
 109     .long   m_read_null      # 0xB00000 - 0xB7FFFF
 110     .long   m_read_null      # 0xB80000 - 0xBFFFFF
 111     .long   m_read32_vdp     # 0xC00000 - 0xC7FFFF
 112     .long   m_read32_vdp     # 0xC80000 - 0xCFFFFF
 113     .long   m_read32_vdp     # 0xD00000 - 0xD7FFFF
 114     .long   m_read32_vdp     # 0xD80000 - 0xDFFFFF
 115     .long   m_read32_ram     # 0xE00000 - 0xE7FFFF
 116     .long   m_read32_ram     # 0xE80000 - 0xEFFFFF
 117     .long   m_read32_ram     # 0xF00000 - 0xF7FFFF
 118     .long   m_read32_ram     # 0xF80000 - 0xFFFFFF
 119
 120
 121 # #############################################################################
 122
 123 .bss
 124 .align 4
 125
 126 # used tables
 127 m_read8_table:
 128     .skip 32*4
 129
 130 m_read16_table:
 131     .skip 32*4
 132
 133 m_read32_table:
 134     .skip 32*4
 135
 136
 137 # #############################################################################
 138
 139 .text
 140 .align 4
 141
 142 .global PicoMemReset
 143 .global PicoRead8
 144 .global PicoRead16
 145 .global PicoRead32
 146 .global PicoWriteRomHW_SSF2
 147
 148 .global m_read8_def_table
 149 .global m_read8_table
 150
 151 .macro PicoMemResetCopyDef dst_table src_table
 152     lui     $t0, %hi(\dst_table)
 153     addiu   $t0, %lo(\dst_table)
 154     lui     $t1, %hi(\src_table)
 155     addiu   $t1, %lo(\src_table)
 156     li      $t2, 32
 157 1:
 158     lw      $t3, 0($t1)
 159     sw      $t3, 0($t0)
 160     addiu   $t2, -1
 161     addiu   $t1, 4
 162     bnez    $t2, 1b
 163     addiu   $t0, 4
 164 .endm
 165
 166 # $t4 = 4
 167 .macro PicoMemResetRomArea dst_table ar_label
 168     lui     $t0, %hi(\dst_table)
 169     addiu   $t0, %lo(\dst_table)
 170     lui     $t1, %hi(\ar_label)
 171     addiu   $t1, %lo(\ar_label)
 172     li      $t2, 20
 173 1:
 174     beq     $t2, $v1, 2f
 175     addiu   $t2, -1
 176     sll     $t3, $t2, 2
 177     beq     $t2, $t4, 1b           # do not touch the SRAM area
 178     addu    $t3, $t0
 179     j       1b
 180     sw      $t1, 0($t3)
 181 2:
 182 .endm
 183
 184
 185 PicoMemReset:
 186     lui     $v1, %hi(Pico+0x22204)
 187     lw      $v1, %lo(Pico+0x22204)($v1)  # romsize
 188     lui     $t0, 8
 189     addu    $v1, $t0
 190     addiu   $v1, -1
 191     srl     $v1, 19
 192
 193     PicoMemResetCopyDef m_read8_table  m_read8_def_table
 194     PicoMemResetCopyDef m_read16_table m_read16_def_table
 195     PicoMemResetCopyDef m_read32_table m_read32_def_table
 196
 197     # update memhandlers according to ROM size
 198     li      $t4, 4
 199     PicoMemResetRomArea m_read8_table  m_read8_above_rom
 200     PicoMemResetRomArea m_read16_table m_read16_above_rom
 201     PicoMemResetRomArea m_read32_table m_read32_above_rom
 202
 203     jr      $ra
 204     nop
 205
 206 # #############################################################################
 207
 208 .macro PicoReadJump table
 209     lui     $t0, %hi(\table)
 210     srl     $t1, $a0, 19
 211     ins     $t0, $t1, 2, 5
 212     lw      $t0, %lo(\table)($t0)
 213     ins     $a0, $0,  24, 8
 214     jr      $t0
 215     nop
 216 .endm
 217
 218 PicoRead8: # u32 a
 219     PicoReadJump m_read8_table
 220
 221 PicoRead16: # u32 a
 222     PicoReadJump m_read16_table
 223
 224 PicoRead32: # u32 a
 225     PicoReadJump m_read32_table
 226
 227 # #############################################################################
 228
 229 m_read_null:
 230     jr      $ra
 231     li      $v0, 0
 232
 233 m_read_neg1:
 234     jr      $ra
 235     addiu   $v0, $0, 0xffff
 236
 237 # loads &Pico.rom to $t3
 238 .macro m_read_rom_try_sram is200000 size
 239     lui     $t2, %hi(SRam)
 240     addiu   $t2, %lo(SRam)
 241     lui     $t3, %hi(Pico+0x22200)
 242     lw      $t1, 8($t2)     # SRam.end
 243 .if \is200000
 244     ins     $a0, $0,  19, 13
 245     lui     $t4, 0x20
 246     or      $a0, $t4
 247 .endif
 248     subu    $t4, $a0, $t1
 249     bgtz    $t4, 1f
 250     addiu   $t3, %lo(Pico+0x22200)
 251     lw      $t1, 4($t2)     # SRam.start
 252     subu    $t4, $t1, $a0
 253     bgtz    $t4, 1f
 254     nop
 255     lb      $t1, 0x11($t3)  # Pico.m.sram_reg
 256     andi    $t4, $t1, 5
 257     beqz    $t4, 1f
 258     nop
 259 .if \size == 8
 260     j       SRAMRead
 261     nop
 262 .elseif \size == 16
 263     addiu   $sp, -4
 264     jal     SRAMRead
 265     sw      $ra, 0($sp)
 266     lw      $ra, 0($sp)
 267     addiu   $sp, 4
 268     jr      $ra
 269     ins     $v0, $v0, 8, 8
 270 .else
 271     addiu   $sp, -8
 272     sw      $a0, 4($sp)
 273     jal     SRAMRead
 274     sw      $ra, 0($sp)
 275     lw      $a0, 4($sp)
 276     sw      $v0, 4($sp)
 277     jal     SRAMRead
 278     addiu   $a0, 2
 279     lw      $v1, 4($sp)
 280     lw      $ra, 0($sp)
 281     addiu   $sp, 8
 282     ins     $v0, $v1, 16, 16
 283     sll     $t0, $v0, 8
 284     jr      $ra
 285     or      $v0, $t0
 286 .endif
 287 # m_read_nosram:
 288 1:
 289 .endm
 290
 291 .macro m_read8_rom sect
 292     lui     $t0, %hi(Pico+0x22200)
 293     lw      $t0, %lo(Pico+0x22200)($t0)  # rom
 294     xori    $a0, 1
 295     ins     $a0, $0,  19, 13
 296 .if \sect
 297     lui     $t1, 8*\sect
 298     addu    $a0, $t1
 299 .endif
 300     addu    $t0, $a0
 301     jr      $ra
 302     lb      $v0, 0($t0)
 303 .endm
 304
 305
 306 m_read8_rom0: # 0x000000 - 0x07ffff
 307     m_read8_rom 0
 308
 309 m_read8_rom1: # 0x080000 - 0x0fffff
 310     m_read8_rom 1
 311
 312 m_read8_rom2: # 0x100000 - 0x17ffff
 313     m_read8_rom 2
 314
 315 m_read8_rom3: # 0x180000 - 0x1fffff
 316     m_read8_rom 3
 317
 318 m_read8_rom4: # 0x200000 - 0x27ffff, SRAM area
 319     m_read_rom_try_sram 1 8
 320     lw      $t1, 4($t3)     # romsize
 321     subu    $t4, $t1, $a0
 322     blez    $t4, m_read_null
 323     lw      $t1, 0($t3)     # rom
 324     xori    $a0, 1
 325     addu    $t1, $a0
 326     jr      $ra
 327     lb      $v0, 0($t1)
 328
 329 m_read8_rom5: # 0x280000 - 0x2fffff
 330     m_read8_rom 5
 331
 332 m_read8_rom6: # 0x300000 - 0x37ffff
 333     m_read8_rom 6
 334
 335 m_read8_rom7: # 0x380000 - 0x3fffff
 336     m_read8_rom 7
 337
 338 m_read8_rom8: # 0x400000 - 0x47ffff
 339     m_read8_rom 8
 340
 341 m_read8_rom9: # 0x480000 - 0x4fffff
 342     m_read8_rom 9
 343
 344 m_read8_romA: # 0x500000 - 0x57ffff
 345     m_read8_rom 0xA
 346
 347 m_read8_romB: # 0x580000 - 0x5fffff
 348     m_read8_rom 0xB
 349
 350 m_read8_romC: # 0x600000 - 0x67ffff
 351     m_read8_rom 0xC
 352
 353 m_read8_romD: # 0x680000 - 0x6fffff
 354     m_read8_rom 0xD
 355
 356 m_read8_romE: # 0x700000 - 0x77ffff
 357     m_read8_rom 0xE
 358
 359 m_read8_romF: # 0x780000 - 0x7fffff
 360     m_read8_rom 0xF
 361
 362 m_read8_rom10: # 0x800000 - 0x87ffff
 363     m_read8_rom 0x10
 364
 365 m_read8_rom11: # 0x880000 - 0x8fffff
 366     m_read8_rom 0x11
 367
 368 m_read8_rom12: # 0x900000 - 0x97ffff
 369     m_read8_rom 0x12
 370
 371 m_read8_rom13: # 0x980000 - 0x9fffff
 372     m_read8_rom 0x13
 373
 374
 375 m_read8_misc:
 376     srl     $t0, $a0, 5
 377     sll     $t0, $t0, 5
 378     lui     $t1, 0xa1
 379     bne     $t0, $t1, m_read8_misc2
 380     andi    $t0, $a0, 0x1e
 381 m_read8_misc_io:
 382     beqz    $t0, m_read8_misc_hwreg
 383     sub     $t1, $t0, 4
 384     bgtz    $t1, m_read8_misc_ioports
 385     nop
 386     slti    $a0, $t0, 4
 387     xori    $a0, 1
 388     j       PadRead
 389     nop
 390
 391 m_read8_misc_hwreg:
 392     lui     $v0, %hi(Pico+0x2220f)
 393     jr      $ra
 394     lb      $v0, %lo(Pico+0x2220f)($v0)
 395
 396 m_read8_misc_ioports:
 397     lui     $v0, %hi(Pico+0x22000)
 398     ins     $v0, $t0, 0, 5
 399     jr      $ra
 400     lb      $v0, %lo(Pico+0x22000)($v0)
 401
 402 m_read8_misc2:
 403     lui     $t0, 0xa1
 404     ori     $t0, 0x1100
 405     bne     $a0, $t0, m_read8_misc3
 406     srl     $t0, $a0, 16
 407     j       z80ReadBusReq
 408
 409 m_read8_misc3:
 410     addiu   $t0, 0xff60       # expecting 0xa0 to get 0
 411     bnez    $t0, m_read8_misc4
 412
 413     # z80 area
 414     andi    $t0, $a0, 0x4000
 415     bnez    $t0, m_read8_z80_misc
 416     andi    $t0, $a0, 0x6000
 417     j       z80Read8          # z80 RAM
 418
 419 m_read8_z80_misc:
 420     addiu   $t0, 0xc000       # expecting 0x4000 to get 0
 421     bnez    $t0, m_read_neg1  # invalid
 422
 423     lui     $t0, %hi(PicoOpt)
 424     lw      $t0, %lo(PicoOpt)($t0)
 425     andi    $t0, 1
 426     beqz    $t0, m_read8_fake_ym2612
 427     lui     $t0, %hi(Pico+0x22208)
 428     j       YM2612Read_
 429     nop
 430
 431 m_read8_fake_ym2612:
 432     lb      $v0, %lo(Pico+0x22208)($t0) # Pico.m.rotate
 433     addiu   $t1, $v0, 1
 434     jr      $ra
 435     sb      $t1, %lo(Pico+0x22208)($t0)
 436
 437 # delay slot friendly
 438 .macro m_read8_call16 funcname
 439     andi    $t0, $a0, 1
 440     beqz    $t0, 1f
 441     li      $a1, 8      # not always needed, but shouln't cause problems
 442     j       \funcname   # odd address
 443     nop
 444 1:
 445     addiu   $sp, -4
 446     sw      $ra, 0($sp)
 447     jal     \funcname
 448     xori    $a0, 1
 449     lw      $ra, 0($sp)
 450     addiu   $sp, 4
 451     jr      $ra
 452     srl     $v0, 8
 453 .endm
 454
 455 m_read8_misc4:
 456     # if everything else fails, use generic handler
 457     m_read8_call16 OtherRead16
 458
 459 m_read8_vdp:
 460     ext     $t0, $a0, 16, 3
 461     andi    $t1, $a0, 0xe0
 462     or      $t0, $t1
 463     bnez    $t0, m_read_null # invalid address
 464     m_read8_call16 PicoVideoRead
 465
 466 m_read8_ram:
 467     lui     $t0, %hi(Pico)
 468     ins     $t0, $a0, 0, 16
 469     xori    $t0, 1
 470     jr      $ra
 471     lb      $v0, %lo(Pico)($t0)
 472
 473 m_read8_above_rom:
 474     # might still be SRam (Micro Machines, HardBall '95)
 475     m_read_rom_try_sram 0 8
 476     m_read8_call16 OtherRead16End
 477
 478 # #############################################################################
 479
 480 .macro m_read16_rom sect
 481     lui     $t0, %hi(Pico+0x22200)
 482     lw      $t0, %lo(Pico+0x22200)($t0)  # rom
 483     ins     $a0, $0,   0,  1
 484     ins     $a0, $0,  19, 13
 485 .if \sect
 486     lui     $t1, 8*\sect
 487     addu    $a0, $t1
 488 .endif
 489     addu    $t0, $a0
 490     jr      $ra
 491     lh      $v0, 0($t0)
 492 .endm
 493
 494
 495 m_read16_rom0: # 0x000000 - 0x07ffff
 496     m_read16_rom 0
 497
 498 m_read16_rom1: # 0x080000 - 0x0fffff
 499     m_read16_rom 1
 500
 501 m_read16_rom2: # 0x100000 - 0x17ffff
 502     m_read16_rom 2
 503
 504 m_read16_rom3: # 0x180000 - 0x1fffff
 505     m_read16_rom 3
 506
 507 m_read16_rom4: # 0x200000 - 0x27ffff, SRAM area
 508     m_read_rom_try_sram 1 16
 509     lw      $t1, 4($t3)     # romsize
 510     subu    $t4, $t1, $a0
 511     blez    $t4, m_read_null
 512     lw      $t1, 0($t3)     # rom
 513     ins     $a0, $0, 0, 1
 514     addu    $t1, $a0
 515     jr      $ra
 516     lh      $v0, 0($t1)
 517
 518 m_read16_rom5: # 0x280000 - 0x2fffff
 519     m_read16_rom 5
 520
 521 m_read16_rom6: # 0x300000 - 0x37ffff
 522     m_read16_rom 6
 523
 524 m_read16_rom7: # 0x380000 - 0x3fffff
 525     m_read16_rom 7
 526
 527 m_read16_rom8: # 0x400000 - 0x47ffff
 528     m_read16_rom 8
 529
 530 m_read16_rom9: # 0x480000 - 0x4fffff
 531     m_read16_rom 9
 532
 533 m_read16_romA: # 0x500000 - 0x57ffff
 534     m_read16_rom 0xA
 535
 536 m_read16_romB: # 0x580000 - 0x5fffff
 537     m_read16_rom 0xB
 538
 539 m_read16_romC: # 0x600000 - 0x67ffff
 540     m_read16_rom 0xC
 541
 542 m_read16_romD: # 0x680000 - 0x6fffff
 543     m_read16_rom 0xD
 544
 545 m_read16_romE: # 0x700000 - 0x77ffff
 546     m_read16_rom 0xE
 547
 548 m_read16_romF: # 0x780000 - 0x7fffff
 549     m_read16_rom 0xF
 550
 551 m_read16_rom10: # 0x800000 - 0x87ffff
 552     m_read16_rom 0x10
 553
 554 m_read16_rom11: # 0x880000 - 0x8fffff
 555     m_read16_rom 0x11
 556
 557 m_read16_rom12: # 0x900000 - 0x97ffff
 558     m_read16_rom 0x12
 559
 560 m_read16_rom13: # 0x980000 - 0x9fffff
 561     m_read16_rom 0x13
 562
 563 m_read16_misc:
 564     ins     $a0, $0, 0, 1
 565     j       OtherRead16
 566     li      $a1, 16
 567
 568 m_read16_vdp:
 569     ext     $t0, $a0, 16, 3
 570     andi    $t1, $a0, 0xe0
 571     or      $t0, $t1
 572     bnez    $t0, m_read_null # invalid address
 573     ins     $a0, $0, 0, 1
 574     j       PicoVideoRead
 575     nop
 576
 577 m_read16_ram:
 578     lui     $t0, %hi(Pico)
 579     ins     $a0, $0, 0, 1
 580     ins     $t0, $a0, 0, 16
 581     jr      $ra
 582     lh      $v0, %lo(Pico)($t0)
 583
 584 m_read16_above_rom:
 585     # might still be SRam
 586     m_read_rom_try_sram 0 16
 587     j       OtherRead16End
 588     ins     $a0, $0, 0, 1
 589
 590 # #############################################################################
 591
 592 .macro m_read32_rom sect
 593     lui     $t0, %hi(Pico+0x22200)
 594     lw      $t0, %lo(Pico+0x22200)($t0)  # rom
 595     ins     $a0, $0,   0,  1
 596     ins     $a0, $0,  19, 13
 597 .if \sect
 598     lui     $t1, 8*\sect
 599     addu    $a0, $t1
 600 .endif
 601     addu    $t0, $a0
 602     lh      $v1, 0($t0)
 603     lh      $v0, 2($t0)
 604     jr      $ra
 605     ins     $v0, $v1, 16, 16
 606 .endm
 607
 608
 609 m_read32_rom0: # 0x000000 - 0x07ffff
 610     m_read32_rom 0
 611
 612 m_read32_rom1: # 0x080000 - 0x0fffff
 613     m_read32_rom 1
 614
 615 m_read32_rom2: # 0x100000 - 0x17ffff
 616     m_read32_rom 2
 617
 618 m_read32_rom3: # 0x180000 - 0x1fffff
 619     m_read32_rom 3
 620
 621 m_read32_rom4: # 0x200000 - 0x27ffff, SRAM area
 622     m_read_rom_try_sram 1 32
 623     lw      $t1, 4($t3)     # romsize
 624     subu    $t4, $t1, $a0
 625     blez    $t4, m_read_null
 626     lw      $t1, 0($t3)     # rom
 627     ins     $a0, $0, 0, 1
 628     addu    $t1, $a0
 629     lh      $v1, 0($t1)
 630     lh      $v0, 2($t1)
 631     jr      $ra
 632     ins     $v0, $v1, 16, 16
 633
 634 m_read32_rom5: # 0x280000 - 0x2fffff
 635     m_read32_rom 5
 636
 637 m_read32_rom6: # 0x300000 - 0x37ffff
 638     m_read32_rom 6
 639
 640 m_read32_rom7: # 0x380000 - 0x3fffff
 641     m_read32_rom 7
 642
 643 m_read32_rom8: # 0x400000 - 0x47ffff
 644     m_read32_rom 8
 645
 646 m_read32_rom9: # 0x480000 - 0x4fffff
 647     m_read32_rom 9
 648
 649 m_read32_romA: # 0x500000 - 0x57ffff
 650     m_read32_rom 0xA
 651
 652 m_read32_romB: # 0x580000 - 0x5fffff
 653     m_read32_rom 0xB
 654
 655 m_read32_romC: # 0x600000 - 0x67ffff
 656     m_read32_rom 0xC
 657
 658 m_read32_romD: # 0x680000 - 0x6fffff
 659     m_read32_rom 0xD
 660
 661 m_read32_romE: # 0x700000 - 0x77ffff
 662     m_read32_rom 0xE
 663
 664 m_read32_romF: # 0x780000 - 0x7fffff
 665     m_read32_rom 0xF
 666
 667 m_read32_rom10: # 0x800000 - 0x87ffff
 668     m_read32_rom 0x10
 669
 670 m_read32_rom11: # 0x880000 - 0x8fffff
 671     m_read32_rom 0x11
 672
 673 m_read32_rom12: # 0x900000 - 0x97ffff
 674     m_read32_rom 0x12
 675
 676 m_read32_rom13: # 0x980000 - 0x9fffff
 677     m_read32_rom 0x13
 678
 679 .macro m_read32_call16 func need_a1=0
 680     addiu   $sp, -8
 681     sw      $ra, 0($sp)
 682     sw      $s0, 4($sp)
 683 .if \need_a1
 684     li      $a1, 16
 685 .endif
 686     jal     \func
 687     move    $s0, $a0
 688
 689     addu    $a0, $s0, 2
 690 .if \need_a1
 691     li      $a1, 16
 692 .endif
 693     jal     \func
 694     move    $s0, $v0
 695
 696     ins     $v0, $s0, 16, 16
 697     lw      $ra, 0($sp)
 698     lw      $s0, 4($sp)
 699     jr      $ra
 700     addiu   $sp, 8
 701 .endm
 702
 703 m_read32_misc:
 704     ins     $a0, $0, 0, 1
 705     m_read32_call16 OtherRead16, 1
 706
 707 m_read32_vdp:
 708     ext     $t0, $a0, 16, 3
 709     andi    $t1, $a0, 0xe0
 710     or      $t0, $t1
 711     bnez    $t0, m_read_null # invalid address
 712     ins     $a0, $0, 0, 1
 713     m_read32_call16 PicoVideoRead
 714
 715 m_read32_ram:
 716     lui     $t0, %hi(Pico)
 717     ins     $a0, $0, 0, 1
 718     ins     $t0, $a0, 0, 16
 719     lh      $v1, %lo(Pico)($t0)
 720     lh      $v0, %lo(Pico+2)($t0)
 721     jr      $ra
 722     ins     $v0, $v1, 16, 16
 723
 724 m_read32_above_rom:
 725     # might still be SRam
 726     m_read_rom_try_sram 0 32
 727     ins     $a0, $0, 0, 1
 728     m_read32_call16 OtherRead16End
 729
 730 # #############################################################################
 731
 732 .macro PicoWriteRomHW_SSF2_ls def_table table
 733     lui     $t3, %hi(\def_table)
 734     ins     $t3, $a1, 2, 5
 735     lw      $t0, %lo(\def_table)($t3)
 736     lui     $t2, %hi(\table)
 737     ins     $t2, $a0, 2, 3
 738     sw      $t0, %lo(\table)($t2)
 739 .endm
 740
 741 PicoWriteRomHW_SSF2: # u32 a, u32 d
 742     ext     $a0, $a0, 1, 3
 743     bnez    $a0, pwr_banking
 744
 745     # sram register
 746     lui     $t0, %hi(Pico+0x22211)
 747     lb      $t1, %lo(Pico+0x22211)($t0) # Pico.m.sram_reg
 748     ins     $t1, $a1, 0, 2
 749     jr      $ra
 750     sb      $t1, %lo(Pico+0x22211)($t0)
 751
 752 pwr_banking:
 753     andi    $a1, 0x1f
 754
 755     PicoWriteRomHW_SSF2_ls m_read8_def_table  m_read8_table
 756     PicoWriteRomHW_SSF2_ls m_read16_def_table m_read16_table
 757     PicoWriteRomHW_SSF2_ls m_read32_def_table m_read32_table
 758
 759     jr      $ra
 760     nop
 761