[pcsx_rearmed.git] / libpcsxcore / new_dynarec / linkage_arm.S

/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
 *   linkage_arm.s for PCSX                                                *
 *   Copyright (C) 2009-2011 Ari64                                         *
 *   Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas                     *
 *                                                                         *
 *   This program is free software; you can redistribute it and/or modify  *
 *   it under the terms of the GNU General Public License as published by  *
 *   the Free Software Foundation; either version 2 of the License, or     *
 *   (at your option) any later version.                                   *
 *                                                                         *
 *   This program is distributed in the hope that it will be useful,       *
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
 *   GNU General Public License for more details.                          *
 *                                                                         *
 *   You should have received a copy of the GNU General Public License     *
 *   along with this program; if not, write to the                         *
 *   Free Software Foundation, Inc.,                                       *
 *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
 * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */

#include "arm_features.h"
#include "new_dynarec_config.h"
#include "linkage_offsets.h"


#ifdef __MACH__
#define dynarec_local		ESYM(dynarec_local)
#define ndrc_add_jump_out	ESYM(ndrc_add_jump_out)
#define ndrc_try_restore_block	ESYM(ndrc_try_restore_block)
#define ndrc_get_addr_ht	ESYM(ndrc_get_addr_ht)
#define ndrc_get_addr_ht_param	ESYM(ndrc_get_addr_ht_param)
#define ndrc_write_invalidate_one ESYM(ndrc_write_invalidate_one)
#define gen_interupt		ESYM(gen_interupt)
#define gteCheckStallRaw	ESYM(gteCheckStallRaw)
#define psxException		ESYM(psxException)
#endif

	.bss
	.align	4
	.global dynarec_local
	.type	dynarec_local, %object
	.size	dynarec_local, LO_dynarec_local_size
dynarec_local:
	.space	LO_dynarec_local_size

#define DRC_VAR_(name, vname, size_) \
	vname = dynarec_local + LO_##name; \
	.global vname; \
	.type	vname, %object; \
	.size	vname, size_

#define DRC_VAR(name, size_) \
	DRC_VAR_(name, ESYM(name), size_)

DRC_VAR(next_interupt, 4)
DRC_VAR(cycle_count, 4)
DRC_VAR(last_count, 4)
DRC_VAR(pending_exception, 4)
DRC_VAR(stop, 4)
DRC_VAR(branch_target, 4)
DRC_VAR(address, 4)
DRC_VAR(hack_addr, 4)
DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)

/* psxRegs */
@DRC_VAR(reg, 128)
DRC_VAR(lo, 4)
DRC_VAR(hi, 4)
DRC_VAR(reg_cop0, 128)
DRC_VAR(reg_cop2d, 128)
DRC_VAR(reg_cop2c, 128)
DRC_VAR(pcaddr, 4)
@DRC_VAR(code, 4)
@DRC_VAR(cycle, 4)
@DRC_VAR(interrupt, 4)
@DRC_VAR(intCycle, 256)

DRC_VAR(rcnts, 7*4*4)
DRC_VAR(inv_code_start, 4)
DRC_VAR(inv_code_end, 4)
DRC_VAR(mem_rtab, 4)
DRC_VAR(mem_wtab, 4)
DRC_VAR(psxH_ptr, 4)
DRC_VAR(zeromem_ptr, 4)
DRC_VAR(invc_ptr, 4)
DRC_VAR(scratch_buf_ptr, 4)
DRC_VAR(ram_offset, 4)
DRC_VAR(mini_ht, 256)


	.syntax unified
	.text
	.align	2

#ifndef HAVE_ARMV5
.macro blx rd
	mov	lr, pc
	bx	\rd
.endm
#endif

.macro load_varadr reg var
#if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
	movw	\reg, #:lower16:(\var-(1678f+8))
	movt	\reg, #:upper16:(\var-(1678f+8))
1678:
	add	\reg, pc
#elif defined(HAVE_ARMV7) && !defined(__PIC__)
	movw	\reg, #:lower16:\var
	movt	\reg, #:upper16:\var
#else
	ldr	\reg, =\var
#endif
.endm

.macro load_varadr_ext reg var
#if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
	movw	\reg, #:lower16:(ptr_\var-(1678f+8))
	movt	\reg, #:upper16:(ptr_\var-(1678f+8))
1678:
	ldr	\reg, [pc, \reg]
#else
	load_varadr \reg \var
#endif
.endm

.macro mov_16 reg imm
#ifdef HAVE_ARMV7
	movw	\reg, #\imm
#else
	mov	\reg, #(\imm & 0x00ff)
	orr	\reg, #(\imm & 0xff00)
#endif
.endm

.macro mov_24 reg imm
#ifdef HAVE_ARMV7
	movw	\reg, #(\imm & 0xffff)
	movt	\reg, #(\imm >> 16)
#else
	mov	\reg, #(\imm & 0x0000ff)
	orr	\reg, #(\imm & 0x00ff00)
	orr	\reg, #(\imm & 0xff0000)
#endif
.endm

FUNCTION(dyna_linker):
	/* r0 = virtual target address */
	/* r1 = pointer to an instruction to patch */
#ifndef NO_WRITE_EXEC
	ldr	r7, [r1]
	mov	r4, r0
	add	r6, r7, #2
	mov	r5, r1
	lsl	r6, r6, #8
	/* must not compile - that might expire the caller block */
	mov	r1, #0
	bl	ndrc_get_addr_ht_param

	movs	r8, r0
	beq	0f
	add	r6, r5, r6, asr #6  /* old target */
	teq	r0, r6
	moveq	pc, r0 /* Stale i-cache */
	mov	r0, r4
	mov	r1, r6
	bl	ndrc_add_jump_out

	sub	r2, r8, r5
	and	r1, r7, #0xff000000
	lsl	r2, r2, #6
	sub	r1, r1, #2
	add	r1, r1, r2, lsr #8
	str	r1, [r5]
	mov	pc, r8
0:
	mov	r0, r4
#else
	/* XXX: should be able to do better than this... */
#endif
	bl	ndrc_get_addr_ht
	mov	pc, r0
	.size	dyna_linker, .-dyna_linker

	.align	2
FUNCTION(jump_vaddr_r1):
	mov	r0, r1
	b	jump_vaddr_r0
	.size	jump_vaddr_r1, .-jump_vaddr_r1
FUNCTION(jump_vaddr_r2):
	mov	r0, r2
	b	jump_vaddr_r0
	.size	jump_vaddr_r2, .-jump_vaddr_r2
FUNCTION(jump_vaddr_r3):
	mov	r0, r3
	b	jump_vaddr_r0
	.size	jump_vaddr_r3, .-jump_vaddr_r3
FUNCTION(jump_vaddr_r4):
	mov	r0, r4
	b	jump_vaddr_r0
	.size	jump_vaddr_r4, .-jump_vaddr_r4
FUNCTION(jump_vaddr_r5):
	mov	r0, r5
	b	jump_vaddr_r0
	.size	jump_vaddr_r5, .-jump_vaddr_r5
FUNCTION(jump_vaddr_r6):
	mov	r0, r6
	b	jump_vaddr_r0
	.size	jump_vaddr_r6, .-jump_vaddr_r6
FUNCTION(jump_vaddr_r8):
	mov	r0, r8
	b	jump_vaddr_r0
	.size	jump_vaddr_r8, .-jump_vaddr_r8
FUNCTION(jump_vaddr_r9):
	mov	r0, r9
	b	jump_vaddr_r0
	.size	jump_vaddr_r9, .-jump_vaddr_r9
FUNCTION(jump_vaddr_r10):
	mov	r0, r10
	b	jump_vaddr_r0
	.size	jump_vaddr_r10, .-jump_vaddr_r10
FUNCTION(jump_vaddr_r12):
	mov	r0, r12
	b	jump_vaddr_r0
	.size	jump_vaddr_r12, .-jump_vaddr_r12
FUNCTION(jump_vaddr_r7):
	add	r0, r7, #0
	.size	jump_vaddr_r7, .-jump_vaddr_r7
FUNCTION(jump_vaddr_r0):
	bl	ndrc_get_addr_ht
	mov	pc, r0
	.size	jump_vaddr_r0, .-jump_vaddr_r0

	.align	2
FUNCTION(cc_interrupt):
	ldr	r0, [fp, #LO_last_count]
	mov	r1, #0
	add	r10, r0, r10
	str	r1, [fp, #LO_pending_exception]
	str	r10, [fp, #LO_cycle]		/* PCSX cycles */
	mov	r10, lr

	add	r0, fp, #LO_reg_cop0            /* CP0 */
	bl	gen_interupt
	mov	lr, r10
	ldr	r10, [fp, #LO_cycle]
	ldr	r0, [fp, #LO_next_interupt]
	ldr	r1, [fp, #LO_pending_exception]
	ldr	r2, [fp, #LO_stop]
	str	r0, [fp, #LO_last_count]
	sub	r10, r10, r0
	tst	r2, r2
	ldmfdne	sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
	tst	r1, r1
	moveq	pc, lr
	ldr	r0, [fp, #LO_pcaddr]
	bl	ndrc_get_addr_ht
	mov	pc, r0
	.size	cc_interrupt, .-cc_interrupt

	.align	2
FUNCTION(jump_addrerror_ds): /* R3000E_AdEL / R3000E_AdES in r0 */
	str	r1, [fp, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
	mov	r1, #1
	b	call_psxException
FUNCTION(jump_addrerror):
	str	r1, [fp, #(LO_psxRegs + (34+8)*4)]  /* BadVaddr */
	mov	r1, #0
	b	call_psxException
FUNCTION(jump_overflow_ds):
	mov	r0, #(12<<2)  /* R3000E_Ov */
	mov	r1, #1
	b	call_psxException
FUNCTION(jump_overflow):
	mov	r0, #(12<<2)
	mov	r1, #0
	b	call_psxException
FUNCTION(jump_break_ds):
	mov	r0, #(9<<2)  /* R3000E_Bp */
	mov	r1, #1
	b	call_psxException
FUNCTION(jump_break):
	mov	r0, #(9<<2)
	mov	r1, #0
	b	call_psxException
FUNCTION(jump_syscall_ds):
	mov	r0, #(8<<2)  /* R3000E_Syscall */
	mov	r1, #2
	b	call_psxException
FUNCTION(jump_syscall):
	mov	r0, #(8<<2)
	mov	r1, #0

call_psxException:
	ldr	r3, [fp, #LO_last_count]
	str	r2, [fp, #LO_pcaddr]
	add	r10, r3, r10
	str	r10, [fp, #LO_cycle]            /* PCSX cycles */
	add	r2, fp, #LO_reg_cop0            /* CP0 */
	bl	psxException

	/* note: psxException might do recursive recompiler call from it's HLE code,
	 * so be ready for this */
FUNCTION(jump_to_new_pc):
	ldr	r1, [fp, #LO_next_interupt]
	ldr	r10, [fp, #LO_cycle]
	ldr	r0, [fp, #LO_pcaddr]
	sub	r10, r10, r1
	str	r1, [fp, #LO_last_count]
	bl	ndrc_get_addr_ht
	mov	pc, r0
	.size	jump_to_new_pc, .-jump_to_new_pc

	.align	2
FUNCTION(new_dyna_leave):
	ldr	r0, [fp, #LO_last_count]
	add	r12, fp, #28
	add	r10, r0, r10
	str	r10, [fp, #LO_cycle]
	ldmfd	sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
	.size	new_dyna_leave, .-new_dyna_leave

	.align	2
FUNCTION(invalidate_addr_r0):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	b	invalidate_addr_call
	.size	invalidate_addr_r0, .-invalidate_addr_r0
	.align	2
FUNCTION(invalidate_addr_r1):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r1
	b	invalidate_addr_call
	.size	invalidate_addr_r1, .-invalidate_addr_r1
	.align	2
FUNCTION(invalidate_addr_r2):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r2
	b	invalidate_addr_call
	.size	invalidate_addr_r2, .-invalidate_addr_r2
	.align	2
FUNCTION(invalidate_addr_r3):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r3
	b	invalidate_addr_call
	.size	invalidate_addr_r3, .-invalidate_addr_r3
	.align	2
FUNCTION(invalidate_addr_r4):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r4
	b	invalidate_addr_call
	.size	invalidate_addr_r4, .-invalidate_addr_r4
	.align	2
FUNCTION(invalidate_addr_r5):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r5
	b	invalidate_addr_call
	.size	invalidate_addr_r5, .-invalidate_addr_r5
	.align	2
FUNCTION(invalidate_addr_r6):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r6
	b	invalidate_addr_call
	.size	invalidate_addr_r6, .-invalidate_addr_r6
	.align	2
FUNCTION(invalidate_addr_r7):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r7
	b	invalidate_addr_call
	.size	invalidate_addr_r7, .-invalidate_addr_r7
	.align	2
FUNCTION(invalidate_addr_r8):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r8
	b	invalidate_addr_call
	.size	invalidate_addr_r8, .-invalidate_addr_r8
	.align	2
FUNCTION(invalidate_addr_r9):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r9
	b	invalidate_addr_call
	.size	invalidate_addr_r9, .-invalidate_addr_r9
	.align	2
FUNCTION(invalidate_addr_r10):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r10
	b	invalidate_addr_call
	.size	invalidate_addr_r10, .-invalidate_addr_r10
	.align	2
FUNCTION(invalidate_addr_r12):
	stmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
	mov	r0, r12
	.size	invalidate_addr_r12, .-invalidate_addr_r12
	.align	2
invalidate_addr_call:
	ldr	r12, [fp, #LO_inv_code_start]
	ldr	lr, [fp, #LO_inv_code_end]
	cmp	r0, r12
	cmpcs   lr, r0
	blcc	ndrc_write_invalidate_one
	ldmia	fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
	.size	invalidate_addr_call, .-invalidate_addr_call

	.align	2
FUNCTION(new_dyna_start):
	/* ip is stored to conform EABI alignment */
	stmfd	sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
	mov	fp, r0 /* dynarec_local */
	ldr	r0, [fp, #LO_pcaddr]
	bl	ndrc_get_addr_ht
	ldr	r1, [fp, #LO_next_interupt]
	ldr	r10, [fp, #LO_cycle]
	str	r1, [fp, #LO_last_count]
	sub	r10, r10, r1
	mov	pc, r0
	.size	new_dyna_start, .-new_dyna_start

/* --------------------------------------- */

.align	2

.macro pcsx_read_mem readop tab_shift
	/* r0 = address, r1 = handler_tab, r2 = cycles */
	lsl	r3, r0, #20
	lsr	r3, #(20+\tab_shift)
	ldr	r12, [fp, #LO_last_count]
	ldr	r1, [r1, r3, lsl #2]
	add	r2, r2, r12
	lsls	r1, #1
.if \tab_shift == 1
	lsl	r3, #1
	\readop	r0, [r1, r3]
.else
	\readop	r0, [r1, r3, lsl #\tab_shift]
.endif
	movcc	pc, lr
	str	r2, [fp, #LO_cycle]
	bx	r1
.endm

FUNCTION(jump_handler_read8):
	add     r1, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
	pcsx_read_mem ldrbcc, 0

FUNCTION(jump_handler_read16):
	add     r1, #0x1000/4*4              @ shift to r16 part
	pcsx_read_mem ldrhcc, 1

FUNCTION(jump_handler_read32):
	pcsx_read_mem ldrcc, 2


.macro memhandler_post
	ldr	r0, [fp, #LO_next_interupt]
	ldr	r2, [fp, #LO_cycle]        @ memhandlers can modify cc, like dma
	str	r0, [fp, #LO_last_count]
	sub	r0, r2, r0
.endm

.macro pcsx_write_mem wrtop tab_shift
	/* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
	lsl	r12,r0, #20
	lsr	r12, #(20+\tab_shift)
	ldr	r3, [r3, r12, lsl #2]
	str	r0, [fp, #LO_address]      @ some handlers still need it..
	lsls	r3, #1
	mov     r0, r2                     @ cycle return in case of direct store
.if \tab_shift == 1
	lsl	r12, #1
	\wrtop	r1, [r3, r12]
.else
	\wrtop	r1, [r3, r12, lsl #\tab_shift]
.endif
	movcc	pc, lr
	ldr	r12, [fp, #LO_last_count]
	mov     r0, r1
	add	r2, r2, r12
	str	r2, [fp, #LO_cycle]

	str	lr, [fp, #LO_saved_lr]
	blx	r3
	ldr	lr, [fp, #LO_saved_lr]

	memhandler_post
	bx	lr
.endm

FUNCTION(jump_handler_write8):
	add     r3, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
	pcsx_write_mem strbcc, 0

FUNCTION(jump_handler_write16):
	add     r3, #0x1000/4*4              @ shift to r16 part
	pcsx_write_mem strhcc, 1

FUNCTION(jump_handler_write32):
	pcsx_write_mem strcc, 2

FUNCTION(jump_handler_write_h):
	/* r0 = address, r1 = data, r2 = cycles, r3 = handler */
	ldr	r12, [fp, #LO_last_count]
	str	r0, [fp, #LO_address]      @ some handlers still need it..
	add	r2, r2, r12
	mov     r0, r1
	str	r2, [fp, #LO_cycle]

	str	lr, [fp, #LO_saved_lr]
	blx	r3
	ldr	lr, [fp, #LO_saved_lr]

	memhandler_post
	bx	lr

FUNCTION(jump_handle_swl):
	/* r0 = address, r1 = data, r2 = cycles */
	ldr	r3, [fp, #LO_mem_wtab]
	mov	r12,r0,lsr #12
	ldr	r3, [r3, r12, lsl #2]
	lsls	r3, #1
	bcs	jump_handle_swx_interp
	add	r3, r0, r3
	mov	r0, r2
	tst	r3, #2
	beq	101f
	tst	r3, #1
	beq	2f
3:
	str	r1, [r3, #-3]
	bx	lr
2:
	lsr	r2, r1, #8
	lsr	r1, #24
	strh	r2, [r3, #-2]
	strb	r1, [r3]
	bx	lr
101:
	tst	r3, #1
	lsrne	r1, #16		@ 1
	lsreq	r12, r1, #24	@ 0
	strhne	r1, [r3, #-1]
	strbeq	r12, [r3]
	bx	lr

FUNCTION(jump_handle_swr):
	/* r0 = address, r1 = data, r2 = cycles */
	ldr	r3, [fp, #LO_mem_wtab]
	mov	r12,r0,lsr #12
	ldr	r3, [r3, r12, lsl #2]
	lsls	r3, #1
	bcs	jump_handle_swx_interp
	add	r3, r0, r3
	and	r12,r3, #3
	mov	r0, r2
	cmp	r12,#2
	strbgt	r1, [r3]	@ 3
	strheq	r1, [r3]	@ 2
	cmp	r12,#1
	strlt	r1, [r3]	@ 0
	bxne	lr
	lsr	r2, r1, #8	@ 1
	strb	r1, [r3]
	strh	r2, [r3, #1]
	bx	lr

jump_handle_swx_interp: /* almost never happens */
	ldr	r3, [fp, #LO_last_count]
	add	r0, fp, #LO_psxRegs
	add	r2, r3, r2
	str	r2, [fp, #LO_cycle]           /* PCSX cycles */
	bl	execI
	b	jump_to_new_pc

.macro rcntx_read_mode0 num
	/* r0 = address, r2 = cycles */
	ldr	r3, [fp, #LO_rcnts+6*4+7*4*\num] @ cycleStart
	mov	r0, r2, lsl #16
	sub	r0, r0, r3, lsl #16
	lsr	r0, #16
	bx	lr
.endm

FUNCTION(rcnt0_read_count_m0):
	rcntx_read_mode0 0

FUNCTION(rcnt1_read_count_m0):
	rcntx_read_mode0 1

FUNCTION(rcnt2_read_count_m0):
	rcntx_read_mode0 2

FUNCTION(rcnt0_read_count_m1):
	/* r0 = address, r2 = cycles */
	ldr	r3, [fp, #LO_rcnts+6*4+7*4*0] @ cycleStart
	mov_16	r1, 0x3334
	sub	r2, r2, r3
	mul	r0, r1, r2		@ /= 5
	lsr	r0, #16
	bx	lr

FUNCTION(rcnt1_read_count_m1):
	/* r0 = address, r2 = cycles */
	ldr	r3, [fp, #LO_rcnts+6*4+7*4*1]
	mov_24	r1, 0x1e6cde
	sub	r2, r2, r3
	umull	r3, r0, r1, r2		@ ~ /= hsync_cycles, max ~0x1e6cdd
	bx	lr

FUNCTION(rcnt2_read_count_m1):
	/* r0 = address, r2 = cycles */
	ldr	r3, [fp, #LO_rcnts+6*4+7*4*2]
	mov	r0, r2, lsl #16-3
	sub	r0, r0, r3, lsl #16-3
	lsr	r0, #16			@ /= 8
	bx	lr

FUNCTION(call_gteStall):
	/* r0 = op_cycles, r1 = cycles */
	ldr	r2, [fp, #LO_last_count]
	str	lr, [fp, #LO_saved_lr]
	add	r1, r1, r2
	str	r1, [fp, #LO_cycle]
	add	r1, fp, #LO_psxRegs
	bl	gteCheckStallRaw
	ldr	lr, [fp, #LO_saved_lr]
	add	r10, r10, r0
	bx	lr

#ifdef HAVE_ARMV6

FUNCTION(get_reg):
	ldr	r12, [r0]
	and	r1, r1, #0xff
	ldr	r2, [r0, #4]
	orr	r1, r1, r1, lsl #8
	ldr	r3, [r0, #8]
	orr	r1, r1, r1, lsl #16   @ searched char in every byte
	ldrb    r0, [r0, #12]         @ last byte
	eor	r12, r12, r1
	eor	r2, r2, r1
	eor	r3, r3, r1
	cmp     r0, r1, lsr #24
	mov	r0, #12
	mvn	r1, #0                @ r1=~0
	bxeq	lr
	orr	r3, r3, #0xff000000   @ EXCLUDE_REG
	uadd8	r0, r12, r1           @ add and set GE bits when not 0 (match)
	mov	r12, #0
	sel	r0, r12, r1           @ 0 if no match, else ff in some byte
	uadd8	r2, r2, r1
	sel	r2, r12, r1
	uadd8	r3, r3, r1
	sel	r3, r12, r1
	mov	r12, #3
	clz     r0, r0                @ 0, 8, 16, 24 or 32
	clz     r2, r2
	clz     r3, r3
	sub	r0, r12, r0, lsr #3   @ 3, 2, 1, 0 or -1
	sub	r2, r12, r2, lsr #3
	sub	r3, r12, r3, lsr #3
	orr	r2, r2, #4
	orr	r3, r3, #8
	and	r0, r0, r2
	and	r0, r0, r3
	bx	lr

#endif /* HAVE_ARMV6 */

@ vim:filetype=armasm
Commit	Line	Data
57871462	1	/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
7e605697	2	* linkage_arm.s for PCSX *
0bbd1454	3	* Copyright (C) 2009-2011 Ari64 *
b1f89e6f	4	* Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas *
57871462	5	* *
	6	* This program is free software; you can redistribute it and/or modify *
	7	* it under the terms of the GNU General Public License as published by *
	8	* the Free Software Foundation; either version 2 of the License, or *
	9	* (at your option) any later version. *
	10	* *
	11	* This program is distributed in the hope that it will be useful, *
	12	* but WITHOUT ANY WARRANTY; without even the implied warranty of *
	13	* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *
	14	* GNU General Public License for more details. *
	15	* *
	16	* You should have received a copy of the GNU General Public License *
	17	* along with this program; if not, write to the *
	18	* Free Software Foundation, Inc., *
	19	* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA. *
	20	* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
b021ee75	21
665f33e1	22	#include "arm_features.h"
d148d265	23	#include "new_dynarec_config.h"
b1f89e6f	24	#include "linkage_offsets.h"
	25
	26
	27	#ifdef __MACH__
	28	#define dynarec_local ESYM(dynarec_local)
104df9d3	29	#define ndrc_add_jump_out ESYM(ndrc_add_jump_out)
398d6924	30	#define ndrc_try_restore_block ESYM(ndrc_try_restore_block)
104df9d3	31	#define ndrc_get_addr_ht ESYM(ndrc_get_addr_ht)
104df9d3	32	#define ndrc_get_addr_ht_param ESYM(ndrc_get_addr_ht_param)
9b495f6e	33	#define ndrc_write_invalidate_one ESYM(ndrc_write_invalidate_one)
b1f89e6f	34	#define gen_interupt ESYM(gen_interupt)
81dbbf4c	35	#define gteCheckStallRaw ESYM(gteCheckStallRaw)
d1150cd6	36	#define psxException ESYM(psxException)
b1f89e6f	37	#endif
f95a77f7	38
57871462	39	.bss
57871462	40	.align 4
b1f89e6f	41	.global dynarec_local
57871462	42	.type dynarec_local, %object
b1f89e6f	43	.size dynarec_local, LO_dynarec_local_size
57871462	44	dynarec_local:
b1f89e6f	45	.space LO_dynarec_local_size
	46
	47	#define DRC_VAR_(name, vname, size_) \
	48	vname = dynarec_local + LO_##name; \
	49	.global vname; \
	50	.type vname, %object; \
	51	.size vname, size_
	52
	53	#define DRC_VAR(name, size_) \
	54	DRC_VAR_(name, ESYM(name), size_)
	55
	56	DRC_VAR(next_interupt, 4)
	57	DRC_VAR(cycle_count, 4)
	58	DRC_VAR(last_count, 4)
	59	DRC_VAR(pending_exception, 4)
	60	DRC_VAR(stop, 4)
687b4580	61	DRC_VAR(branch_target, 4)
b1f89e6f	62	DRC_VAR(address, 4)
7f94b097	63	DRC_VAR(hack_addr, 4)
b1f89e6f	64	DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
f95a77f7	65
f95a77f7	66	/* psxRegs */
7c3a5182	67	@DRC_VAR(reg, 128)
b1f89e6f	68	DRC_VAR(lo, 4)
	69	DRC_VAR(hi, 4)
	70	DRC_VAR(reg_cop0, 128)
	71	DRC_VAR(reg_cop2d, 128)
	72	DRC_VAR(reg_cop2c, 128)
	73	DRC_VAR(pcaddr, 4)
	74	@DRC_VAR(code, 4)
	75	@DRC_VAR(cycle, 4)
	76	@DRC_VAR(interrupt, 4)
	77	@DRC_VAR(intCycle, 256)
	78
	79	DRC_VAR(rcnts, 744)
687b4580	80	DRC_VAR(inv_code_start, 4)
687b4580	81	DRC_VAR(inv_code_end, 4)
b1f89e6f	82	DRC_VAR(mem_rtab, 4)
	83	DRC_VAR(mem_wtab, 4)
	84	DRC_VAR(psxH_ptr, 4)
	85	DRC_VAR(zeromem_ptr, 4)
687b4580	86	DRC_VAR(invc_ptr, 4)
c6d5790c	87	DRC_VAR(scratch_buf_ptr, 4)
37387d8b	88	DRC_VAR(ram_offset, 4)
b1f89e6f	89	DRC_VAR(mini_ht, 256)
63cb0298	90
57871462	91
b861c0a9	92	.syntax unified
	93	.text
	94	.align 2
	95
665f33e1	96	#ifndef HAVE_ARMV5
	97	.macro blx rd
	98	mov lr, pc
	99	bx \rd
	100	.endm
	101	#endif
	102
c67af2ac	103	.macro load_varadr reg var
0e4ad319	104	#if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
1f4e070a	105	movw \reg, #:lower16:(\var-(1678f+8))
1f4e070a	106	movt \reg, #:upper16:(\var-(1678f+8))
b861c0a9	107	1678:
b861c0a9	108	add \reg, pc
0e4ad319	109	#elif defined(HAVE_ARMV7) && !defined(__PIC__)
	110	movw \reg, #:lower16:\var
	111	movt \reg, #:upper16:\var
c67af2ac	112	#else
274c4243	113	ldr \reg, =\var
c67af2ac	114	#endif
274c4243	115	.endm
274c4243	116
b861c0a9	117	.macro load_varadr_ext reg var
0e4ad319	118	#if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
1f4e070a	119	movw \reg, #:lower16:(ptr_\var-(1678f+8))
1f4e070a	120	movt \reg, #:upper16:(ptr_\var-(1678f+8))
b861c0a9	121	1678:
	122	ldr \reg, [pc, \reg]
	123	#else
	124	load_varadr \reg \var
	125	#endif
	126	.endm
	127
b1be1eee	128	.macro mov_16 reg imm
8f2bb0cb	129	#ifdef HAVE_ARMV7
b1be1eee	130	movw \reg, #\imm
c67af2ac	131	#else
b1be1eee	132	mov \reg, #(\imm & 0x00ff)
b1be1eee	133	orr \reg, #(\imm & 0xff00)
c67af2ac	134	#endif
b1be1eee	135	.endm
	136
	137	.macro mov_24 reg imm
8f2bb0cb	138	#ifdef HAVE_ARMV7
b1be1eee	139	movw \reg, #(\imm & 0xffff)
b1be1eee	140	movt \reg, #(\imm >> 16)
c67af2ac	141	#else
b1be1eee	142	mov \reg, #(\imm & 0x0000ff)
	143	orr \reg, #(\imm & 0x00ff00)
	144	orr \reg, #(\imm & 0xff0000)
c67af2ac	145	#endif
b1be1eee	146	.endm
b1be1eee	147
104df9d3	148	FUNCTION(dyna_linker):
	149	/* r0 = virtual target address */
	150	/* r1 = pointer to an instruction to patch */
d148d265	151	#ifndef NO_WRITE_EXEC
104df9d3	152	ldr r7, [r1]
	153	mov r4, r0
	154	add r6, r7, #2
	155	mov r5, r1
	156	lsl r6, r6, #8
	157	/* must not compile - that might expire the caller block */
	158	mov r1, #0
	159	bl ndrc_get_addr_ht_param
	160
	161	movs r8, r0
	162	beq 0f
	163	add r6, r5, r6, asr #6 /* old target */
398d6924	164	teq r0, r6
398d6924	165	moveq pc, r0 /* Stale i-cache */
398d6924	166	mov r0, r4
76f71c27	167	mov r1, r6
104df9d3	168	bl ndrc_add_jump_out
104df9d3	169
76f71c27	170	sub r2, r8, r5
57871462	171	and r1, r7, #0xff000000
	172	lsl r2, r2, #6
	173	sub r1, r1, #2
	174	add r1, r1, r2, lsr #8
	175	str r1, [r5]
76f71c27	176	mov pc, r8
104df9d3	177	0:
398d6924	178	mov r0, r4
d148d265	179	#else
d148d265	180	/* XXX: should be able to do better than this... */
d148d265	181	#endif
104df9d3	182	bl ndrc_get_addr_ht
57871462	183	mov pc, r0
4bdc30ab	184	.size dyna_linker, .-dyna_linker
7139f3c8	185
57871462	186	.align 2
5c6457c3	187	FUNCTION(jump_vaddr_r1):
57871462	188	mov r0, r1
104df9d3	189	b jump_vaddr_r0
57871462	190	.size jump_vaddr_r1, .-jump_vaddr_r1
5c6457c3	191	FUNCTION(jump_vaddr_r2):
57871462	192	mov r0, r2
104df9d3	193	b jump_vaddr_r0
57871462	194	.size jump_vaddr_r2, .-jump_vaddr_r2
5c6457c3	195	FUNCTION(jump_vaddr_r3):
57871462	196	mov r0, r3
104df9d3	197	b jump_vaddr_r0
57871462	198	.size jump_vaddr_r3, .-jump_vaddr_r3
5c6457c3	199	FUNCTION(jump_vaddr_r4):
57871462	200	mov r0, r4
104df9d3	201	b jump_vaddr_r0
57871462	202	.size jump_vaddr_r4, .-jump_vaddr_r4
5c6457c3	203	FUNCTION(jump_vaddr_r5):
57871462	204	mov r0, r5
104df9d3	205	b jump_vaddr_r0
57871462	206	.size jump_vaddr_r5, .-jump_vaddr_r5
5c6457c3	207	FUNCTION(jump_vaddr_r6):
57871462	208	mov r0, r6
104df9d3	209	b jump_vaddr_r0
57871462	210	.size jump_vaddr_r6, .-jump_vaddr_r6
5c6457c3	211	FUNCTION(jump_vaddr_r8):
57871462	212	mov r0, r8
104df9d3	213	b jump_vaddr_r0
57871462	214	.size jump_vaddr_r8, .-jump_vaddr_r8
5c6457c3	215	FUNCTION(jump_vaddr_r9):
57871462	216	mov r0, r9
104df9d3	217	b jump_vaddr_r0
57871462	218	.size jump_vaddr_r9, .-jump_vaddr_r9
5c6457c3	219	FUNCTION(jump_vaddr_r10):
57871462	220	mov r0, r10
104df9d3	221	b jump_vaddr_r0
57871462	222	.size jump_vaddr_r10, .-jump_vaddr_r10
5c6457c3	223	FUNCTION(jump_vaddr_r12):
57871462	224	mov r0, r12
104df9d3	225	b jump_vaddr_r0
57871462	226	.size jump_vaddr_r12, .-jump_vaddr_r12
5c6457c3	227	FUNCTION(jump_vaddr_r7):
57871462	228	add r0, r7, #0
57871462	229	.size jump_vaddr_r7, .-jump_vaddr_r7
104df9d3	230	FUNCTION(jump_vaddr_r0):
104df9d3	231	bl ndrc_get_addr_ht
57871462	232	mov pc, r0
104df9d3	233	.size jump_vaddr_r0, .-jump_vaddr_r0
7139f3c8	234
57871462	235	.align 2
5c6457c3	236	FUNCTION(cc_interrupt):
b1f89e6f	237	ldr r0, [fp, #LO_last_count]
57871462	238	mov r1, #0
57871462	239	add r10, r0, r10
b1f89e6f	240	str r1, [fp, #LO_pending_exception]
b1f89e6f	241	str r10, [fp, #LO_cycle] /* PCSX cycles */
57871462	242	mov r10, lr
398d6924	243
de6dbc52	244	add r0, fp, #LO_reg_cop0 /* CP0 */
57871462	245	bl gen_interupt
57871462	246	mov lr, r10
b1f89e6f	247	ldr r10, [fp, #LO_cycle]
	248	ldr r0, [fp, #LO_next_interupt]
	249	ldr r1, [fp, #LO_pending_exception]
	250	ldr r2, [fp, #LO_stop]
	251	str r0, [fp, #LO_last_count]
57871462	252	sub r10, r10, r0
57871462	253	tst r2, r2
b861c0a9	254	ldmfdne sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
57871462	255	tst r1, r1
57871462	256	moveq pc, lr
b1f89e6f	257	ldr r0, [fp, #LO_pcaddr]
104df9d3	258	bl ndrc_get_addr_ht
57871462	259	mov pc, r0
57871462	260	.size cc_interrupt, .-cc_interrupt
7139f3c8	261
57871462	262	.align 2
277718fa	263	FUNCTION(jump_addrerror_ds): /* R3000E_AdEL / R3000E_AdES in r0 */
	264	str r1, [fp, #(LO_psxRegs + (34+8)4)] / BadVaddr */
	265	mov r1, #1
	266	b call_psxException
	267	FUNCTION(jump_addrerror):
	268	str r1, [fp, #(LO_psxRegs + (34+8)4)] / BadVaddr */
	269	mov r1, #0
	270	b call_psxException
a5cd72d0	271	FUNCTION(jump_overflow_ds):
	272	mov r0, #(12<<2) /* R3000E_Ov */
	273	mov r1, #1
	274	b call_psxException
	275	FUNCTION(jump_overflow):
	276	mov r0, #(12<<2)
	277	mov r1, #0
	278	b call_psxException
d1150cd6	279	FUNCTION(jump_break_ds):
a5cd72d0	280	mov r0, #(9<<2) /* R3000E_Bp */
d1150cd6	281	mov r1, #1
	282	b call_psxException
	283	FUNCTION(jump_break):
a5cd72d0	284	mov r0, #(9<<2)
d1150cd6	285	mov r1, #0
	286	b call_psxException
	287	FUNCTION(jump_syscall_ds):
a5cd72d0	288	mov r0, #(8<<2) /* R3000E_Syscall */
bc7c5acb	289	mov r1, #2
d1150cd6	290	b call_psxException
5c6457c3	291	FUNCTION(jump_syscall):
a5cd72d0	292	mov r0, #(8<<2)
d1150cd6	293	mov r1, #0
	294
	295	call_psxException:
	296	ldr r3, [fp, #LO_last_count]
	297	str r2, [fp, #LO_pcaddr]
	298	add r10, r3, r10
6d75addf	299	str r10, [fp, #LO_cycle] /* PCSX cycles */
de6dbc52	300	add r2, fp, #LO_reg_cop0 /* CP0 */
d1150cd6	301	bl psxException
7139f3c8	302
b1f89e6f	303	/* note: psxException might do recursive recompiler call from it's HLE code,
7139f3c8	304	* so be ready for this */
3968e69e	305	FUNCTION(jump_to_new_pc):
b1f89e6f	306	ldr r1, [fp, #LO_next_interupt]
	307	ldr r10, [fp, #LO_cycle]
	308	ldr r0, [fp, #LO_pcaddr]
822b27d1	309	sub r10, r10, r1
b1f89e6f	310	str r1, [fp, #LO_last_count]
104df9d3	311	bl ndrc_get_addr_ht
7139f3c8	312	mov pc, r0
3968e69e	313	.size jump_to_new_pc, .-jump_to_new_pc
0d16cda2	314
7139f3c8	315	.align 2
5c6457c3	316	FUNCTION(new_dyna_leave):
b1f89e6f	317	ldr r0, [fp, #LO_last_count]
7139f3c8	318	add r12, fp, #28
7139f3c8	319	add r10, r0, r10
b1f89e6f	320	str r10, [fp, #LO_cycle]
b021ee75	321	ldmfd sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
7139f3c8	322	.size new_dyna_leave, .-new_dyna_leave
7139f3c8	323
0bbd1454	324	.align 2
5c6457c3	325	FUNCTION(invalidate_addr_r0):
5df0e313	326	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
0bbd1454	327	b invalidate_addr_call
	328	.size invalidate_addr_r0, .-invalidate_addr_r0
	329	.align 2
5c6457c3	330	FUNCTION(invalidate_addr_r1):
5df0e313	331	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	332	mov r0, r1
0bbd1454	333	b invalidate_addr_call
	334	.size invalidate_addr_r1, .-invalidate_addr_r1
	335	.align 2
5c6457c3	336	FUNCTION(invalidate_addr_r2):
5df0e313	337	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	338	mov r0, r2
0bbd1454	339	b invalidate_addr_call
	340	.size invalidate_addr_r2, .-invalidate_addr_r2
	341	.align 2
5c6457c3	342	FUNCTION(invalidate_addr_r3):
5df0e313	343	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	344	mov r0, r3
0bbd1454	345	b invalidate_addr_call
	346	.size invalidate_addr_r3, .-invalidate_addr_r3
	347	.align 2
5c6457c3	348	FUNCTION(invalidate_addr_r4):
5df0e313	349	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	350	mov r0, r4
0bbd1454	351	b invalidate_addr_call
	352	.size invalidate_addr_r4, .-invalidate_addr_r4
	353	.align 2
5c6457c3	354	FUNCTION(invalidate_addr_r5):
5df0e313	355	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	356	mov r0, r5
0bbd1454	357	b invalidate_addr_call
	358	.size invalidate_addr_r5, .-invalidate_addr_r5
	359	.align 2
5c6457c3	360	FUNCTION(invalidate_addr_r6):
5df0e313	361	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	362	mov r0, r6
0bbd1454	363	b invalidate_addr_call
	364	.size invalidate_addr_r6, .-invalidate_addr_r6
	365	.align 2
5c6457c3	366	FUNCTION(invalidate_addr_r7):
5df0e313	367	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	368	mov r0, r7
0bbd1454	369	b invalidate_addr_call
	370	.size invalidate_addr_r7, .-invalidate_addr_r7
	371	.align 2
5c6457c3	372	FUNCTION(invalidate_addr_r8):
5df0e313	373	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	374	mov r0, r8
0bbd1454	375	b invalidate_addr_call
	376	.size invalidate_addr_r8, .-invalidate_addr_r8
	377	.align 2
5c6457c3	378	FUNCTION(invalidate_addr_r9):
5df0e313	379	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	380	mov r0, r9
0bbd1454	381	b invalidate_addr_call
	382	.size invalidate_addr_r9, .-invalidate_addr_r9
	383	.align 2
5c6457c3	384	FUNCTION(invalidate_addr_r10):
5df0e313	385	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	386	mov r0, r10
0bbd1454	387	b invalidate_addr_call
	388	.size invalidate_addr_r10, .-invalidate_addr_r10
	389	.align 2
5c6457c3	390	FUNCTION(invalidate_addr_r12):
5df0e313	391	stmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
9be4ba64	392	mov r0, r12
0bbd1454	393	.size invalidate_addr_r12, .-invalidate_addr_r12
0bbd1454	394	.align 2
b1f89e6f	395	invalidate_addr_call:
	396	ldr r12, [fp, #LO_inv_code_start]
	397	ldr lr, [fp, #LO_inv_code_end]
9be4ba64	398	cmp r0, r12
9be4ba64	399	cmpcs lr, r0
9b495f6e	400	blcc ndrc_write_invalidate_one
5df0e313	401	ldmia fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
0bbd1454	402	.size invalidate_addr_call, .-invalidate_addr_call
0bbd1454	403
57871462	404	.align 2
5c6457c3	405	FUNCTION(new_dyna_start):
b021ee75	406	/* ip is stored to conform EABI alignment */
b021ee75	407	stmfd sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
be516ebe	408	mov fp, r0 /* dynarec_local */
b1f89e6f	409	ldr r0, [fp, #LO_pcaddr]
104df9d3	410	bl ndrc_get_addr_ht
b1f89e6f	411	ldr r1, [fp, #LO_next_interupt]
	412	ldr r10, [fp, #LO_cycle]
	413	str r1, [fp, #LO_last_count]
7139f3c8	414	sub r10, r10, r1
7139f3c8	415	mov pc, r0
57871462	416	.size new_dyna_start, .-new_dyna_start
7139f3c8	417
7e605697	418	/* --------------------------------------- */
7139f3c8	419
7e605697	420	.align 2
c6c3b1b3	421
	422	.macro pcsx_read_mem readop tab_shift
	423	/* r0 = address, r1 = handler_tab, r2 = cycles */
	424	lsl r3, r0, #20
	425	lsr r3, #(20+\tab_shift)
b1f89e6f	426	ldr r12, [fp, #LO_last_count]
c6c3b1b3	427	ldr r1, [r1, r3, lsl #2]
	428	add r2, r2, r12
	429	lsls r1, #1
	430	.if \tab_shift == 1
	431	lsl r3, #1
	432	\readop r0, [r1, r3]
	433	.else
	434	\readop r0, [r1, r3, lsl #\tab_shift]
	435	.endif
	436	movcc pc, lr
b1f89e6f	437	str r2, [fp, #LO_cycle]
c6c3b1b3	438	bx r1
	439	.endm
	440
5c6457c3	441	FUNCTION(jump_handler_read8):
c6c3b1b3	442	add r1, #0x1000/44 + 0x1000/24 @ shift to r8 part
b861c0a9	443	pcsx_read_mem ldrbcc, 0
c6c3b1b3	444
5c6457c3	445	FUNCTION(jump_handler_read16):
c6c3b1b3	446	add r1, #0x1000/4*4 @ shift to r16 part
10858959	447	pcsx_read_mem ldrhcc, 1
c6c3b1b3	448
5c6457c3	449	FUNCTION(jump_handler_read32):
c6c3b1b3	450	pcsx_read_mem ldrcc, 2
c6c3b1b3	451
b96d3df7	452
9b9af0d1	453	.macro memhandler_post
	454	ldr r0, [fp, #LO_next_interupt]
	455	ldr r2, [fp, #LO_cycle] @ memhandlers can modify cc, like dma
	456	str r0, [fp, #LO_last_count]
	457	sub r0, r2, r0
	458	.endm
	459
b96d3df7	460	.macro pcsx_write_mem wrtop tab_shift
	461	/* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
	462	lsl r12,r0, #20
	463	lsr r12, #(20+\tab_shift)
	464	ldr r3, [r3, r12, lsl #2]
b1f89e6f	465	str r0, [fp, #LO_address] @ some handlers still need it..
b96d3df7	466	lsls r3, #1
9b9af0d1	467	mov r0, r2 @ cycle return in case of direct store
b96d3df7	468	.if \tab_shift == 1
	469	lsl r12, #1
	470	\wrtop r1, [r3, r12]
	471	.else
	472	\wrtop r1, [r3, r12, lsl #\tab_shift]
	473	.endif
	474	movcc pc, lr
b1f89e6f	475	ldr r12, [fp, #LO_last_count]
b96d3df7	476	mov r0, r1
b96d3df7	477	add r2, r2, r12
b1f89e6f	478	str r2, [fp, #LO_cycle]
9b9af0d1	479
9b9af0d1	480	str lr, [fp, #LO_saved_lr]
b96d3df7	481	blx r3
9b9af0d1	482	ldr lr, [fp, #LO_saved_lr]
b96d3df7	483
9b9af0d1	484	memhandler_post
687b4580	485	bx lr
b96d3df7	486	.endm
b96d3df7	487
5c6457c3	488	FUNCTION(jump_handler_write8):
b96d3df7	489	add r3, #0x1000/44 + 0x1000/24 @ shift to r8 part
b861c0a9	490	pcsx_write_mem strbcc, 0
b96d3df7	491
5c6457c3	492	FUNCTION(jump_handler_write16):
b96d3df7	493	add r3, #0x1000/4*4 @ shift to r16 part
b861c0a9	494	pcsx_write_mem strhcc, 1
b96d3df7	495
5c6457c3	496	FUNCTION(jump_handler_write32):
b96d3df7	497	pcsx_write_mem strcc, 2
b96d3df7	498
5c6457c3	499	FUNCTION(jump_handler_write_h):
b96d3df7	500	/* r0 = address, r1 = data, r2 = cycles, r3 = handler */
b1f89e6f	501	ldr r12, [fp, #LO_last_count]
b1f89e6f	502	str r0, [fp, #LO_address] @ some handlers still need it..
b96d3df7	503	add r2, r2, r12
b96d3df7	504	mov r0, r1
b1f89e6f	505	str r2, [fp, #LO_cycle]
9b9af0d1	506
9b9af0d1	507	str lr, [fp, #LO_saved_lr]
b96d3df7	508	blx r3
9b9af0d1	509	ldr lr, [fp, #LO_saved_lr]
b96d3df7	510
9b9af0d1	511	memhandler_post
687b4580	512	bx lr
b96d3df7	513
5c6457c3	514	FUNCTION(jump_handle_swl):
b96d3df7	515	/* r0 = address, r1 = data, r2 = cycles */
b1f89e6f	516	ldr r3, [fp, #LO_mem_wtab]
b96d3df7	517	mov r12,r0,lsr #12
	518	ldr r3, [r3, r12, lsl #2]
	519	lsls r3, #1
de6dbc52	520	bcs jump_handle_swx_interp
b96d3df7	521	add r3, r0, r3
	522	mov r0, r2
	523	tst r3, #2
	524	beq 101f
	525	tst r3, #1
	526	beq 2f
	527	3:
	528	str r1, [r3, #-3]
	529	bx lr
	530	2:
	531	lsr r2, r1, #8
	532	lsr r1, #24
	533	strh r2, [r3, #-2]
	534	strb r1, [r3]
	535	bx lr
	536	101:
	537	tst r3, #1
	538	lsrne r1, #16 @ 1
	539	lsreq r12, r1, #24 @ 0
b861c0a9	540	strhne r1, [r3, #-1]
b861c0a9	541	strbeq r12, [r3]
b96d3df7	542	bx lr
b96d3df7	543
5c6457c3	544	FUNCTION(jump_handle_swr):
b96d3df7	545	/* r0 = address, r1 = data, r2 = cycles */
b1f89e6f	546	ldr r3, [fp, #LO_mem_wtab]
b96d3df7	547	mov r12,r0,lsr #12
	548	ldr r3, [r3, r12, lsl #2]
	549	lsls r3, #1
de6dbc52	550	bcs jump_handle_swx_interp
b96d3df7	551	add r3, r0, r3
	552	and r12,r3, #3
	553	mov r0, r2
	554	cmp r12,#2
b861c0a9	555	strbgt r1, [r3] @ 3
b861c0a9	556	strheq r1, [r3] @ 2
b96d3df7	557	cmp r12,#1
	558	strlt r1, [r3] @ 0
	559	bxne lr
	560	lsr r2, r1, #8 @ 1
	561	strb r1, [r3]
	562	strh r2, [r3, #1]
	563	bx lr
b96d3df7	564
de6dbc52	565	jump_handle_swx_interp: /* almost never happens */
	566	ldr r3, [fp, #LO_last_count]
	567	add r0, fp, #LO_psxRegs
	568	add r2, r3, r2
	569	str r2, [fp, #LO_cycle] /* PCSX cycles */
	570	bl execI
	571	b jump_to_new_pc
b96d3df7	572
b1be1eee	573	.macro rcntx_read_mode0 num
b1be1eee	574	/* r0 = address, r2 = cycles */
b1f89e6f	575	ldr r3, [fp, #LO_rcnts+64+74*\num] @ cycleStart
b1be1eee	576	mov r0, r2, lsl #16
b861c0a9	577	sub r0, r0, r3, lsl #16
b1be1eee	578	lsr r0, #16
	579	bx lr
	580	.endm
	581
5c6457c3	582	FUNCTION(rcnt0_read_count_m0):
b1be1eee	583	rcntx_read_mode0 0
b1be1eee	584
5c6457c3	585	FUNCTION(rcnt1_read_count_m0):
b1be1eee	586	rcntx_read_mode0 1
b1be1eee	587
5c6457c3	588	FUNCTION(rcnt2_read_count_m0):
b1be1eee	589	rcntx_read_mode0 2
b1be1eee	590
5c6457c3	591	FUNCTION(rcnt0_read_count_m1):
b1be1eee	592	/* r0 = address, r2 = cycles */
b1f89e6f	593	ldr r3, [fp, #LO_rcnts+64+74*0] @ cycleStart
b1be1eee	594	mov_16 r1, 0x3334
	595	sub r2, r2, r3
	596	mul r0, r1, r2 @ /= 5
	597	lsr r0, #16
	598	bx lr
	599
5c6457c3	600	FUNCTION(rcnt1_read_count_m1):
b1be1eee	601	/* r0 = address, r2 = cycles */
b1f89e6f	602	ldr r3, [fp, #LO_rcnts+64+74*1]
b1be1eee	603	mov_24 r1, 0x1e6cde
	604	sub r2, r2, r3
	605	umull r3, r0, r1, r2 @ ~ /= hsync_cycles, max ~0x1e6cdd
	606	bx lr
	607
5c6457c3	608	FUNCTION(rcnt2_read_count_m1):
b1be1eee	609	/* r0 = address, r2 = cycles */
b1f89e6f	610	ldr r3, [fp, #LO_rcnts+64+74*2]
b1be1eee	611	mov r0, r2, lsl #16-3
b861c0a9	612	sub r0, r0, r3, lsl #16-3
b1be1eee	613	lsr r0, #16 @ /= 8
	614	bx lr
	615
81dbbf4c	616	FUNCTION(call_gteStall):
	617	/* r0 = op_cycles, r1 = cycles */
	618	ldr r2, [fp, #LO_last_count]
	619	str lr, [fp, #LO_saved_lr]
	620	add r1, r1, r2
	621	str r1, [fp, #LO_cycle]
	622	add r1, fp, #LO_psxRegs
	623	bl gteCheckStallRaw
	624	ldr lr, [fp, #LO_saved_lr]
	625	add r10, r10, r0
	626	bx lr
	627
cdc2da64	628	#ifdef HAVE_ARMV6
	629
	630	FUNCTION(get_reg):
	631	ldr r12, [r0]
	632	and r1, r1, #0xff
	633	ldr r2, [r0, #4]
	634	orr r1, r1, r1, lsl #8
	635	ldr r3, [r0, #8]
	636	orr r1, r1, r1, lsl #16 @ searched char in every byte
	637	ldrb r0, [r0, #12] @ last byte
	638	eor r12, r12, r1
	639	eor r2, r2, r1
	640	eor r3, r3, r1
	641	cmp r0, r1, lsr #24
	642	mov r0, #12
	643	mvn r1, #0 @ r1=~0
	644	bxeq lr
	645	orr r3, r3, #0xff000000 @ EXCLUDE_REG
	646	uadd8 r0, r12, r1 @ add and set GE bits when not 0 (match)
	647	mov r12, #0
	648	sel r0, r12, r1 @ 0 if no match, else ff in some byte
	649	uadd8 r2, r2, r1
	650	sel r2, r12, r1
	651	uadd8 r3, r3, r1
	652	sel r3, r12, r1
	653	mov r12, #3
	654	clz r0, r0 @ 0, 8, 16, 24 or 32
	655	clz r2, r2
	656	clz r3, r3
	657	sub r0, r12, r0, lsr #3 @ 3, 2, 1, 0 or -1
	658	sub r2, r12, r2, lsr #3
	659	sub r3, r12, r3, lsr #3
	660	orr r2, r2, #4
	661	orr r3, r3, #8
	662	and r0, r0, r2
	663	and r0, r0, r3
	664	bx lr
	665
	666	#endif /* HAVE_ARMV6 */
	667
7e605697	668	@ vim:filetype=armasm