libpcsxcore/new_dynarec/linkage_arm.S

   1 /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
   2  *   linkage_arm.s for PCSX                                                *
   3  *   Copyright (C) 2009-2011 Ari64                                         *
   4  *   Copyright (C) 2010-2013 Gražvydas "notaz" Ignotas                     *
   5  *                                                                         *
   6  *   This program is free software; you can redistribute it and/or modify  *
   7  *   it under the terms of the GNU General Public License as published by  *
   8  *   the Free Software Foundation; either version 2 of the License, or     *
   9  *   (at your option) any later version.                                   *
  10  *                                                                         *
  11  *   This program is distributed in the hope that it will be useful,       *
  12  *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  13  *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  14  *   GNU General Public License for more details.                          *
  15  *                                                                         *
  16  *   You should have received a copy of the GNU General Public License     *
  17  *   along with this program; if not, write to the                         *
  18  *   Free Software Foundation, Inc.,                                       *
  19  *   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.          *
  20  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
  21
  22 #include "arm_features.h"
  23 #include "new_dynarec_config.h"
  24 #include "linkage_offsets.h"
  25
  26
  27 #ifdef __MACH__
  28 #define dynarec_local           ESYM(dynarec_local)
  29 #define ndrc_add_jump_out       ESYM(ndrc_add_jump_out)
  30 #define ndrc_try_restore_block  ESYM(ndrc_try_restore_block)
  31 #define ndrc_get_addr_ht        ESYM(ndrc_get_addr_ht)
  32 #define ndrc_get_addr_ht_param  ESYM(ndrc_get_addr_ht_param)
  33 #define ndrc_write_invalidate_one ESYM(ndrc_write_invalidate_one)
  34 #define gen_interupt            ESYM(gen_interupt)
  35 #define gteCheckStallRaw        ESYM(gteCheckStallRaw)
  36 #define psxException            ESYM(psxException)
  37 #endif
  38
  39         .bss
  40         .align  4
  41         .global dynarec_local
  42         .type   dynarec_local, %object
  43         .size   dynarec_local, LO_dynarec_local_size
  44 dynarec_local:
  45         .space  LO_dynarec_local_size
  46
  47 #define DRC_VAR_(name, vname, size_) \
  48         vname = dynarec_local + LO_##name; \
  49         .global vname; \
  50         .type   vname, %object; \
  51         .size   vname, size_
  52
  53 #define DRC_VAR(name, size_) \
  54         DRC_VAR_(name, ESYM(name), size_)
  55
  56 DRC_VAR(next_interupt, 4)
  57 DRC_VAR(cycle_count, 4)
  58 DRC_VAR(last_count, 4)
  59 DRC_VAR(pending_exception, 4)
  60 DRC_VAR(stop, 4)
  61 DRC_VAR(branch_target, 4)
  62 DRC_VAR(address, 4)
  63 DRC_VAR(hack_addr, 4)
  64 DRC_VAR(psxRegs, LO_psxRegs_end - LO_psxRegs)
  65
  66 /* psxRegs */
  67 @DRC_VAR(reg, 128)
  68 DRC_VAR(lo, 4)
  69 DRC_VAR(hi, 4)
  70 DRC_VAR(reg_cop0, 128)
  71 DRC_VAR(reg_cop2d, 128)
  72 DRC_VAR(reg_cop2c, 128)
  73 DRC_VAR(pcaddr, 4)
  74 @DRC_VAR(code, 4)
  75 @DRC_VAR(cycle, 4)
  76 @DRC_VAR(interrupt, 4)
  77 @DRC_VAR(intCycle, 256)
  78
  79 DRC_VAR(rcnts, 7*4*4)
  80 DRC_VAR(inv_code_start, 4)
  81 DRC_VAR(inv_code_end, 4)
  82 DRC_VAR(mem_rtab, 4)
  83 DRC_VAR(mem_wtab, 4)
  84 DRC_VAR(psxH_ptr, 4)
  85 DRC_VAR(zeromem_ptr, 4)
  86 DRC_VAR(invc_ptr, 4)
  87 DRC_VAR(scratch_buf_ptr, 4)
  88 DRC_VAR(ram_offset, 4)
  89 DRC_VAR(mini_ht, 256)
  90
  91
  92         .syntax unified
  93         .text
  94         .align  2
  95
  96 #ifndef HAVE_ARMV5
  97 .macro blx rd
  98         mov     lr, pc
  99         bx      \rd
 100 .endm
 101 #endif
 102
 103 .macro load_varadr reg var
 104 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 105         movw    \reg, #:lower16:(\var-(1678f+8))
 106         movt    \reg, #:upper16:(\var-(1678f+8))
 107 1678:
 108         add     \reg, pc
 109 #elif defined(HAVE_ARMV7) && !defined(__PIC__)
 110         movw    \reg, #:lower16:\var
 111         movt    \reg, #:upper16:\var
 112 #else
 113         ldr     \reg, =\var
 114 #endif
 115 .endm
 116
 117 .macro load_varadr_ext reg var
 118 #if defined(HAVE_ARMV7) && defined(TEXRELS_FORBIDDEN)
 119         movw    \reg, #:lower16:(ptr_\var-(1678f+8))
 120         movt    \reg, #:upper16:(ptr_\var-(1678f+8))
 121 1678:
 122         ldr     \reg, [pc, \reg]
 123 #else
 124         load_varadr \reg \var
 125 #endif
 126 .endm
 127
 128 .macro mov_16 reg imm
 129 #ifdef HAVE_ARMV7
 130         movw    \reg, #\imm
 131 #else
 132         mov     \reg, #(\imm & 0x00ff)
 133         orr     \reg, #(\imm & 0xff00)
 134 #endif
 135 .endm
 136
 137 .macro mov_24 reg imm
 138 #ifdef HAVE_ARMV7
 139         movw    \reg, #(\imm & 0xffff)
 140         movt    \reg, #(\imm >> 16)
 141 #else
 142         mov     \reg, #(\imm & 0x0000ff)
 143         orr     \reg, #(\imm & 0x00ff00)
 144         orr     \reg, #(\imm & 0xff0000)
 145 #endif
 146 .endm
 147
 148 FUNCTION(dyna_linker):
 149         /* r0 = virtual target address */
 150         /* r1 = pointer to an instruction to patch */
 151 #ifndef NO_WRITE_EXEC
 152         ldr     r7, [r1]
 153         mov     r4, r0
 154         add     r6, r7, #2
 155         mov     r5, r1
 156         lsl     r6, r6, #8
 157         /* must not compile - that might expire the caller block */
 158         mov     r1, #0
 159         bl      ndrc_get_addr_ht_param
 160
 161         movs    r8, r0
 162         beq     0f
 163         add     r6, r5, r6, asr #6  /* old target */
 164         teq     r0, r6
 165         moveq   pc, r0 /* Stale i-cache */
 166         mov     r0, r4
 167         mov     r1, r6
 168         bl      ndrc_add_jump_out
 169
 170         sub     r2, r8, r5
 171         and     r1, r7, #0xff000000
 172         lsl     r2, r2, #6
 173         sub     r1, r1, #2
 174         add     r1, r1, r2, lsr #8
 175         str     r1, [r5]
 176         mov     pc, r8
 177 0:
 178         mov     r0, r4
 179 #else
 180         /* XXX: should be able to do better than this... */
 181 #endif
 182         bl      ndrc_get_addr_ht
 183         mov     pc, r0
 184         .size   dyna_linker, .-dyna_linker
 185
 186         .align  2
 187 FUNCTION(jump_vaddr_r1):
 188         mov     r0, r1
 189         b       jump_vaddr_r0
 190         .size   jump_vaddr_r1, .-jump_vaddr_r1
 191 FUNCTION(jump_vaddr_r2):
 192         mov     r0, r2
 193         b       jump_vaddr_r0
 194         .size   jump_vaddr_r2, .-jump_vaddr_r2
 195 FUNCTION(jump_vaddr_r3):
 196         mov     r0, r3
 197         b       jump_vaddr_r0
 198         .size   jump_vaddr_r3, .-jump_vaddr_r3
 199 FUNCTION(jump_vaddr_r4):
 200         mov     r0, r4
 201         b       jump_vaddr_r0
 202         .size   jump_vaddr_r4, .-jump_vaddr_r4
 203 FUNCTION(jump_vaddr_r5):
 204         mov     r0, r5
 205         b       jump_vaddr_r0
 206         .size   jump_vaddr_r5, .-jump_vaddr_r5
 207 FUNCTION(jump_vaddr_r6):
 208         mov     r0, r6
 209         b       jump_vaddr_r0
 210         .size   jump_vaddr_r6, .-jump_vaddr_r6
 211 FUNCTION(jump_vaddr_r8):
 212         mov     r0, r8
 213         b       jump_vaddr_r0
 214         .size   jump_vaddr_r8, .-jump_vaddr_r8
 215 FUNCTION(jump_vaddr_r9):
 216         mov     r0, r9
 217         b       jump_vaddr_r0
 218         .size   jump_vaddr_r9, .-jump_vaddr_r9
 219 FUNCTION(jump_vaddr_r10):
 220         mov     r0, r10
 221         b       jump_vaddr_r0
 222         .size   jump_vaddr_r10, .-jump_vaddr_r10
 223 FUNCTION(jump_vaddr_r12):
 224         mov     r0, r12
 225         b       jump_vaddr_r0
 226         .size   jump_vaddr_r12, .-jump_vaddr_r12
 227 FUNCTION(jump_vaddr_r7):
 228         add     r0, r7, #0
 229         .size   jump_vaddr_r7, .-jump_vaddr_r7
 230 FUNCTION(jump_vaddr_r0):
 231         bl      ndrc_get_addr_ht
 232         mov     pc, r0
 233         .size   jump_vaddr_r0, .-jump_vaddr_r0
 234
 235         .align  2
 236 FUNCTION(cc_interrupt):
 237         ldr     r0, [fp, #LO_last_count]
 238         mov     r1, #0
 239         add     r10, r0, r10
 240         str     r1, [fp, #LO_pending_exception]
 241         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 242 @@      str     r10, [fp, #LO_reg_cop0+36]      /* Count - not on PSX */
 243         mov     r10, lr
 244
 245         add     r0, fp, #(LO_psxRegs + 34*4)    /* CP0 */
 246         bl      gen_interupt
 247         mov     lr, r10
 248         ldr     r10, [fp, #LO_cycle]
 249         ldr     r0, [fp, #LO_next_interupt]
 250         ldr     r1, [fp, #LO_pending_exception]
 251         ldr     r2, [fp, #LO_stop]
 252         str     r0, [fp, #LO_last_count]
 253         sub     r10, r10, r0
 254         tst     r2, r2
 255         ldmfdne sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 256         tst     r1, r1
 257         moveq   pc, lr
 258         ldr     r0, [fp, #LO_pcaddr]
 259         bl      ndrc_get_addr_ht
 260         mov     pc, r0
 261         .size   cc_interrupt, .-cc_interrupt
 262
 263         .align  2
 264 FUNCTION(jump_overflow_ds):
 265         mov     r0, #(12<<2)  /* R3000E_Ov */
 266         mov     r1, #1
 267         b       call_psxException
 268 FUNCTION(jump_overflow):
 269         mov     r0, #(12<<2)
 270         mov     r1, #0
 271         b       call_psxException
 272 FUNCTION(jump_break_ds):
 273         mov     r0, #(9<<2)  /* R3000E_Bp */
 274         mov     r1, #1
 275         b       call_psxException
 276 FUNCTION(jump_break):
 277         mov     r0, #(9<<2)
 278         mov     r1, #0
 279         b       call_psxException
 280 FUNCTION(jump_syscall_ds):
 281         mov     r0, #(8<<2)  /* R3000E_Syscall */
 282         mov     r1, #2
 283         b       call_psxException
 284 FUNCTION(jump_syscall):
 285         mov     r0, #(8<<2)
 286         mov     r1, #0
 287
 288 call_psxException:
 289         ldr     r3, [fp, #LO_last_count]
 290         str     r2, [fp, #LO_pcaddr]
 291         add     r10, r3, r10
 292         str     r10, [fp, #LO_cycle]            /* PCSX cycles */
 293         add     r2, fp, #(LO_psxRegs + 34*4)    /* CP0 */
 294         bl      psxException
 295
 296         /* note: psxException might do recursive recompiler call from it's HLE code,
 297          * so be ready for this */
 298 FUNCTION(jump_to_new_pc):
 299         ldr     r1, [fp, #LO_next_interupt]
 300         ldr     r10, [fp, #LO_cycle]
 301         ldr     r0, [fp, #LO_pcaddr]
 302         sub     r10, r10, r1
 303         str     r1, [fp, #LO_last_count]
 304         bl      ndrc_get_addr_ht
 305         mov     pc, r0
 306         .size   jump_to_new_pc, .-jump_to_new_pc
 307
 308         .align  2
 309 FUNCTION(new_dyna_leave):
 310         ldr     r0, [fp, #LO_last_count]
 311         add     r12, fp, #28
 312         add     r10, r0, r10
 313         str     r10, [fp, #LO_cycle]
 314         ldmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, pc}
 315         .size   new_dyna_leave, .-new_dyna_leave
 316
 317         .align  2
 318 FUNCTION(invalidate_addr_r0):
 319         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 320         b       invalidate_addr_call
 321         .size   invalidate_addr_r0, .-invalidate_addr_r0
 322         .align  2
 323 FUNCTION(invalidate_addr_r1):
 324         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 325         mov     r0, r1
 326         b       invalidate_addr_call
 327         .size   invalidate_addr_r1, .-invalidate_addr_r1
 328         .align  2
 329 FUNCTION(invalidate_addr_r2):
 330         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 331         mov     r0, r2
 332         b       invalidate_addr_call
 333         .size   invalidate_addr_r2, .-invalidate_addr_r2
 334         .align  2
 335 FUNCTION(invalidate_addr_r3):
 336         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 337         mov     r0, r3
 338         b       invalidate_addr_call
 339         .size   invalidate_addr_r3, .-invalidate_addr_r3
 340         .align  2
 341 FUNCTION(invalidate_addr_r4):
 342         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 343         mov     r0, r4
 344         b       invalidate_addr_call
 345         .size   invalidate_addr_r4, .-invalidate_addr_r4
 346         .align  2
 347 FUNCTION(invalidate_addr_r5):
 348         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 349         mov     r0, r5
 350         b       invalidate_addr_call
 351         .size   invalidate_addr_r5, .-invalidate_addr_r5
 352         .align  2
 353 FUNCTION(invalidate_addr_r6):
 354         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 355         mov     r0, r6
 356         b       invalidate_addr_call
 357         .size   invalidate_addr_r6, .-invalidate_addr_r6
 358         .align  2
 359 FUNCTION(invalidate_addr_r7):
 360         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 361         mov     r0, r7
 362         b       invalidate_addr_call
 363         .size   invalidate_addr_r7, .-invalidate_addr_r7
 364         .align  2
 365 FUNCTION(invalidate_addr_r8):
 366         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 367         mov     r0, r8
 368         b       invalidate_addr_call
 369         .size   invalidate_addr_r8, .-invalidate_addr_r8
 370         .align  2
 371 FUNCTION(invalidate_addr_r9):
 372         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 373         mov     r0, r9
 374         b       invalidate_addr_call
 375         .size   invalidate_addr_r9, .-invalidate_addr_r9
 376         .align  2
 377 FUNCTION(invalidate_addr_r10):
 378         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 379         mov     r0, r10
 380         b       invalidate_addr_call
 381         .size   invalidate_addr_r10, .-invalidate_addr_r10
 382         .align  2
 383 FUNCTION(invalidate_addr_r12):
 384         stmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, lr}
 385         mov     r0, r12
 386         .size   invalidate_addr_r12, .-invalidate_addr_r12
 387         .align  2
 388 invalidate_addr_call:
 389         ldr     r12, [fp, #LO_inv_code_start]
 390         ldr     lr, [fp, #LO_inv_code_end]
 391         cmp     r0, r12
 392         cmpcs   lr, r0
 393         blcc    ndrc_write_invalidate_one
 394         ldmia   fp, {r0, r1, r2, r3, EXTRA_UNSAVED_REGS r12, pc}
 395         .size   invalidate_addr_call, .-invalidate_addr_call
 396
 397         .align  2
 398 FUNCTION(new_dyna_start):
 399         /* ip is stored to conform EABI alignment */
 400         stmfd   sp!, {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr}
 401         mov     fp, r0 /* dynarec_local */
 402         ldr     r0, [fp, #LO_pcaddr]
 403         bl      ndrc_get_addr_ht
 404         ldr     r1, [fp, #LO_next_interupt]
 405         ldr     r10, [fp, #LO_cycle]
 406         str     r1, [fp, #LO_last_count]
 407         sub     r10, r10, r1
 408         mov     pc, r0
 409         .size   new_dyna_start, .-new_dyna_start
 410
 411 /* --------------------------------------- */
 412
 413 .align  2
 414
 415 .macro pcsx_read_mem readop tab_shift
 416         /* r0 = address, r1 = handler_tab, r2 = cycles */
 417         lsl     r3, r0, #20
 418         lsr     r3, #(20+\tab_shift)
 419         ldr     r12, [fp, #LO_last_count]
 420         ldr     r1, [r1, r3, lsl #2]
 421         add     r2, r2, r12
 422         lsls    r1, #1
 423 .if \tab_shift == 1
 424         lsl     r3, #1
 425         \readop r0, [r1, r3]
 426 .else
 427         \readop r0, [r1, r3, lsl #\tab_shift]
 428 .endif
 429         movcc   pc, lr
 430         str     r2, [fp, #LO_cycle]
 431         bx      r1
 432 .endm
 433
 434 FUNCTION(jump_handler_read8):
 435         add     r1, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 436         pcsx_read_mem ldrbcc, 0
 437
 438 FUNCTION(jump_handler_read16):
 439         add     r1, #0x1000/4*4              @ shift to r16 part
 440         pcsx_read_mem ldrhcc, 1
 441
 442 FUNCTION(jump_handler_read32):
 443         pcsx_read_mem ldrcc, 2
 444
 445
 446 .macro memhandler_post
 447         ldr     r0, [fp, #LO_next_interupt]
 448         ldr     r2, [fp, #LO_cycle]        @ memhandlers can modify cc, like dma
 449         str     r0, [fp, #LO_last_count]
 450         sub     r0, r2, r0
 451 .endm
 452
 453 .macro pcsx_write_mem wrtop tab_shift
 454         /* r0 = address, r1 = data, r2 = cycles, r3 = handler_tab */
 455         lsl     r12,r0, #20
 456         lsr     r12, #(20+\tab_shift)
 457         ldr     r3, [r3, r12, lsl #2]
 458         str     r0, [fp, #LO_address]      @ some handlers still need it..
 459         lsls    r3, #1
 460         mov     r0, r2                     @ cycle return in case of direct store
 461 .if \tab_shift == 1
 462         lsl     r12, #1
 463         \wrtop  r1, [r3, r12]
 464 .else
 465         \wrtop  r1, [r3, r12, lsl #\tab_shift]
 466 .endif
 467         movcc   pc, lr
 468         ldr     r12, [fp, #LO_last_count]
 469         mov     r0, r1
 470         add     r2, r2, r12
 471         str     r2, [fp, #LO_cycle]
 472
 473         str     lr, [fp, #LO_saved_lr]
 474         blx     r3
 475         ldr     lr, [fp, #LO_saved_lr]
 476
 477         memhandler_post
 478         bx      lr
 479 .endm
 480
 481 FUNCTION(jump_handler_write8):
 482         add     r3, #0x1000/4*4 + 0x1000/2*4 @ shift to r8 part
 483         pcsx_write_mem strbcc, 0
 484
 485 FUNCTION(jump_handler_write16):
 486         add     r3, #0x1000/4*4              @ shift to r16 part
 487         pcsx_write_mem strhcc, 1
 488
 489 FUNCTION(jump_handler_write32):
 490         pcsx_write_mem strcc, 2
 491
 492 FUNCTION(jump_handler_write_h):
 493         /* r0 = address, r1 = data, r2 = cycles, r3 = handler */
 494         ldr     r12, [fp, #LO_last_count]
 495         str     r0, [fp, #LO_address]      @ some handlers still need it..
 496         add     r2, r2, r12
 497         mov     r0, r1
 498         str     r2, [fp, #LO_cycle]
 499
 500         str     lr, [fp, #LO_saved_lr]
 501         blx     r3
 502         ldr     lr, [fp, #LO_saved_lr]
 503
 504         memhandler_post
 505         bx      lr
 506
 507 FUNCTION(jump_handle_swl):
 508         /* r0 = address, r1 = data, r2 = cycles */
 509         ldr     r3, [fp, #LO_mem_wtab]
 510         mov     r12,r0,lsr #12
 511         ldr     r3, [r3, r12, lsl #2]
 512         lsls    r3, #1
 513         bcs     4f
 514         add     r3, r0, r3
 515         mov     r0, r2
 516         tst     r3, #2
 517         beq     101f
 518         tst     r3, #1
 519         beq     2f
 520 3:
 521         str     r1, [r3, #-3]
 522         bx      lr
 523 2:
 524         lsr     r2, r1, #8
 525         lsr     r1, #24
 526         strh    r2, [r3, #-2]
 527         strb    r1, [r3]
 528         bx      lr
 529 101:
 530         tst     r3, #1
 531         lsrne   r1, #16         @ 1
 532         lsreq   r12, r1, #24    @ 0
 533         strhne  r1, [r3, #-1]
 534         strbeq  r12, [r3]
 535         bx      lr
 536 4:
 537         mov     r0, r2
 538 @       b       abort
 539         bx      lr              @ TODO?
 540
 541
 542 FUNCTION(jump_handle_swr):
 543         /* r0 = address, r1 = data, r2 = cycles */
 544         ldr     r3, [fp, #LO_mem_wtab]
 545         mov     r12,r0,lsr #12
 546         ldr     r3, [r3, r12, lsl #2]
 547         lsls    r3, #1
 548         bcs     4f
 549         add     r3, r0, r3
 550         and     r12,r3, #3
 551         mov     r0, r2
 552         cmp     r12,#2
 553         strbgt  r1, [r3]        @ 3
 554         strheq  r1, [r3]        @ 2
 555         cmp     r12,#1
 556         strlt   r1, [r3]        @ 0
 557         bxne    lr
 558         lsr     r2, r1, #8      @ 1
 559         strb    r1, [r3]
 560         strh    r2, [r3, #1]
 561         bx      lr
 562 4:
 563         mov     r0, r2
 564 @       b       abort
 565         bx      lr              @ TODO?
 566
 567
 568 .macro rcntx_read_mode0 num
 569         /* r0 = address, r2 = cycles */
 570         ldr     r3, [fp, #LO_rcnts+6*4+7*4*\num] @ cycleStart
 571         mov     r0, r2, lsl #16
 572         sub     r0, r0, r3, lsl #16
 573         lsr     r0, #16
 574         bx      lr
 575 .endm
 576
 577 FUNCTION(rcnt0_read_count_m0):
 578         rcntx_read_mode0 0
 579
 580 FUNCTION(rcnt1_read_count_m0):
 581         rcntx_read_mode0 1
 582
 583 FUNCTION(rcnt2_read_count_m0):
 584         rcntx_read_mode0 2
 585
 586 FUNCTION(rcnt0_read_count_m1):
 587         /* r0 = address, r2 = cycles */
 588         ldr     r3, [fp, #LO_rcnts+6*4+7*4*0] @ cycleStart
 589         mov_16  r1, 0x3334
 590         sub     r2, r2, r3
 591         mul     r0, r1, r2              @ /= 5
 592         lsr     r0, #16
 593         bx      lr
 594
 595 FUNCTION(rcnt1_read_count_m1):
 596         /* r0 = address, r2 = cycles */
 597         ldr     r3, [fp, #LO_rcnts+6*4+7*4*1]
 598         mov_24  r1, 0x1e6cde
 599         sub     r2, r2, r3
 600         umull   r3, r0, r1, r2          @ ~ /= hsync_cycles, max ~0x1e6cdd
 601         bx      lr
 602
 603 FUNCTION(rcnt2_read_count_m1):
 604         /* r0 = address, r2 = cycles */
 605         ldr     r3, [fp, #LO_rcnts+6*4+7*4*2]
 606         mov     r0, r2, lsl #16-3
 607         sub     r0, r0, r3, lsl #16-3
 608         lsr     r0, #16                 @ /= 8
 609         bx      lr
 610
 611 FUNCTION(call_gteStall):
 612         /* r0 = op_cycles, r1 = cycles */
 613         ldr     r2, [fp, #LO_last_count]
 614         str     lr, [fp, #LO_saved_lr]
 615         add     r1, r1, r2
 616         str     r1, [fp, #LO_cycle]
 617         add     r1, fp, #LO_psxRegs
 618         bl      gteCheckStallRaw
 619         ldr     lr, [fp, #LO_saved_lr]
 620         add     r10, r10, r0
 621         bx      lr
 622
 623 #ifdef HAVE_ARMV6
 624
 625 FUNCTION(get_reg):
 626         ldr     r12, [r0]
 627         and     r1, r1, #0xff
 628         ldr     r2, [r0, #4]
 629         orr     r1, r1, r1, lsl #8
 630         ldr     r3, [r0, #8]
 631         orr     r1, r1, r1, lsl #16   @ searched char in every byte
 632         ldrb    r0, [r0, #12]         @ last byte
 633         eor     r12, r12, r1
 634         eor     r2, r2, r1
 635         eor     r3, r3, r1
 636         cmp     r0, r1, lsr #24
 637         mov     r0, #12
 638         mvn     r1, #0                @ r1=~0
 639         bxeq    lr
 640         orr     r3, r3, #0xff000000   @ EXCLUDE_REG
 641         uadd8   r0, r12, r1           @ add and set GE bits when not 0 (match)
 642         mov     r12, #0
 643         sel     r0, r12, r1           @ 0 if no match, else ff in some byte
 644         uadd8   r2, r2, r1
 645         sel     r2, r12, r1
 646         uadd8   r3, r3, r1
 647         sel     r3, r12, r1
 648         mov     r12, #3
 649         clz     r0, r0                @ 0, 8, 16, 24 or 32
 650         clz     r2, r2
 651         clz     r3, r3
 652         sub     r0, r12, r0, lsr #3   @ 3, 2, 1, 0 or -1
 653         sub     r2, r12, r2, lsr #3
 654         sub     r3, r12, r3, lsr #3
 655         orr     r2, r2, #4
 656         orr     r3, r3, #8
 657         and     r0, r0, r2
 658         and     r0, r0, r3
 659         bx      lr
 660
 661 #endif /* HAVE_ARMV6 */
 662
 663 @ vim:filetype=armasm